Kuruluş-yapı-şablon-listeye # + BEGIN_ # + END_ dışında şablonlar eklemek mümkün müdür?

Org-structure-template-alist'in otomatik olarak genişletilmesi için değiştiğini (org modu sürüm 9.2 kullanıyorum) fark ettim #+BEGIN_<some block tag> #+END_<some block tag>. Farklı türde şablonlar eklemenin mümkün olup olmadığını merak ediyorum. Örneğin bir :PROPERTIES:<some properties>:END:şablon.

Mümkün mü yoksa yasnippets gibi başka bir pakete mi dönmeliyim?

GÜNCELLEME:

Kuruluş Modu 9.2'ninorg-structure-template-alist yalnızca "#+BEGIN_"ve tarafından tanımlanan bloklar için olan şablon genişletme mekanizmasını değiştirdiğini fark etmedim"#+END_" . Ve benzeri giriş ("p" ":PROPERTIES:?:END:")artık kabul edilmiyor.

Yukarıdaki bağlantıda belirtildiği gibi, diğer "karmaşık" şablon işlev tarafından tanımlanabilir tempo-define-templateve org-tempo yüklenmelidir ( (require 'org-tempo)). Aslında, girişleri yoluyla tarafından org-structure-template-alist dönüştürülür ve varsayılan olarak:org-tempo-tagstempo-define-templateorg-tempoorg-tempo-tags

(("<i" . tempo-template-org-index)
 ("<A" . tempo-template-org-ascii)
 ("<H" . tempo-template-org-html)
 ("<L" . tempo-template-org-latex)
 ("<v" . tempo-template-org-verse)
 ("<s" . tempo-template-org-src)
 ("<q" . tempo-template-org-quote)
 ("<l" . tempo-template-org-export-latex)
 ("<h" . tempo-template-org-export-html)
 ("<E" . tempo-template-org-export)
 ("<e" . tempo-template-org-example)
 ("<C" . tempo-template-org-comment)
 ("<c" . tempo-template-org-center)
 ("<a" . tempo-template-org-export-ascii)
 ("<I" . tempo-template-org-include))

Durumunuz için bir şablon tanımlayabilirsiniz:

(tempo-define-template "my-property"
               '(":PROPERTIES:" p ":END:" >)
               "<p"
               "Insert a property tempate")

Aşağıdaki yanıt yalnızca 9.2'den önceki Kuruluş modu sürümü için geçerlidir

Evet, buna şöyle bir giriş ekleyebilirsiniz:

(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))

Daha sonra org dosyasına, yazın <pve TABözelliği genişler ve noktayı konumunda bırakır ?.

Ve değişkenin belgelerinde daha fazla ayrıntı yazarak bulabilirsiniz C-h v org-structure-template-alist RET.

Kuruluş kipinin özelleştirilmesinde uyumsuz değişiklikler yapma sıklığı gerçekten üzücü.

Aşağıdaki kod, 9.2 sürümünden önceki kuruluş modunun eski yapı şablonlarını verir. İşlev org-complete-expand-structure-template, 9.1 sürümünden alınan saf bir kopyadır ve 9.1 sürümünden org-try-structure-completionbiraz değiştirilmiş bir sürümüdür. (Buraya bir tür kontrol ekledim.)

Bu kodu yükledikten sonra eski şablonunuzu
(add-to-list 'org-structure-template-alist '("p" ":PROPERTIES:?:END:"))
tekrar kullanabilirsiniz.

(defvar org-structure-template-alist)

(defun org+-avoid-old-structure-templates (fun &rest args)
  "Call FUN with ARGS with modified `org-structure-template-alist'.
Use a copy of `org-structure-template-alist' with all
old structure templates removed."
  (let ((org-structure-template-alist
     (cl-remove-if
      (lambda (template)
        (null (stringp (cdr template))))
      org-structure-template-alist)))
    (apply fun args)))

(eval-after-load "org"
  '(when (version<= "9.2" (org-version))
     (defun org-try-structure-completion ()
       "Try to complete a structure template before point.
This looks for strings like \"<e\" on an otherwise empty line and
expands them."
       (let ((l (buffer-substring (point-at-bol) (point)))
         a)
     (when (and (looking-at "[ \t]*$")
            (string-match "^[ \t]*<\\([a-zA-Z]+\\)$" l)
            (setq a (assoc (match-string 1 l) org-structure-template-alist))
            (null (stringp (cdr a))))
       (org-complete-expand-structure-template (+ -1 (point-at-bol)
                              (match-beginning 1)) a)
       t)))

     (defun org-complete-expand-structure-template (start cell)
       "Expand a structure template."
       (let ((rpl (nth 1 cell))
         (ind ""))
     (delete-region start (point))
     (when (string-match "\\`[ \t]*#\\+" rpl)
       (cond
        ((bolp))
        ((not (string-match "\\S-" (buffer-substring (point-at-bol) (point))))
         (setq ind (buffer-substring (point-at-bol) (point))))
        (t (newline))))
     (setq start (point))
     (when (string-match "%file" rpl)
       (setq rpl (replace-match
              (concat
               "\""
               (save-match-data
             (abbreviate-file-name (read-file-name "Include file: ")))
               "\"")
              t t rpl)))
     (setq rpl (mapconcat 'identity (split-string rpl "\n")
                  (concat "\n" ind)))
     (insert rpl)
     (when (re-search-backward "\\?" start t) (delete-char 1))))

     (advice-add 'org-tempo-add-templates :around #'org+-avoid-old-structure-templates)

     (add-hook 'org-tab-after-check-for-cycling-hook #'org-try-structure-completion)

     (require 'org-tempo)
     ))