Şu anda OS X (10.9.1) kullanıyorum ve kaydetme iletişim kutusunda ⌘+ ⇧+ .klavye kısayolunu denedim ve gayet iyi çalıştı.
Ayrıca makinemde bir AppleScript'i ^+ ⌘+ ⇧+ klavye kısayoluyla, .istediğimde Bulucu içindeki gizli dosyaların görünürlüğünü değiştiren bir kısayolla kurdum. Bu şekilde, gizli dosyaları göstermek için bir terminal komutunu manuel olarak çalıştırmam gerekmiyor ve sistem dosyalarını yanlışlıkla değiştirmekten kaçınmak için hızlıca kapatabilirim. AppleScript'imin klavye kısayolunu ayarlamama izin vermek için FastScripts ( Mac App Store'da da mevcuttur ) kullanıyorum ve AppleScript'i Klasörüme yerleştirdim ~/Library/Scripts.
Güncelleme
Senaryoyu güncelledim, böylece Finder'ın gizli dosyaların görüntüsünü göstermek / gizlemek istediğinizde öldürülmesine gerek kalmayacak. Markhunte'nin belirttiği gibi, içerik listesini yenileyecek Finder penceresinin görünüm durumunu değiştirebilirsiniz. Bana işaret ettiğin için teşekkürler! İşte güncellenmiş komut dosyası:
(*
Author: Anil Natha
Description:
This script toggles the visibility of hidden files in OS X. This includes
showing hidden files in Finder windows and on the desktop.
Last Updated: 2015-02-20
*)
tell application "System Events"
try
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
on error
set hiddenFilesDisplayStatus to "NO"
end try
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
end tell
tell application "Finder"
set allWindows to windows
repeat with currentWindow in allWindows
set currentWindowView to get the current view of the currentWindow
set alternateWindowView to list view
if currentWindowView is list view then
set alternateWindowView to icon view
end if
set the current view of the currentWindow to alternateWindowView
set the current view of the currentWindow to currentWindowView
end repeat
end tell
Komut dosyasının eski sürümü aşağıda listelenmiştir. Çalışsa da, yukarıdaki betiğin daha verimli çalıştığı için artık kullanılmasını önermiyorum.
tell application "System Events"
set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
set hiddenFilesNewDisplayStatus to "NO"
if hiddenFilesDisplayStatus is "NO" then
set hiddenFilesNewDisplayStatus to "YES"
end if
do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
do shell script "killall Finder"
end tell