Emacs izin verilen tavsiye

Bir parça koddaki bir işlevi geçici olarak geçersiz kılmak istiyorum.

Örneğin, aşağıdakileri ele alalım:

(defun nadvice/load-quiet (args)
  (cl-destructuring-bind
      (file &optional noerror nomessage nosuffix must-suffix)
      args
    (list file noerror t nosuffix must-suffix)))

(defun nadvice/idle-require-quiet (old-fun &rest args)
    (advice-add 'load :filter-args #'nadvice/load-quiet)
    (apply old-fun args)
    (advice-remove #'load #'nadvice/load-quiet))

(advice-add 'idle-require-load-next :around #'nadvice/idle-require-quiet)

Ne işe yaramaz:

• Bu. Tavsiyeyi manuel olarak etkinleştirmeyi ve devre dışı bırakmayı önleyebilir ve Emacs'ın işlere bakmak için tek iş parçacıklı doğasına güvenebilirsem çok daha temiz olurdu.
• cl-letforijinal işleve başvurmama izin vermeyecek, bu yüzden :filter-argsnormalde yapacak şeyleri uygulayamam .
• cl-flet diğer işlevlerdeki işlevleri geçersiz kılamaz.
• nofletkaçınmak istediğim harici bir paket. (Ayrıca ihtiyacımdan çok daha fazlasını yapar)

(cl-)letfOrijinal fonksiyona kendiniz referans verirken kullanamaz mısınız?

Bunun gibi bir şey:

;; Original function
(defun my-fun (arg)
  (message "my-fun (%s)" arg))


;; Standard call
(my-fun "arg") ;; => my-fun (arg)


;; Temporary overriding (more or less like an around advice)
(let ((orig-fun (symbol-function 'my-fun)))
  (letf (((symbol-function 'my-fun)
          (lambda (arg)
            ;; filter arguments
            (funcall orig-fun (concat "modified-" arg)))))
    (my-fun "arg")))
;; => my-fun (modified-arg)


;; The overriding was only temporary
(my-fun "arg") ;; => my-fun (arg)

Yeniden kullanmayı planlıyorsanız, bunu bir makroya da ekleyebilirsiniz:

(defmacro with-advice (args &rest body)
  (declare (indent 1))
  (let ((fun-name (car args))
        (advice   (cadr args))
        (orig-sym (make-symbol "orig")))
    `(cl-letf* ((,orig-sym  (symbol-function ',fun-name))
                ((symbol-function ',fun-name)
                 (lambda (&rest args)
                   (apply ,advice ,orig-sym args))))
       ,@body)))

Yukarıdaki örnek daha sonra aşağıdaki gibi yeniden yazılabilir:

(defun my-fun (arg)
  (message "my-fun (%s)" arg))


(my-fun "my-arg")

(with-advice (my-fun
              (lambda (orig-fun arg)
                (funcall orig-fun (concat "modified-" arg))))
  (my-fun "my-arg"))

(my-fun "my-arg")