Hiçbir cümlecik olmadan <table> 'den büyük bir DELETE' i hızlandırma yöntemleri

SQL Server 2005'i kullanma.

Hiçbir cümlecik olmadan büyük bir DELETE FROM yapıyorum. Temel olarak bir TRUNCATE TABLE ifadesine eşdeğerdir - TRUNCATE kullanmama izin verilmiyor hariç. Sorun tablo büyük - 10 milyon satır ve tamamlanması bir saatten fazla sürüyor. Olmadan daha hızlı yapmanın bir yolu var mı:

• Kısaltmayı Kullanma
• Dizinleri devre dışı bırakma veya bırakma?

T-log zaten ayrı bir diskte.

Herhangi bir öneriniz hoş geldiniz!

Ne yapabilirsiniz toplu iş böyle siler:

SELECT 'Starting' --sets @@ROWCOUNT
WHILE @@ROWCOUNT <> 0
    DELETE TOP (xxx) MyTable

Xxx'in 50000 olduğu yerde

Bunun bir modifikasyonu, çok yüksek bir satır yüzdesini kaldırmak istiyorsanız ...

SELECT col1, col2, ... INTO #Holdingtable
           FROM MyTable WHERE ..some condition..

SELECT 'Starting' --sets @@ROWCOUNT
WHILE @@ROWCOUNT <> 0
    DELETE TOP (xxx) MyTable WHERE ...

INSERT MyTable (col1, col2, ...)
           SELECT col1, col2, ... FROM #Holdingtable

Bunu kolayca yapmak için TOP yan tümcesini kullanabilirsiniz:

WHILE (1=1)
BEGIN
    DELETE TOP(1000) FROM table
    IF @@ROWCOUNT < 1 BREAK
END

TRUNCATE kullanamıyorsanız, silme işlemlerinizi yönetilebilir parçalara ayırma önerileriyle aynı fikirdeyim ve orijinalliği için bırakma / oluşturma önerisini seviyorum, ancak sorunuzdaki şu yorumu merak ediyorum:

Temel olarak bir TRUNCATE TABLE ifadesine eşdeğerdir - TRUNCATE kullanmama izin verilmemesi dışında

Bu kısıtlamanın nedeninin bir masayı doğrudan kesmek için verilmesi gereken güvenlikle ve ilgilendiğinizden başka masaları kesmenize izin vereceği gerçeğiyle ilgili olduğunu tahmin ediyorum.

Durumun böyle olduğunu varsayarak, TRUNCATE TABLE kullanarak ve "EXECUTE AS" kullanan bir saklı yordamın oluşturulup yaratılmadığını merak ediyorum, masayı doğrudan kesmek için gerekli güvenlik haklarını vermenin uygun bir alternatif olarak kabul edilip edilmeyeceğini düşünüyorum.

Umarım, bu size ihtiyacınız olan hızı verirken, şirketinizin db_ddladmin rolüne hesabınızı eklerken sahip olabileceği güvenlik kaygılarını da ele alır.

Saklı yordamın bu şekilde kullanılmasının bir başka avantajı da saklı yordamın kilitlenebilmesi ve böylece yalnızca belirli hesapların kullanmasına izin verilmesidir.

Herhangi bir nedenden ötürü bu kabul edilebilir bir çözüm değilse ve bu tablodaki verilerin kaldırılması gerekliliği günde / saatte bir kez yapılması gereken bir şeyse, tabloyu kesmek için bir SQL Agent işi oluşturulmasını isterim. Her gün planlanan bir zamanda.

Bu yardımcı olur umarım!

Kesik hariç .. sadece gruplar halinde silmek size yardımcı olabilir.

Masayı bırakıp tüm kısıtlamalar ve indekslerle kursun dışı bırakabilirsiniz. Management Studio'da düşünüp oluşturulacak bir tabloyu kodlama seçeneğiniz vardır, bu nedenle önemsiz bir seçenek olmalıdır. Ancak bu yalnızca DDL işlemleri yapmanıza izin veriliyorsa, ki bunun gerçekten bir seçenek olmadığını görüyorum.

Bu soru çok önemli bir referans olduğu için bu kodu gönderip gerçekten döngüleri silmeyi ve ilerlemeyi izlemek için bir döngü içinde mesajlaşmayı anlamama yardımcı oldu.

Sorgu bu yinelenen sorudan değiştirildi . Sorgu tabanı için @ RRL'ye kredi verin .

CREATE TABLE #DelTest (ID INT IDENTITY, name NVARCHAR(128)); -- Build the test table
INSERT INTO #DelTest (name) SELECT name FROM sys.objects;  -- fill from system DB
SELECT COUNT(*) TableNamesContainingSys FROM #deltest WHERE name LIKE '%sys%'; -- check rowcount
go
DECLARE @HowMany INT;
DECLARE @RowsTouched INT;
DECLARE @TotalRowCount INT;
DECLARE @msg VARCHAR(100);
DECLARE @starttime DATETIME 
DECLARE @currenttime DATETIME 

SET @RowsTouched = 1; -- Needs to be >0 for loop to start
SET @TotalRowCount=0  -- Total rows deleted so far is 0
SET @HowMany = 5;     -- Variable to choose how many rows to delete per loop
SET @starttime=GETDATE()

WHILE @RowsTouched > 0
BEGIN
   DELETE TOP (@HowMany)
   FROM #DelTest 
   WHERE name LIKE '%sys%';

   SET @RowsTouched = @@ROWCOUNT; -- Rows deleted this loop
   SET @TotalRowCount = @TotalRowCount+@RowsTouched; -- Increment Total rows deleted count
   SET @currenttime = GETDATE();
   SELECT @msg='Deleted ' + CONVERT(VARCHAR(9),@TotalRowCount) + ' Records. Runtime so far is '+CONVERT(VARCHAR(30),DATEDIFF(MILLISECOND,@starttime,@currenttime))+' milliseconds.'
   RAISERROR(@msg, 0, 1) WITH NOWAIT;  -- Print message after every loop. Can't use the PRINT function as SQL buffers output in loops.  

END; 
SELECT COUNT(*) TableNamesContainingSys FROM #DelTest WHERE name LIKE '%sys%'; -- Check row count after loop finish
DROP TABLE #DelTest;