PWM frekansını 25 kHz olarak ayarlayın

Şu anda dört PWM pini aşağıdaki kodla yaklaşık 31 kHz'e ayarlayabilirim:

void setup()
{
    TCCR1B = TCCR1B & B11111000 | B00000001; // Set PWM frequency for D9 & D10:
    pinMode(pwmPin9, OUTPUT); // Sets the pin as output
    pinMode(pwmPin10, OUTPUT); // Sets the pin as output


    TCCR2B = TCCR2B & B11111000 | B00000001; // Set PWM for D3 & D11
    pinMode(pwmPin3, OUTPUT); // Sets the pin as output
    pinMode(pwmPin11, OUTPUT); // Sets the pin as output
}

Bu kurulumu bir yerde buldum, ancak bu dört PWM pimini nasıl 25 kHz'e ayarlayabileceğimi bilmiyorum. Bu nasıl mümkün olabilir?

Bu ikinci cevabı, tek bir Arduino Uno'da 161 adımla 25 kHz'de 4 PWM kanalına sahip olmanın mümkün olduğunu fark ettiğim için gönderiyorum. Bu, ana saat frekansının 8 MHz olarak değiştirilmesini içerir , bu da tüm programın yarısı kadar hızlı çalışacağından bazı yan etkilere sahiptir. Ayrıca üç süreleri, Arduino zamanlama fonksiyonlarını kaybetme araçları yeniden yapılandırma içermektedir ( millis(), micros(), delay()ve delayMicroseconds()). Eğer bu değiş tokuşlar kabul edilebilirse, işte böyle gidiyor:

void setup()
{
    // Set the main system clock to 8 MHz.
    noInterrupts();
    CLKPR = _BV(CLKPCE);  // enable change of the clock prescaler
    CLKPR = _BV(CLKPS0);  // divide frequency by 2
    interrupts();

    // Configure Timer 0 for phase correct PWM @ 25 kHz.
    TCCR0A = 0;           // undo the configuration done by...
    TCCR0B = 0;           // ...the Arduino core library
    TCNT0  = 0;           // reset timer
    TCCR0A = _BV(COM0B1)  // non-inverted PWM on ch. B
        | _BV(WGM00);  // mode 5: ph. correct PWM, TOP = OCR0A
    TCCR0B = _BV(WGM02)   // ditto
        | _BV(CS00);   // prescaler = 1
    OCR0A  = 160;         // TOP = 160

    // Same for Timer 1.
    TCCR1A = 0;
    TCCR1B = 0;
    TCNT1  = 0;
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
        | _BV(COM1B1)  // same on ch. B
        | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
        | _BV(CS10);   // prescaler = 1
    ICR1   = 160;

    // Same for Timer 2.
    TCCR2A = 0;
    TCCR2B = 0;
    TCNT2  = 0;
    TCCR2A = _BV(COM2B1)  // non-inverted PWM on ch. B
        | _BV(WGM20);  // mode 5: ph. correct PWM, TOP = OCR2A
    TCCR2B = _BV(WGM22)   // ditto
        | _BV(CS20);   // prescaler = 1
    OCR2A  = 160;
}

void loop()
{
    analogWrite( 3,   1);  // duty cycle = 1/160
    analogWrite( 5,  53);  // ~ 1/3
    analogWrite( 9, 107);  // ~ 2/3
    analogWrite(10, 159);  // 159/160
}

Diğer cevabın aksine, bunun değiştirilmiş bir versiyonuna ihtiyacı yoktur analogWrite(): standart olan iyi çalışır. Sadece dikkatli olunmalıdır:

1. Yazılan değer, 0 (her zaman DÜŞÜK anlamına gelir) ile 160 (her zaman YÜKSEK) arasında olmalıdır.
2. Sadece 3, 5, 9 ve 10 pinleri mevcuttur. analogWrite() Pim 6 veya 11'e girişmek sadece bir PWM çıkışı iletmekle kalmaz, aynı zamanda pim 5 veya 3'teki frekansı da değiştirir.

Zamanlayıcı 1'i faz doğru PWM modunda 25 kHz'de dönecek şekilde yapılandırabilir ve 9 ve 10 pinlerinde iki çıkışı aşağıdaki gibi kullanabilirsiniz:

// PWM output @ 25 kHz, only on pins 9 and 10.
// Output value should be between 0 and 320, inclusive.
void analogWrite25k(int pin, int value)
{
    switch (pin) {
        case 9:
            OCR1A = value;
            break;
        case 10:
            OCR1B = value;
            break;
        default:
            // no other pin will work
            break;
    }
}

void setup()
{
    // Configure Timer 1 for PWM @ 25 kHz.
    TCCR1A = 0;           // undo the configuration done by...
    TCCR1B = 0;           // ...the Arduino core library
    TCNT1  = 0;           // reset timer
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
           | _BV(COM1B1)  // same on ch; B
           | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
           | _BV(CS10);   // prescaler = 1
    ICR1   = 320;         // TOP = 320

    // Set the PWM pins as output.
    pinMode( 9, OUTPUT);
    pinMode(10, OUTPUT);
}

void loop()
{
    // Just an example:
    analogWrite25k( 9, 110);
    analogWrite25k(10, 210);
    for (;;) ;  // infinite loop
}

0 ile bir değer yazmak analogWrite25k()pimin her zaman DÜŞÜK olacağı anlamına gelirken, 320 her zaman YÜKSEK anlamına gelir. Düzenli analogWrite() gerektiği neredeyse eser, ancak 255 (yani her zaman YÜKSEK) 320 ile aynı yorumlayacaktır.

Bu kod bir Arduino Uno veya benzeri bir kartı (ATmega168 veya 328 @ 16 MHz) varsayar. Burada kullanılan yöntem 16 bitlik bir zamanlayıcı gerektirir ve bu nedenle Uno'da kullanılabilen tek zamanlayıcı olduğu için Zamanlayıcı 1'i kullanır; bu yüzden sadece iki çıkış mevcuttur. Yöntem, 16 bitlik bir zamanlayıcı ile diğer AVR tabanlı kartlara uyarlanabilir. Gerben'in belirttiği gibi, bu zamanlayıcının karşılık gelen bir ICRx kaydına sahip olması gerekir. Arduino Mega'da her biri 3 çıkışlı 4 zamanlayıcı var.