Çok sayıda kullanıcı olduğunda DROP USER çok uzun sürüyor

Yeterli RAM ve hızlı disklere sahip bir SQL Server 2014 örneğinde, bir veritabanına erişimi olan 160'tan fazla kullanıcı vardır. Herhangi bir sebepten ötürü bana göre, DROP USER [username]bu veritabanında komutun çalıştırılması kullanıcı başına 5 saniye kadar sürüyor.

Kullanıcıları oturum açma işlemleriyle yeniden eşleştirmek ve izinlerini geri yüklemek çok hızlıdır.

DEV veritabanlarını üretimden yenileme bağlamında, tüm veritabanı kullanıcılarını bırakıp yeniden oluşturmam gerekiyor. Bu yüzden evet veritabanı kullanıcılarını bırakmak ve onları yeniden oluşturmak gereklidir.

DROP USERKomutu nasıl hızlandırabilirim ?

Unutmayın, hakkında yazdığım örnek için 160 defa çalıştırmam gerekiyor.

Bu kullanıyorum SQL:

DECLARE drop_user_cur CURSOR FOR 
SELECT name FROM #drop_users

OPEN drop_user_cur
FETCH NEXT FROM drop_user_cur INTO @user

WHILE @@FETCH_STATUS = 0
BEGIN
    SET @sql = 'use [' + @db_name + '] DROP USER [' + @user + ']'
    BEGIN TRY
        print @sql
        EXECUTE(@sql)
    END TRY
    BEGIN CATCH
        print 'ERREUR : ' + @sql
    END CATCH
    FETCH NEXT FROM drop_user_cur INTO @user
END

CLOSE drop_user_cur
DEALLOCATE drop_user_cur

Sorun imleçten gelmiyor; DROP USER5 saniye süren gerçek .

sp_whoisactiveBunu kullanarak , wait_type kullanılır NULL.

Süreye dikkat etmeyin DROPve CREATE USERbir WHILEdöngü içinde çalıştırılıyorlar, bu yüzden bir dakikadan fazla diyor.

Profiler yürütmek için 125.000'den fazla okuma gösterir DROP USER.

Hizmet Aracısı etkin değil.

Bu soruna çözüm, veritabanında hizmet aracısı etkinleştirildi.

ALTER DATABASE [Database_name] SET NEW_BROKER WITH ROLLBACK IMMEDIATE;

Veritabanı için hizmet komisyoncusu etkinleştirildikten sonra, bırakma kullanıcıları pratik olarak anlıkdı.

Kin, servis aracının bana doğru yönde arama gönderen önceki bir yorumda etkinleştirilip etkinleştirilmediğini sordu.

bu sorunun cevabı değil, tamamen reddetmek için bir argüman.

Yorumunuzu doğru anlarsam:

DEV veritabanlarını üretimden yenileme bağlamında, tüm veritabanı kullanıcılarını bırakıp yeniden oluşturmam gerekiyor. Bu yüzden evet veritabanı kullanıcılarını bırakmak ve onları yeniden oluşturmak gereklidir.

Amacınız üretim verilerini bir dev sistemine kopyalamak ve aynı kullanıcı adlarını kullanarak üretim ile aynı izinle çalışmasını sağlamaktır .

En hızlı yol, bu kb makalesinde ms tarafından açıklanan prosedürü kullanarak üretim sisteminden dev sistem girişlerini dev sistemine klonlamaktır .

ms tarafından tanımlanan yordamla, sonuç, dev sunucunuzdaki veritabanlarını geri yükleyebilmeniz ve izinte değişiklik yapılmadan çalışılmasıdır.

Bir sql 2005 üretim env hem test ve dev sql 2012 ortamlarına kopyalamak için yukarıda belirtilen yordamı başarıyla kullandım.
Kullanıcıları klonladıktan sonra, basit bir veritabanı geri yüklemesi beni güncel verilerle tamamen çalışan bir çift yeni sisteme yönlendirdi.

Bu çözümün en büyük artısı, dev verilerini yenilemek için sadece üretim veritabanını geri yüklemeniz ve bu kadar; referansları, eşanlamlıları ve benzerlerini ayarlamanız gerekecektir, ancak izinler bozulmayacaktır.

Makaleden kod, sadece referans amaçlıdır, ancak lütfen eski sql sürümleriyle uyumluluk, şifre şifreleme ayrıntıları ve oturum açma işlemlerini sunucular arasında aktarırken bazı baş ağrısından kurtarabilecek diğer bilgilerle ilgili açıklamalara ve ayrıntılara sahip makaleye bakın:

USE master
GO
IF OBJECT_ID ('sp_hexadecimal') IS NOT NULL
  DROP PROCEDURE sp_hexadecimal
GO
CREATE PROCEDURE sp_hexadecimal
    @binvalue varbinary(256),
    @hexvalue varchar (514) OUTPUT
AS
DECLARE @charvalue varchar (514)
DECLARE @i int
DECLARE @length int
DECLARE @hexstring char(16)
SELECT @charvalue = '0x'
SELECT @i = 1
SELECT @length = DATALENGTH (@binvalue)
SELECT @hexstring = '0123456789ABCDEF'
WHILE (@i <= @length)
BEGIN
  DECLARE @tempint int
  DECLARE @firstint int
  DECLARE @secondint int
  SELECT @tempint = CONVERT(int, SUBSTRING(@binvalue,@i,1))
  SELECT @firstint = FLOOR(@tempint/16)
  SELECT @secondint = @tempint - (@firstint*16)
  SELECT @charvalue = @charvalue +
    SUBSTRING(@hexstring, @firstint+1, 1) +
    SUBSTRING(@hexstring, @secondint+1, 1)
  SELECT @i = @i + 1
END

SELECT @hexvalue = @charvalue
GO

IF OBJECT_ID ('sp_help_revlogin') IS NOT NULL
  DROP PROCEDURE sp_help_revlogin
GO
CREATE PROCEDURE sp_help_revlogin @login_name sysname = NULL AS
DECLARE @name sysname
DECLARE @type varchar (1)
DECLARE @hasaccess int
DECLARE @denylogin int
DECLARE @is_disabled int
DECLARE @PWD_varbinary  varbinary (256)
DECLARE @PWD_string  varchar (514)
DECLARE @SID_varbinary varbinary (85)
DECLARE @SID_string varchar (514)
DECLARE @tmpstr  varchar (1024)
DECLARE @is_policy_checked varchar (3)
DECLARE @is_expiration_checked varchar (3)

DECLARE @defaultdb sysname

IF (@login_name IS NULL)
  DECLARE login_curs CURSOR FOR

      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM 
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name <> 'sa'
ELSE
  DECLARE login_curs CURSOR FOR


      SELECT p.sid, p.name, p.type, p.is_disabled, p.default_database_name, l.hasaccess, l.denylogin FROM 
sys.server_principals p LEFT JOIN sys.syslogins l
      ON ( l.name = p.name ) WHERE p.type IN ( 'S', 'G', 'U' ) AND p.name = @login_name
OPEN login_curs

FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
IF (@@fetch_status = -1)
BEGIN
  PRINT 'No login(s) found.'
  CLOSE login_curs
  DEALLOCATE login_curs
  RETURN -1
END
SET @tmpstr = '/* sp_help_revlogin script '
PRINT @tmpstr
SET @tmpstr = '** Generated ' + CONVERT (varchar, GETDATE()) + ' on ' + @@SERVERNAME + ' */'
PRINT @tmpstr
PRINT ''
WHILE (@@fetch_status <> -1)
BEGIN
  IF (@@fetch_status <> -2)
  BEGIN
    PRINT ''
    SET @tmpstr = '-- Login: ' + @name
    PRINT @tmpstr
    IF (@type IN ( 'G', 'U'))
    BEGIN -- NT authenticated account/group

      SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' FROM WINDOWS WITH DEFAULT_DATABASE = [' + @defaultdb + ']'
    END
    ELSE BEGIN -- SQL Server authentication
        -- obtain password and sid
            SET @PWD_varbinary = CAST( LOGINPROPERTY( @name, 'PasswordHash' ) AS varbinary (256) )
        EXEC sp_hexadecimal @PWD_varbinary, @PWD_string OUT
        EXEC sp_hexadecimal @SID_varbinary,@SID_string OUT

        -- obtain password policy state
        SELECT @is_policy_checked = CASE is_policy_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name
        SELECT @is_expiration_checked = CASE is_expiration_checked WHEN 1 THEN 'ON' WHEN 0 THEN 'OFF' ELSE NULL END FROM sys.sql_logins WHERE name = @name

            SET @tmpstr = 'CREATE LOGIN ' + QUOTENAME( @name ) + ' WITH PASSWORD = ' + @PWD_string + ' HASHED, SID = ' + @SID_string + ', DEFAULT_DATABASE = [' + @defaultdb + ']'

        IF ( @is_policy_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_POLICY = ' + @is_policy_checked
        END
        IF ( @is_expiration_checked IS NOT NULL )
        BEGIN
          SET @tmpstr = @tmpstr + ', CHECK_EXPIRATION = ' + @is_expiration_checked
        END
    END
    IF (@denylogin = 1)
    BEGIN -- login is denied access
      SET @tmpstr = @tmpstr + '; DENY CONNECT SQL TO ' + QUOTENAME( @name )
    END
    ELSE IF (@hasaccess = 0)
    BEGIN -- login exists but does not have access
      SET @tmpstr = @tmpstr + '; REVOKE CONNECT SQL TO ' + QUOTENAME( @name )
    END
    IF (@is_disabled = 1)
    BEGIN -- login is disabled
      SET @tmpstr = @tmpstr + '; ALTER LOGIN ' + QUOTENAME( @name ) + ' DISABLE'
    END
    PRINT @tmpstr
  END

  FETCH NEXT FROM login_curs INTO @SID_varbinary, @name, @type, @is_disabled, @defaultdb, @hasaccess, @denylogin
   END
CLOSE login_curs
DEALLOCATE login_curs
RETURN 0
GO

Buna benzer bir imleç çalışmalı

Use DB_name

declare @username varchar(50)
declare user_cursor cursor for select '['+name+']' from sys.database_principals where type in ('u', 's') and principal_id>4
open user_cursor
fetch next from user_cursor into @username
while (@@fetch_status=0)
begin
EXEC sp_dropuser @username
fetch next from user_cursor into @username
end
close user_cursor
deallocate user_cursor
go