İşaretli bir e-postayı ileten bir elma betiği nasıl oluşturulur

İşaretli bir e-postayı x@mail.asana.com adresine iletecek bir elma betiği oluşturmak istiyorum

Bu senaryoyu denedim:

on run

 tell application "Mail"
    repeat with _acct in imap accounts
        --Look For Flagged Messages in the INBOX
        set _acct_name to name of _acct
        set _inbox to _acct's mailbox "INBOX"

        set _msgs_to_capture to (a reference to ¬
            (every message of _inbox ¬
                whose flagged status is true))

        repeat with eachMessage in _msgs_to_capture
            set theStart to missing value
            set theDue to missing value
            set theOmniTask to missing value

            set theTitle to the subject of eachMessage
            set theNotes to the content of eachMessage

            set theCombinedBody to "message://%3c" & message id of eachMessage & "%3e" & return & return & theNotes

            tell application "OmniFocus"
                tell default document
                    set newTaskProps to {name:theTitle}
                    if theStart is not missing value then set newTaskProps to newTaskProps & {start date:theStart}
                    if theDue is not missing value then set newTaskProps to newTaskProps & {due date:theDue}
                    if theCombinedBody is not missing value then set newTaskProps to newTaskProps & {note:theCombinedBody}

                    set newTask to make new inbox task with properties newTaskProps
                end tell
            end tell

            set flagged status of eachMessage to false

        end repeat

    end repeat
end tell

end run

Ancak, bu komut dosyası yalnızca bir e-posta göndermek yerine OmniFocus'u açar.

Bu betiği nasıl değiştirebilirim veya yeni bir tane ile başlayabilirim ki işaretli bir e-postayı otomatik olarak x@mail.asana.com adresine yönlendirir?

İşaretli tüm mesajları ayarlanmış bir adrese ileten OmniFocus uygulamanıza referansta bulunmayan bazı kodlar. Beğeninize ayarlayın ....

Snow Leopard macbook'umdaki bir cazibe gibi çalışıyor.

set toAddress to "userx@mail.asana.com"
set toName to "User X"

tell application "Mail"
    repeat with _acct in imap accounts
        --Look For Flagged Messages in the INBOX
        set _acct_name to name of _acct
        set _inbox to _acct's mailbox "INBOX"
        set _msgs_to_capture to (a reference to ¬
            (every message of _inbox ¬
                whose flagged status is true))

        repeat with _msg in _msgs_to_capture
            set _fwdmsg to forward _msg with opening window

            tell _fwdmsg
                make new to recipient at end of ¬
                    to recipients with properties {name:toName, address:toAddress}
            end tell

            activate

            send _fwdmsg
        end repeat
    end repeat
end tell