Ben çoğunlukla bu işlevi kullanırım:
cf() {
cd "$(osascript -e 'tell app "Finder" to POSIX path of (insertion location as alias)')"
}
Ayrıca aşağıdakiler gibi bir betiğe kısayol atayabilirsiniz.
Mevcut bir sekmeyi yeniden kullanın veya yeni bir pencere oluşturun (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if (exists window 1) and not busy of window 1 then
do script "cd " & quoted form of p in window 1
else
do script "cd " & quoted form of p
end if
activate
end tell
Mevcut bir sekmeyi tekrar kullanın veya yeni bir sekme oluşturun (Terminal):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "Terminal"
if not (exists window 1) then reopen
activate
if busy of window 1 then
tell application "System Events" to keystroke "t" using command down
end if
do script "cd " & quoted form of p in window 1
end tell
Her zaman yeni bir sekme oluştur (iTerm 2):
tell application "Finder" to set p to POSIX path of (insertion location as alias)
tell application "iTerm"
if exists current terminal then
current terminal
else
make new terminal
end if
tell (launch session "Default") of result to write text "cd " & quoted form of p
activate
end tell
İlk iki senaryo, 10.7’de eklenen hizmetlere kıyasla birkaç avantaja sahiptir:
- 10.9'dan itibaren, giriş olarak klasör alan servislerin sütun görünümündeki servisler menüsünde hiçbir zaman listelenmediği bir hata var. Klasör hizmetinde Yeni Terminal Sekmesini bir klavye kısayolu atarsanız, sütun görünümünde çalışmaz.
- Önce bir klasör seçmenizi yerine başlık çubuğundaki klasörü kullanırlar.
- Meşgul değilse en öndeki sekmeyi yeniden kullanırlar, örneğin bir komut çalıştırmak, bir man sayfasını görüntülemek veya emacs çalıştırmak.
10.7 veya 10.8 kullanıyorsanız, şuna değiştirin tell application "Finder" to set p to POSIX path of (insertion location as alias):
tell application "Finder"
if exists Finder window 1 then
set p to POSIX path of (target of Finder window 1 as alias)
else
set p to POSIX path of (path to desktop)
end if
end tell
10.7 ve 10.8’de bir hata var (ancak 10.9 veya 10.6’da değil), Finder'ın en son odaklanmasından sonra oluşturulan pencereleri görmezden geldiğini ve başka bir uygulamaya geçildiğini ve insertion locationözelliği geri alırken geri döndüğünü gösteriyor .
