Şeffaf bir “düz geçiş” işlev sargısı nasıl yazılır?

"Şeffaf" düz geçişli "işlev sarmalayıcı" ile kastettiğim, bir işlevdir, diyelim wrapperki, tüm argümanını başka bir işleve geçirmekten sonuç döndürür, diyelim wrappee.

Emacs Lisp'de bu nasıl yapılır?

Dikkat: İdeal wrapperişlev, işlevin imzası hakkında agnostiktirwrappee ; yani wrappeeargümanlarının sayısı, pozisyonları, isimleri vb. hakkında hiçbir şey bilmiyor ; tüm argümanlarını wrappeetıpkı wrappeebaşlangıçta çağrılmış gibi geçirir . (Ancak, çağrıyı yerine wrapperbir çağrıyla değiştirmek için çağrı yığınıyla uğraşmanıza gerek yoktur wrappee.)

Soruma kısmi bir cevap gönderdim :

(defun wrapper (&rest args) (apply 'wrappee args))

Bu sadece çalışır wrappeeolduğunu değil interaktif. Görünüşe göre, etkileşimli işlevlerin argümanlarını alma şekli, (&rest args)büyünün kapsadığı şeyden farklı bir "kanalı" temsil eder . Bu yüzden hala ihtiyacım olan şey, etkileşimli bir işlevin olduğu durumun imzasının eşit wrappeederecede agnostik bir karşılığıdır .(&rest args)wrappee

(Bu soru, bu önceki soruda açıklanan bir sorunla motive edildi .)

İstediğim şeyin daha fazla açıklanması gerekirse, aşağıda Python ve JavaScript eşdeğerlerini gösteren birkaç örnek verilmiştir.

Python'da böyle bir ambalajı uygulamak için birkaç standart yol aşağıda gösterilmiştir:

def wrapper(*args, **kwargs):
    return wrappee(*args, **kwargs)

# or

wrapper = lambda *args, **kwargs: wrappee(*args, **kwargs)

(Burada *args"tüm konumsal bağımsız değişkenler", **kwargs"tüm anahtar kelime bağımsız değişkenleri" anlamına gelir.)

JavaScript eşdeğeri şuna benzer:

function wrapper () { return wrappee.apply(this, arguments); }

// or

wrapper = function () { return wrappee.apply(this, arguments); }

Kayıt için, bu sorunun Mapcar'ı birden çok argümanı olan bir işleve nasıl uygulayacağının bir kopyası olduğunu kabul etmiyorum . Nedenini açıklamakta zorlanıyorum, çünkü iki soru benim için çok farklı görünüyor. "Bir elmanın neden bir portakal ile eşdeğer sayılmaması gerektiğini açıklamak" gibi bir soru soruluyor. Sadece o kadar çılgınca bir soru ki, kişinin soran kişiyi tatmin edecek bir cevap bulabileceğinden şüphe ediyor.

Tabii ki interactiveşartname dahil etmek mümkündür . Burada elisp ile uğraşıyoruz ! (Lisp, en önemli yapıların listeler olduğu dildir. Çağrılabilir formlar sadece listelerdir. Böylece istediğiniz gibi yapılandırabilirsiniz.)

Uygulama: Bazı işlevlere otomatik olarak bazı işlevler eklemek istiyorsunuz. Genişletilmiş işlevlere defadviceuygulanamayacak yeni adlar verilmelidir .

İlk önce tam olarak amacınıza uyan bir versiyon. fsetSembolün işlev hücresini ( ) wrappergerekli tüm bilgilerle ayarlıyoruz ve wrappeeekstra öğelerimizi ekliyoruz.

Her iki wrappeetanım için de çalışır . İlk sürümü wrappeeinteraktif, ikincisi değil.

(defun wrappee (num str)
  "Nontrivial wrappee."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee (num str)
  "Noninteractive wrappee."
  (message "The number is %d.\nThe string is \"%s\"." num str))

(fset 'wrapper (list 'lambda
             '(&rest args)
             (concat (documentation 'wrappee t) "\n Wrapper does something more.")
             (interactive-form 'wrappee)
             '(prog1 (apply 'wrappee args)
            (message "Wrapper does something more."))))

Ancak, genişletilmiş işlevleri oluşturan bir makro tanımlamak daha uygundur. Bundan sonra işlev adlarını bile belirtebiliriz. (Otomatik sürüm için iyidir.)

Aşağıdaki kodu yürüttükten sonra wrapper-interactiveetkileşimli ve etkileşimli wrapper-non-interactiveolmayan çağrı yapabilirsiniz .

(defmacro make-wrapper (wrappee wrapper)
  "Create a WRAPPER (a symbol) for WRAPPEE (also a symbol)."
  (let ((arglist (make-symbol "arglist")))
  `(defun ,wrapper (&rest ,arglist)
     ,(concat (documentation wrappee) "\n But I do something more.")
     ,(interactive-form wrappee)
     (prog1 (apply (quote ,wrappee) ,arglist)
       (message "Wrapper %S does something more." (quote ,wrapper))))))

(defun wrappee-interactive (num str)
  "That is the doc string of wrappee-interactive."
  (interactive "nNumber:\nsString:")
  (message "The number is %d.\nThe string is \"%s\"." num str))

(defun wrappee-non-interactive (format &rest arglist)
  "That is the doc string of wrappee-non-interactive."
  (apply 'message format arglist))

(make-wrapper wrappee-interactive wrapper-interactive)
(make-wrapper wrappee-non-interactive wrapper-non-interactive)
;; test of the non-interactive part:
(wrapper-non-interactive "Number: %d, String: %s" 1 "test")

Şimdiye kadar, deklarasyon formlarını aktarmak için henüz bir yol bulamadım, ancak bu da mümkün olmalı.

Ben çok benzer bir sorunu çözmek zorunda kaldı nadvice.el, bu yüzden burada bir çözüm (hangi nadvice.el kodundan bazılarını kullanır):

(defun wrapper (&rest args)
  (interactive (advice-eval-interactive-spec
                (cadr (interactive-form #'wrappee))))
  (apply #'wrappee args))

Şimdiye kadar yayınlanan diğer çözümlerle karşılaştırıldığında, wrappeefarklı bir etkileşimli özellikle yeniden tanımlanırsa (yani eski spesifikasyonu kullanmaya devam etmez) , bu doğru çalışma avantajına sahiptir .

Tabii ki, ambalajınızın gerçekten şeffaf olmasını istiyorsanız, daha basit bir şekilde yapabilirsiniz:

(defalias 'wrapper #'wrappee)

edit: Tobias'ın cevabı, tam etkileşimli formu ve sarılmış fonksiyonun öğretisini elde ettiği için bundan daha güzel.

Aaron Harris ve kjo'nun cevaplarını birleştirerek, şöyle bir şey kullanabilirsiniz:

(defmacro my-make-wrapper (fn &optional name)
  "Return a wrapper function for FN defined as symbol NAME."
  `(defalias ',(or (eval name)
                   (intern (concat "my-" (symbol-name (eval fn)) "-wrapper")))
     (lambda (&rest args)
       ,(format "Generic wrapper for %s."
                (if (symbolp (eval fn))
                    (concat "`" (symbol-name (eval fn)) "'")
                  fn))
       (interactive)
       (if (called-interactively-p 'any)
           (call-interactively ,fn)
         (apply ,fn args)))))

Kullanımı:

(my-make-wrapper 'find-file 'wrapper-func)

Aşağıdakilerden birini içeren çağrı sarmalayıcısı:

(wrapper-func "~/.emacs.d/init.el")

M-x wrapper-func