Diyelim ki (Q7+Q11)÷Q20hücrede olduğu gibi bir formülüm var O20ve onu başka bir hücreye kopyalamak istiyorum, diyelim D47, formülün orijinal referanslarını kaybetmeden ve yeniden yazmadan yapmak için herhangi bir anahtar değiştirici veya kısayol var mı?

Cmd+Alt Sürükle ve bırak gibi bir şey ?

Mac OS Sierra'da Numbers 4 ile birlikteyim

Yerleşik yöntemi kullanma

Gereğince Apple'ın Bilgi Bankası'ndaki , Sayılar destekler mutlak başvurular :

Bir formüldeki satır ve sütun referanslarını mutlak olarak ayarlayabilirsiniz, böylece aynı formülü, e-tablonuzun herhangi bir yerinde, hücre referansları değişmeden değiştirmeden kullanabilirsiniz.

Orijinal formülünüzü mutlak referanslar kullanacak şekilde değiştirmek için aşağıdaki adımları izleyin:

1. Düzenleme moduna geçmek için orijinal hücreye çift tıklayın.
2. Her referans için üçgeni tıklayın; sonra iki kutuyu da Satır Koru ve Sütunu Koru'yu işaretleyin .

Veya, 2. adıma alternatif olarak, e. g. $A$1yerine A1.

Bu yöntemin belirgin sakıncaları şunlardır:

• Bu yöntem temel olarak formülünüzü, gerçekten esnek referanslar istediğiniz diğer yerlerde aynı formülü yeniden kullanmayı zorlaştıran bir modda kilitler .

• Pek çok farklı orijinal formülü kopyalamak istiyorsanız, yöntemi tekrar tekrar yapmanız gerekir.

Formül Kopyalamak için AppleScript Kullanma

Yeniden kullanılabilir bir yaklaşım , Kopyala komutunu kopyalayan, ancak yalnızca çıplak formülleri kopyalayan basit bir AppleScript olacaktır :

on join(cells, delimiter)
  set previousDelimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to delimiter
  set resultString to (cells as text)
  set AppleScript's text item delimiters to previousDelimiters
  return resultString
end join

on getSelectedFormulas()
  set tab to character id 9
  set lf to character id 10

  tell application "Numbers"
    tell document 1's sheet 1's table 1
      tell selection range
        set {min, max} to {column 1's address, column -1's address}
        set formulaRows to {}
        repeat with aRow in rows
          set formulaCells to {}
          repeat with aCell in aRow's cells min thru max
            set formulaCells to formulaCells & (aCell's formula)
          end repeat
          set formulaRows to formulaRows & ¬
            my join(formulaCells, tab)
        end repeat
        return my join(formulaRows, lf)
      end tell
    end tell
  end tell
end getSelectedFormulas

on run()
  tell application "Numbers"
    set the clipboard to my getSelectedFormulas()
  end tell
end run

(Not: Senaryonun yazarıyım; ISC açık kaynak lisansı altında .)

Bu aynı zamanda orijinal formülleri değiştirme ihtiyacını da ortadan kaldırır.

Komut dosyasını klavye kısayoluna bağlama

Bu betiği Numaralar'daki bir klavye kısayoluna bağlamak için, bir Automator iş akışı oluşturmak için Automator.app'yi açın. Servis'in Numbers'dan giriş almaması seçeneğini seçin, tek bir AppleScript Çalıştır adımı oluşturun ve AppleScript kodunu buraya yapıştırın.

İş akışını adın altına kaydedin Copy Formulas, ardından Sistem Tercihleri'ni açın ve Klavye'ye, ardından Klavye Kısayolları » Hizmetler » Numaralar » Formülleri Kopyala'ya tıklayın. Bir klavye kısayolu yapılandırın; Tavsiye ederim ⌥⇧⌘Cçünkü muhtemelen zaten kısayolu olan meslektaşı Yapıştır ve Eşleme Stili ile birlikte kullanacaksınız ⌥⇧⌘V.