`sil-yinelenen satırları` boş satırları ve belirli kelimeleri yoksay

Bir metni org modunda düzenliyorum, aynı konudaki farklı dosyaların bir parçası olduğu için birkaç satır tekrarlanıyor.

delete-duplicate-linesTekrarlanan satırları silmek için kullanmak istiyorum , ancak komut, istemediğim bir şey olan boş satırları da kaldırır (aksi takdirde paragrafları olmazdı!). Satırlarda tek başına var olan bazı kelimeleri görmezden gelmek istiyorum, örneğin, "Sürdür" , metinde birçok kez tekrarlanır, ancak gerektiğinden tutmak istiyorum.

text-editing

— shackra
kaynak

Boş satırları yok sayma

delete-duplicate-linesBoş satırları arayarak yok saymayı söyleyebilirsiniz .

C-u C-u C-u M-x delete-duplicate-lines RET

Aradığınızda C-ubirçok kez vurmak istemiyorsanız delete-duplicate-lines, bunu özel bir komutta sarabilir ve bu komutu istediğiniz bir tuş dizisine bağlayabilirsiniz:

(defun delete-duplicate-lines-keep-blanks ()
  (interactive)
  (delete-duplicate-lines (region-beginning) (region-end) nil nil t))

(global-set-key (kbd "C-c d") 'delete-duplicate-lines-keep-blanks)

Normal ifade ile eşleşen satırlar yoksayılıyor

Sorunuzun ikinci kısmına gelince, yerleşik sürümünü kullanarak istediğinizi elde edebileceğinizi sanmıyorum delete-duplicate-lines. Bununla birlikte, komutun değiştirilmiş bir sürümünü kullanabilirsiniz (varsayılan olarak boş satırları da tutar):

(defun delete-duplicate-lines
    (beg end keep &optional reverse adjacent keep-blanks interactive)
  (interactive
   (progn
     (barf-if-buffer-read-only)
     (list (region-beginning) (region-end)
           (read-string "Keep lines matching regexp: ") ; Prompt for regexp to keep
           (equal current-prefix-arg '(4))
           (equal current-prefix-arg '(16))
           t                                            ; Keep blanks by default
           t)))
  (let ((lines (unless adjacent (make-hash-table :test 'equal)))
        line prev-line
        (count 0)
        (beg (copy-marker beg))
        (end (copy-marker end)))
    (save-excursion
      (goto-char (if reverse end beg))
      (if (and reverse (bolp)) (forward-char -1))
      (while (if reverse
             (and (> (point) beg) (not (bobp)))
               (and (< (point) end) (not (eobp))))
        (setq line (buffer-substring-no-properties
                (line-beginning-position) (line-end-position)))
        (if (or (and keep-blanks (string= "" line))
                (string-match keep line))               ; Ignore line if it
                                                        ; matches regexp to keep
            (forward-line 1)
          (if (if adjacent (equal line prev-line) (gethash line lines))
              (progn
                (delete-region (progn (forward-line 0) (point))
                               (progn (forward-line 1) (point)))
                (if reverse (forward-line -1))
                (setq count (1+ count)))
            (if adjacent (setq prev-line line) (puthash line t lines))
            (forward-line (if reverse -1 1))))))
    (set-marker beg nil)
    (set-marker end nil)
    (when interactive
      (message "Deleted %d %sduplicate line%s%s"
               count
               (if adjacent "adjacent " "")
               (if (= count 1) "" "s")
               (if reverse " backward" "")))
    count))

Bu sürümü delete-duplicate-linessizden bir regexp isteyecek ve regexp ile eşleşen tüm satırları koruyacaktır. Örneğin, yapacağınız kelimeden oluşan tüm satırları tutmak Resumeiçin:

M-x delete-duplicate-lines RET ^Resume$ RET

— itsjeyd
kaynak