Bölge ve / veya çizgiyi sağa nasıl hizalayabilirim?

Metni M-x center-regionve ile ortalayabiliriz M-o M-s. Sağa hizalama için benzer bir şey var mı?

Önceki örnek:

Item 0: value                                                       |
Item 100: value                                                     |
Item 30: value                                                      |

sonra:

                                                       Item 0: value|
                                                     Item 100: value|
                                                      Item 30: value|
                                                       fill-column  ^

Metni sağa hizalamanın en kolay yolu nedir?

Dolgudaki manuel düğüme göre , doldurma işlevlerinin birçoğu kullanabileceğiniz isteğe bağlı bir JUSTIFY bağımsız değişkeni alır. Örneğin, bir paragrafı doğru gerekçe ile doldurmak için kullanabilirsiniz (fill-paragraph 'right).

(justify-current-line 'right)Tek bir satır için de kullanabilirsiniz .

Bu seçenekleri çok kullanmayı planlıyorsanız, bunları aşağıdaki gibi işlevlere sarabilir ve daha sonra bu işlevleri istediğiniz tuşlara bağlayabilirsiniz:

(defun right-justify-current-line ()
  "Right-justify this line."
  (interactive)
  (justify-current-line 'right))

(defun right-fill-paragraph ()
  "Fill paragraph with right justification."
  (interactive)
  (fill-paragraph 'right))

Yedek olarak bırakabileceğiniz bir işlev fill-paragraph. Çeşitli öneklerle, doldurduğunuz paragrafta ne tür bir gerekçe kullanacağınıza karar vermenize izin verir:

(defun fill-paragraph-dwim (&optional arg)
  "Fills the paragraph as normal with no prefix. With C-u,
right-justify.  With C-u C-u, center-justify.  With C-u C-u C-u,
full-justify."
  (interactive "p")
  (fill-paragraph (cond ((= arg 4)  'right)
                        ((= arg 16) 'center)
                        ((= arg 64) 'full))))

Sağa hizalarken doldurmak istemiyorsanız , doğrudan hizadan çıkarmak center-regioniçin tek satırlık bir değişiklikle doğrudan işlevden alınan aşağıdaki işlevi kullanabilirsiniz :

(defun right-region (from to)
  "Right-justify each nonblank line starting in the region."
  (interactive "r")
  (if (> from to)
      (let ((tem to))
    (setq to from from tem)))
  (save-excursion
    (save-restriction
      (narrow-to-region from to)
      (goto-char from)
      (while (not (eobp))
    (or (save-excursion (skip-chars-forward " \t") (eolp))
        ;; (center-line))              ; this was the original code
        (justify-current-line 'right)) ; this is the new code
    (forward-line 1)))))