Bluetooth tethering'i komut satırını kullanarak nasıl başlatabilirim?

İPhone'umu kullanarak internete bağlanmaya başlamak için hızlı bir yol istiyorum, umarım sadece klavyeyi kullanarak. Bluetooth menüsünü kullanarak, cihazımın alt menüsünde Ağa Bağlan seçeneğini seçebilirim, ancak bunu otomatikleştirmek mümkün mü?

Sonunda bunu Alfred.app (çok harika) bir kısayola atamak istiyorum, ancak komut satırı veya AppleScript kullanan her şey işe yarayacak.

Mümkün mü? Teşekkürler!!

Bluetooth ile bu şekilde çalışmak için doğrudan bir AppleScript sözlüğü var gibi görünmüyor.

Bununla birlikte, temel olarak menü öğelerini vb. Seçmek için Mac OS'nin erişilebilirlik özelliğini kullanan GUI komut dizisini kullanabilirsiniz.

MacOSAutomation.com'da GUI AppleScript ile nasıl başlayacağınıza dair harika bir yazı var .

GUI otomasyonu, sürekli değişen bir şey listeniz varsa zor olabilir, ancak genellikle aynı kalan bluetooth öğelerinin bir listesi varsa, tamam olmanız gerekir.

Daha sonra bu AppleScript'i Alfred aracılığıyla çağırabilirsiniz.

http://macscripter.net/viewtopic.php?id=38559

Yukarıdaki linkte biraz güncellemiş olduğum çok güzel bir senaryo var. Blueutil [ git repo ] [ web sitesi / ikili dosyalar ] kullandığını unutmayın.

Bluetooth'u etkinleştir:

-- Enable Bluetooth and Connect to iPhone

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn on bluetooth.
if execBlueutil("status") contains "Status: off" then
    execBlueutil("on")

    connectDevice()

    doGrowl()

end if

on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

-- Connect Device
on connectDevice()
    tell application "System Preferences"
        activate
        set AppleScript's text item delimiters to "."
        set current pane to pane "com.apple.preference.network"
        set winNetwork to "Network"
        set btooth to "Bluetooth"

        tell application "System Events" to tell process "System Preferences"
            set theRow to row 1 of table 1 of scroll area 1 of window winNetwork whose value of static text 1 contains btooth
            select theRow --clicks the bluetooth row
            --If Bluetooth is already connected, the button will say Disconnect, so we don't want to turn it off:
            try
                click (button 1 of group 1 of window winNetwork whose title is "Connect")
            end try
        end tell
        tell application "System Preferences"
            quit
        end tell
    end tell
end connectDevice

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth is On & iPhone Connected" description ¬
                "Bluetooth has been enabled with iPhone tethered." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Bluetooth'u devre dışı bırak:

property blueutilPath : "/opt/local/bin/blueutil"

-- Turn off Bluetooth.
if execBlueutil("status") contains "Status: on" then
    execBlueutil("off")

    doGrowl()
end if
on execBlueutil(command)
    set res to do shell script blueutilPath & " " & command
    if res contains "Error" then
        display dialog res
        quit
    end if
    return res
end execBlueutil

on doGrowl()
    tell application "System Events"
        set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
    end tell
    if isRunning then
        tell application id "com.Growl.GrowlHelperApp"
            set the allNotificationsList to ¬
                {"Bluetooth Setting"}
            set the enabledNotificationsList to ¬
                {"Bluetooth Setting"}
            register as application ¬
                "AppleScript - Bluetooth" all notifications allNotificationsList ¬
                default notifications enabledNotificationsList

            notify with name ¬
                "Bluetooth Setting" title ¬
                "Bluetooth Off" description ¬
                "Bluetooth has been disabled." application name "AppleScript - Bluetooth" icon of file (path to me)
        end tell
    end if
end doGrowl

Bunun için otomatı kullanmanızı tavsiye ederim, kolaylaştırmak için Alfred'den arayabilirsiniz :)

Geçerli otomator iş akışım bunu yapıyor:

Click the "bluetooth" menu bar item.
Connect to Network

Bu yöntemi kullanarak bir dakika içinde neredeyse her şeyi otomatikleştirebilirsiniz