Safari “Arama Sekmeleri” Klavye Kısayolları

Safari 8'in yeni "Arama Sekmeleri" özelliği oldukça hoş. "Tüm sekmeleri göster" etkinleştirildiğinde, sekmeleri istediğiniz sekmeye filtre uygulamak için bazı metinler yazabilirsiniz. Ancak, tek bir sekme görünür olduğunda, o sekmeyi etkinleştirmek çok güzel olurdu . Bu, sekmeler için "spot" türü işlevselliğe izin verir.

Ancak, aradığımda sekmeyi etkinleştirmek için bir klavye kısayolu var gibi görünmüyor, bu yüzden faremle sekmeyi tıklatmak zorunda kaldım! Bu bir gözetim gibi görünüyor, Apple'ın sekmeleri filtrelemek için güzel bir yol ekleyeceğine inanamıyorum, ancak birini seçmenin bir yolu yok!

Ekran görüntüsü:

Hiçbir etki için, bunu yapmak için aşağıdaki anahtar kombinasyonları denedim:

• Command + Return ... + Boşluk
• Option + Return ... + Boşluk
• Control + Return ... + Boşluk
• Command + Shift + \ (Macbook'umdaki "Tüm Sekmeleri Göster" Komutu)

Bu beni gerçekten Apple açısından bir gözetim olduğuna inanmaya yönlendiriyor.

Kludge: Bir Fare Tıklamasını Simüle Etmek için Bir Otomatikleştirici Komutu Oluşturun

Aşağıdaki AppleScripts'i bir araya getirmek için https://discussions.apple.com/thread/3708948 adresinde bulduğum kodu kullandım :

Deneme 1: İşe yaramadı Bu kodu, "Command + Control + Shift + 4" tuşlarına basarak aldığım sayıları kullanarak "Command + Shift + Option + Control + Space" ile eşlenen bir Automator Hizmetinde sarılmış bir Applescript'te çalıştırdım. alanın adresini alın (soldan 600 piksel yatay, üstten 300 piksel dikey) ve normal Safari'de çalışır (tuş kombinasyonuna basmak farenin bu piksel adresinde tıklamasını sağlar), ancak Safari'de "Tüm Sekmeleri Göster" modunda aynı tuş komutu çalıştırıldı!

on run {input, parameters}
    tell application "System Events"
            tell process "Safari"
                click at {600, 300}
            end tell
        end tell

        return input
    end run

Deneme # 2: Çalışıldı, ancak Uygulanamaz

Bir Automator Hizmetinde sarılı olan aşağıdaki Applescript ile çalışan bir tuş komutu aldım, ancak tamamlanması 5.125 saniye sürdü :(

    on run {input, parameters}

    set x to 600
    set y to 150

    do shell script "
/usr/bin/python <<END
import sys
import time
from Quartz.CoreGraphics import *
def mouseEvent(type, posx, posy):
          theEvent = CGEventCreateMouseEvent(None, type, (posx,posy), kCGMouseButtonLeft)
          CGEventPost(kCGHIDEventTap, theEvent)
def mousemove(posx,posy):
          mouseEvent(kCGEventMouseMoved, posx,posy);
def mouseclick(posx,posy):
          mouseEvent(kCGEventLeftMouseDown, posx,posy);
          mouseEvent(kCGEventLeftMouseUp, posx,posy);
ourEvent = CGEventCreate(None);
currentpos=CGEventGetLocation(ourEvent);             # Save current mouse position
mouseclick(" & x & "," & y & ");
mousemove(int(currentpos.x),int(currentpos.y));      # Restore mouse position
END"
    return input
end run

Sanırım cevabını aldım. Bütün gün bunu arayarak geçirdim. Tüm elma cihazlarına ek hareketler ve kısayollar eklemek için BetterTouchTool (OS X 10.10 kullanarak) adlı harika bir ücretsiz uygulama kullanıyorum ve anında çalışıyor! Gecikme yok!

Yapılandırmanız gereken her adımda ekran görüntüleri yapacağım. NOT: Safari'yi kullanırken fare konumunu seçtiğiniz bir klavye kısayolu olarak bağlar. Dezavantajları: Safari'nin pencere konumunu değiştiremezsiniz ve farenin konumu dizüstü bilgisayarınızdan monitörden farklı olacaktır. Çözüm: En çok kullandığınız ekranla fare konumunu tam ekran olarak kullanmanızı öneririm (veya her ekran için iki kısayolu eşleyin)

• 1 Uygulamayı indirin http://www.bettertouchtool.net

• 2 Uygulamayı açın, klavyeyi seçin, ekleyeceğiniz kısayollara listeye bir uygulama ekleyin (bu durumda Safari), kısayolunuzu seçin (bu ekran görüntüsünde "Option + 1" i eşliyorum), ardından Tetikleyici seçimi içinde menüsünde, "Diğer Mouser Eylemleri" nde " Fareyi Konuma Taşı " seçeneğini belirleyin . Ekran görüntüsünde yanlış seçeneği işaretledim, yukarıdaki seçenek. "Fare konumunu kaydet" DEĞİLDİR. Üzgünüm çok yorgunum, sabah 3 ve yarın çalışmak zorundayım

• 3 İmlecin nereye gitmesini istediğinizi seçin (Kullanıcı arabirimi ~ 3 sonuç gösterdiğinde giriş kutusundaki konum ilk sonucu kontrol eder)

• 4 Aşağıdaki etkinliği ekleyin: Sol tıklama etkinliği. Ve bu kadar!

2., 3. .. sonucunu elde etmek için farklı bir fare pozisyonuyla aynı şeyi yapın, ancak daha büyük sonuçlar elde ederseniz ui'nin değişeceğini, hatta bazen ilk sonucu gizleyeceğini unutmayın.

Bu özelliği eklemeden önce bu işlemi yapmak için Applescript kullanıyorum:

http://hea-www.harvard.edu/~fine/OSX/safari-tabs.html

Bir arama iletişim kutusu açılır, aramanıza girersiniz ve hemen tek bir eşleşen sekmeyi etkinleştirir veya size eşleşen sekmeler listesinden seçim yapmanız için bir iletişim kutusu sunar. Pencereyi öne getirir ve bunu penceredeki etkin sekme yapar.

(Terminal pencerelerini bulmak için benzer bir senaryom var.)

Partiye biraz geç kaldım, ancak Shortcat'in gerekli işlevselliği yapacağını düşünüyorum .

Eklenen bonus ile Mail, vb. İle kullanılabilir.

Automator'ı kullanın ve AppleScript'i, aşağıda açıklandığı gibi bir klavye kısayoluna iliştirerek yapıştırın:

Yazdığım bir AppleScript'e nasıl klavye kısayolu atayabilirim?

set question to display dialog ("Find Safari tab:") default answer ""
set searchpat to text returned of question

tell application "Safari"
    set winlist to every window
    set winmatchlist to {}
    set tabmatchlist to {}
    set tabnamematchlist to {}
    repeat with win in winlist
        set ok to true
        try
            set tablist to every tab of win
        on error errmsg
            --display dialog name of win as string
            set ok to false
        end try
        if ok then
            repeat with t in tablist
                if searchpat is in (name of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                else if searchpat is in (URL of t as string) then
                    set end of winmatchlist to win
                    set end of tabmatchlist to t
                    set end of tabnamematchlist to (id of win as string) & "." & (index of t as string) & ".  " & (name of t as string)
                    --display dialog name of t as string
                end if
            end repeat
        end if
    end repeat
    if (count of tabmatchlist) = 1 then
        --display dialog "one!"
        set w to item 1 of winmatchlist
        set t to item 1 of tabmatchlist
        set current tab of w to t
        set index of w to 1
    else if (count of tabmatchlist) = 0 then
        display dialog "No matches"
    else
        set whichtab to choose from list of tabnamematchlist with prompt "The following tabs match, please select one:"
        set AppleScript's text item delimiters to "."
        if whichtab is not equal to false then
            set tmp to text items of (whichtab as string)
            set w to (item 1 of tmp) as integer
            set t to (item 2 of tmp) as integer
            set current tab of window id w to tab t of window id w
            set index of window id w to 1
        end if
    end if
end tell