* Derleme * penceresini gizle

20

Başarılı olduğunda derleme penceresinin görünmesi can sıkıcı bir durumdur. Bunu otomatik olarak nasıl kaldırabilirim?

Eğer başarılı olmazsa görmek istiyorum.

window compilation

— Husain
kaynak

11

yıl önce #emacs IRC kanalında sonsuza kadar kullandığım bu kod parçasını aldım. "2 sn" değeri, başarılı derleme penceresinin görünür kalacağı süreyi ayarlar.

; from enberg on #emacs
(setq compilation-finish-function
  (lambda (buf str)
    (if (null (string-match ".*exited abnormally.*" str))
        ;;no errors, make the compilation window go away in a few seconds
        (progn
          (run-at-time
           "2 sec" nil 'delete-windows-on
           (get-buffer-create "*compilation*"))
          (message "No Compilation Errors!")))))

— shapr
kaynak

14

Koda hızlı bir şekilde (kütüphanede compile.el) baktığınızda, sadece kancadaki bir işlevi kullanarak görüntülenen arabelleği öldürebilir veya gizleyebilirsiniz compilation-finish-functions. Bunu yapmak için şöyle bir şey kullanın:

 (add-hook 'compilation-finish-functions (lambda (buf strg) (kill-buffer buf))

Tamponu öldürmek istemiyorsanız, böyle bir şey kullanın:

 (add-hook 'compilation-finish-functions
           (lambda (buf strg)
             (let ((win  (get-buffer-window buf 'visible)))
               (when win (delete-window win)))))

Genel olarak, böyle bir şey için muhtemelen zaten bir kanca olduğunu hayal edebilirsiniz, böylece işlemde böylesine önemli bir yere kolayca kod ekleyebilirsiniz. Koda biraz göz atmak veya kullanmak M-x aproposgenellikle hızlı bir şekilde size bildirir. Kancaların adları genellikle -hookveya ile biter -functions.

— Drew
kaynak

2

Bu konu, bazılarının ilgilenmesi durumunda da geçerlidir:

/programming/11043004/emacs-compile-buffer-auto-close

Kredi orijinal yazar jpkotta gider . İşte cevabı:

Derleme için aşağıdakileri kullanıyorum. Uyarılar veya hatalar varsa derleme arabelleğini tutar ve aksi takdirde (1 saniye sonra) gömer.

(defun bury-compile-buffer-if-successful (buffer string)
  "Bury a compilation buffer if succeeded without warnings "
  (if (and
       (string-match "compilation" (buffer-name buffer))
       (string-match "finished" string)
       (not
        (with-current-buffer buffer
          (search-forward "warning" nil t))))
      (run-with-timer 1 nil
                      (lambda (buf)
                        (bury-buffer buf)
                        (switch-to-prev-buffer (get-buffer-window buf) 'kill))
                      buffer)))
(add-hook 'compilation-finish-functions 'bury-compile-buffer-if-successful)

— Swarnendu Biswas
kaynak

1

Lütfen yalnızca bağlantıdan oluşan bir yanıt göndermeyin . Cevabınızın önemli kısımlarını yazınıza ekleyin, böylece yayınınız soruyu yanıtlar. Bağlantıyı kaynak olarak ve daha fazla bilgi için sağlayın. Daha fazla bilgi için lütfen cevap yazma hakkındaki yönergelerimizi okuyun .

— Gilles 'SO- kötü olmayı bırak'

Cevabım güncellendi.

— Swarnendu Biswas

O Not bunu Stack Exchange başkasının cevabı alıntı tamam ama sağlamalıdır uygun atıfları yazarın adı dahil.

— Gilles 'SO- kötü olmayı bırak'

1

Bu parçacığı benim var .emacs.d:

    (defcustom compilation-auto-quit-window-delay 1
      "Time in seconds before auto closing the window."
      :group 'compilation
      :type 'number)  

    (defun compilation-auto-quit-window-finish-function (buffer status)
      "Quit the *compilation* window if it went well."
      (let ((window (get-buffer-window buffer)))
        (when (and (equal status "finished\n")
                   (compilation-went-super-p))
          (run-with-timer
              (or compilation-auto-quit-window-delay 0) nil
            (lambda nil
              (when (and (window-live-p window)
                         (eq (window-buffer window)
                             buffer)
                         (not (eq (selected-window)
                                  window)))
                (save-selected-window
                  (quit-window nil window))))))))

    (define-minor-mode compilation-auto-quit-window
      "Automatically close the *compilation* window if it went well."
      :global t
      (cond (compilation-auto-quit-window
             (add-hook 'compilation-finish-functions
                       'compilation-auto-quit-window-finish-function))
            (t
             (remove-hook 'compilation-finish-functions
                          'compilation-auto-quit-window-finish-function))))

    (defun compilation-went-super-p (&optional buffer)
      "Return t, if no gotoable output appeared."
      (with-current-buffer (or buffer (current-buffer))
        (save-excursion
          (goto-char (point-min))
          (let (;; (compilation-skip-threshold 1)
                )
            (not (ignore-errors
                   (compilation-next-error 1)
                   t))))))

— politza
kaynak