TeX formüllerini satır içi olarak rastgele modlarda nasıl önizleyebilirim?

TeX önizlemelerini AUCTeX veya kuruluş modu dışındaki modlarda nasıl alabilirim? Jabber, erc ve markdown'da TeX denklemlerini görmek isterim. E-posta için Emacs'a geçersem, muhtemelen orada önizlemeleri görmek isterim.

AUCTeX önizleme lateksini tekrar kullanmaya çalıştım ama başarısız oldum ve vazgeçtim.

Kuruluş modu da aynı özelliği sağlar . Dönüşler dışında weechat yeniden kullanımı başardı otomatik önizleme lateks göstermek için.

Ben bu repo alabilirsiniz ayrı bir dosyada weechat önizleme bölümünü ayıkladım . Ayrıca pxMELPA'da paket olarak da mevcut (sadece gönderdim).

Etkileşimli olarak çağrılabilen 4 giriş noktası vardır:

• px-preview: geçerli arabellekteki tüm lateks parçalarını oluşturur.
• px-preview-region: Bölgede parçalar oluşturur.
• px-remove: geçerli arabellekteki tüm önizlemeleri kaldır (metni geri yükle).
• px-toggle: geçerli arabellekteki önizlemelerin görüntülenmesini aç / kapat.

Kuruluş modu önizleyicisi çalıştığı sürece, bu olmalıdır.

Kod hala oldukça küçük olduğundan aşağıya ekleyeceğim, ancak lütfen paketi yükleyin veya repoyu kullanın.

;;; px.el --- preview inline latex -*- lexical-binding: t -*-

;; Most of this code comes from weechat-latex.el which in turn uses
;; org-mode previewer.

;; Copyright (C) 2014 Aurélien Aptel <aurelien.aptel@gmail.com>
;; Copyright (C) 2013 Rüdiger Sonderfeld <ruediger@c-plusplus.de>

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

(require 'org)

(defvar px-temp-file-prefix "px-"
  "Prefix for temporary files.")

(defvar px-temp-directory-prefix "px-"
  "Prefix for temporary directory.")

(defvar px-image-program org-latex-create-formula-image-program
  "Program to convert LaTeX fragments.
See `org-latex-create-formula-image-program'")

(defvar px-temp-dir nil
  "The temporary directory used for preview images.")

(defun px--create-preview (at)
  "Wrapper for `org-format-latex'.
The parameter AT should be nil or in (TYPE . POINT) format.  With TYPE being a
string showing the matched LaTeX statement (e.g., ``$'') and POINT being the
POINT to replace.  If AT is nil replace statements everywhere."
  (org-format-latex px-temp-file-prefix
                    px-temp-dir
                    'overlays
                    "Creating images...%s"
                    at 'forbuffer
                    px-image-program))

(defun px--set-temp-dir ()
  "Set `px-temp-dir' unless it is already set."
  (unless px-temp-dir
    (setq px-temp-dir
          (make-temp-file px-temp-directory-prefix
                          'directory))))

(defun px-preview ()
  "Preview LaTeX fragments."
  (interactive)
  (save-excursion
    (let ((inhibit-read-only t))
      (px--set-temp-dir)
      (org-remove-latex-fragment-image-overlays)
      (px--create-preview nil))))

(defun px-preview-region (beg end)
  "Preview LaTeX fragments in region."
  (interactive "r")
  (let* ((math-regex (assoc "$" org-latex-regexps))
         (regex (nth 1 math-regex))
         (n (nth 2 math-regex))
         matches)
    (save-excursion
      (goto-char beg)
      (while (re-search-forward regex end t)
        (setq matches (cons (cons "$" (match-beginning n)) matches)))
      (let ((inhibit-read-only t))
        (px--set-temp-dir)
        (dolist (i matches)
          (px--create-preview i))))))


(defun px-remove ()
  "Remove LaTeX preview images."
  (interactive)
  (let ((inhibit-read-only t))
    (org-remove-latex-fragment-image-overlays)))

(defun px-is-active? ()
  "Are LaTeX Previews currently displayed?"
  org-latex-fragment-image-overlays)

(defun px-toggle ()
  "Toggle display of LaTeX preview."
  (interactive)
  (if (px-is-active?)
      (px-remove)
    (px-preview)))


(provide 'px)

Ayrıca texfrag.eldoxygen yorumları için kutudan çıkan da var prog-mode.

Sen yükleyebilir texfrag.elgelen melpa-stablearacılığıyla M-x package-install RET texfrag RET.

M-x texfrag-mode RETÖnizlemeyi etkinleştirmek için çalıştırın . Önizleme menüsünü AUCTeX önizleme paketinin tüm öğeleriyle birlikte alırsınız.

Bunun texfraghtml kaynağı, eww ve org modunu düzenlemek için de işe yaradığını unutmayın .