DMG dosyasını açarken, pencerelerin önünde açılmasını nasıl sağlayabilirim?

Ne zaman bir .dmgdosya indirip sonra açsam (genellikle Chrome'daki indirme çubuğundan), arka planda açılıyor. Penceremin önünde açılmasının bir yolu var mı?

Düzenle

Netleştirmek için: DMG penceresinin aktif pencere olarak açılmasını istiyorum.

Applescript'te istediğinizi yapabilecek bir Folder Action betiği hazırladım. Kopyalayıp yeni bir Applescript'e yapıştırın ve bir Uygulama olarak (başlangıç ​​diyaloğu olmadan!) "/ Library / Scripts / Folder Action Script /" dizinine kaydedin. Ardından, klasörü sağ tıklayıp hizmetler açılan menüsünden "klasör eylemlerini yapılandır" seçeneğini seçerek herhangi bir klasöre (büyük olasılıkla ~ / Yüklemeler / klasörünüz) ekleyebilirsiniz. Klasör Eylemlerini etkinleştirin ve komut dosyasının klasörü izlemesini sağlayın.

Kodun temelde yaptığı şey, bağlı olduğu klasöre bırakılan öğelere tepki verir ve bırakılan öğe Kind ise: "Image", "hdiutil" komut satırı aracı aracılığıyla Görüntüyü Birim olarak ekler.

Komut dosyasında openWindow ve makeFrontmost özelliklerini ayarlayarak davranışını yapılandırabilirsiniz; Bu, bir uygulama olarak kaydettikten sonra Komut Dosyasına çift tıklatarak da yapılabilir - daha sonra standart davranışının ne olması gerektiği hakkında iki diyalog halinde soracaktır.

Umarım bu yardımcı olur,

Asmus

 property openWindow : true
 property makeFrontmost : true

 on run

    display dialog "Do you want to bring the Finder to the front after new items are added?" buttons {"Don't Activate", "Activate"} default button 2
    if the button returned of the result is "Don't Activate" then
        set makeFrontmost to false
    else
        set makeFrontmost to true
    end if


    display dialog "Open Folder after adding new files?" buttons {"Don't Open", "Open"} default button 2
    if the button returned of the result is "Don't Open" then
        set openWindow to false
    else
        set openWindow to true
    end if


 end run

 on adding folder items to thisFolder after receiving addedItems

    repeat with i from 1 to number of items in addedItems
        set itemKind to the kind of (info for item i of addedItems) as string

        if itemKind is "Disk Image" then
            set itemPath to (quoted form of POSIX path of item i of addedItems)
            try
                showImage(itemPath)
            end try
        end if

    end repeat

 end adding folder items to


 on showImage(itemPath)

    set volumeMountpointInfo to do shell script "/usr/bin/hdiutil  attach " & itemPath & " | grep Volumes"


    if (openWindow is true) then
        if (makeFrontmost is true) then
            tell application "Finder" to activate
        end if

       set currentDelim to text item delimiters
       set text item delimiters to tab

       set volumeMountpoint to POSIX file (text item 3 of volumeMountpointInfo)

       set text item delimiters to currentDelim

       tell application "Finder" to open folder volumeMountpoint

    end if

 end showImage

====

Bir klasöre bırakılan dosyanın türünü belirlemek için ikinci Applescript

On adding folder items to thisFolder after receiving addedItems
repeat with i from 1 to number of items in addedItems
    set itemKind to the kind of (info for item i of addedItems) as string
    display dialog itemKind
end repeat
end adding folder items to

"Resim" yerine "Disk Görüntüsü" Olması Gerekiyor

Söyleyebileceğim kadarıyla OS X, salt okunursa, yalnızca bir disk görüntüsünün içeriğini otomatik olarak görüntüler. Bu, görüntünün içeriğini görüntülerken Finder penceresinin sol alt kısmında kesik çizgili bir kalemle belirtilir.

Bir disk görüntüsünü, bunu yapacak şekilde değiştirmek istiyorsanız, mevcut bir disk görüntüsünü Disk Utility programını kullanarak salt okunur yapabilirsiniz. Ne yazık ki, bu internetten indirebileceğiniz yanlış üretilmiş resimlerin davranışını değiştirmez.

1. Otomatik açmak istediğiniz disk görüntüsünü takın.
2. Spotlight ile arayarak Disk Yardımcı Programını açın.
3. Araç çubuğundaki "Yeni Resim" simgesini seçin.
4. Dosyayı adlandırın ve "Görüntü Biçimi" altında "salt okunur" u seçin.
5. "Kaydet" i tıklayın. Bu yeni resmi eklediğinizde, otomatik olarak bir Finder penceresi açılacaktır.

Bu muhtemelen soruyu da yeterince cevaplamıyor, ama ...

Komuta basar ve indirme çubuğundaki öğeye tıklarsanız, bulucudaki öğeyi gösterir. Bu noktada, sadece O komutuna basmak (veya dmg dosyasına çift tıklamak) onu kuracak ve ön planda yeni bir pencerede açacaktır.