Akıllı Klasör Klasörü Hariç Tut

Sonuçta bu find komutunun sonucunun akıllı bir klasör olmasını istiyorum.

Kriterler o kadar karmaşık değil:

• ad "README.md" olmalıdır
• dosya türü olmalı
• yol "düğüm_modülleri" içermemelidir

find /Users/me/Documents -type f -name README.md -not -path "*/node_modules/*"

Sorun, akıllı klasörler ölçütleri operatör listesinde bir does not containseçenek eksik görünüyor .

Mevcut seçenekler:

• maçlar
• içeren
• İle başlar
• ile biter
• dır-dir
• değil

Bunu başarmak mümkün mü ve eğer öyleyse nasıl?

Düzenle 1

Seçenek tuşunu basılı tutarak akıllı klasör arama ölçütlerine bir olumsuzluk maddesi ekleyebildiğimi ancak başarılı bir şekilde node_modules klasörünü hariç tutamayacağımı buldum. Hangi ölçütlerin kullanılacağı belli değil, ancak denediklerimin hiçbiri işe yaramıyor:

• Doküman Kabı
• Klasör Adlarını İçeren
• Klasör adı

Bunları aşağıdaki operatörlerle birleştirmeyi denedim:

• içeren
• maçlar

ve aşağıdaki şartlarla:

• node_modules
• node_modules

joker karakterli aramaları desteklemesi durumunda.

Yukarıdaki filtrelerin, operatörlerin ve terimlerin tüm kombinasyonlarını denedim.

Bu konuda dokümantasyon çok zayıf.

Görünüşe göre kMDItemPath ihtiyacınız olanı yapamıyor:

no-sonuç-in-spot-in-aramalarda-karşı-kmditempath

Bazı potansiyel alternatifler burada tartışılmaktadır:

nasıl yapılır-bulun-a-Dosya-içinde-spot kullanan klasör ve dosya-ismi

Bir çözüm var, ama çok hoş değil. Bununla birlikte, README'lerinize tek bir klasörden (belirttiğiniz ölçütleri kullanarak) erişmek ve nereden geldiklerine dair bir fikre sahip olmak istiyorsanız, amaçlarınıza hizmet edecektir.

Fikir, doğru dosyaları bulmak için kabuk komut dosyanızı kullanmak ve daha sonra tek bir dizindeki her dosya için diğer adları toplamaktır. Daha sonra, orijinal dosyanın hangi üst dizine ait olduğunu belirtmek için takma adları yeniden adlandırırız.

Bunu yapmak için Applescript aşağıdadır. Burada çirkin görünüyor, ancak Komut Dosyası Düzenleyicisi'ne yapıştırmayı deneyin ve derleyin ve mantığı görebilmeniz gerekir.

--- Set up the name of the folder to contain search results
set myFolder to POSIX file "/Users/me/SmartFolder"

--- Clear the folder of contents. Then we will see only the results of an updated search
tell application "Finder"
    display dialog "WARNING. This will delete all files below " & (POSIX path of myFolder) & " . Are you sure you want to continue?"
    delete (every item of folder myFolder)
    --- alternatively, if you want to keep your script in the same folder, replace the line above with
    --- delete ((every item of folder myFolder) whose name does not end with ".scpt")
end tell

--- The shell command that is doing all the searching
set FileList to do shell script "find /Users/me/Documents -type f -name README.md -not -path '*/node_modules/*'"

--- The rest of the script takes each file and makes an alias in our folder containing search results. The aliases are renamed according to "ParentDirectory_filename"
set FileList to paragraphs of FileList
repeat with CurrentFile in FileList
    set ASCurrentFile to POSIX file CurrentFile
    set PathList to words of (ASCurrentFile as string)
    --- Make the new name include the Parent Directory and file name
    set NewName to (item -2 of PathList) & "_" & (item -1 of PathList)
    tell application "Finder"
        make new alias file at myFolder to ASCurrentFile
        --- We need to save the name/location of the new alias file before we can try to rename it
        set NewAlias to result
        set i to 1
        repeat
            try
                --- Try to rename the alias. Won't work if there's already an alias with the new name
                set name of NewAlias to NewName
                exit repeat
            on error
                --- Append a number to the alias. Increase the number for more duplicates
                if i is not equal to 1 then
                    set NewName to text 1 thru -3 of NewName
                end if
                set NewName to NewName & " " & i
                set i to (i + 1)
            end try
        end repeat
    end tell
end repeat