Bir imleç döngüsünde kullanmak için birden çok sütunu nasıl getirebilirim?

Aşağıdaki SQL parçacığını bir imleç döngüsü içinde çalıştırmayı denediğimde,

set @cmd = N'exec sp_rename ' + @test + N',' +
           RIGHT(@test,LEN(@test)-3) + '_Pct' + N',''COLUMN'''

Aşağıdaki mesajı alıyorum,

Msg 15248, Düzey 11, Durum 1, Prosedür sp_rename, Satır 213
Parametre @objnamebelirsiz veya talep edilen @objtype(COLUMN) yanlış.

Yanlış olan nedir ve bunu nasıl düzeltirim? Sütun adını köşeli parantez []ve ""bazı arama sonuçlarının önerdiği gibi çift ​​tırnak içine almayı denedim .

Düzenle 1 -

İşte tüm senaryo. Tablo adını sp yeniden adlandırmaya nasıl iletirim? Sütun adları birçok tablodan birinde yer aldığı için bunu nasıl yapacağımdan emin değilim.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
declare @cmd nvarchar(500) 
declare Tests cursor for
SELECT COLUMN_NAME FROM INFORMATION_SCHEMA.COLUMNS WHERE COLUMN_NAME LIKE 'pct%' AND TABLE_NAME LIKE 'TestData%'

open Tests
fetch next from Tests into @test
while @@fetch_status = 0
BEGIN
  set @cmd = N'exec sp_rename ' + @test + N',' + RIGHT(@test,LEN(@test)-3) + '_Pct' + N', column' 

  print @cmd

  EXEC sp_executeSQL @cmd

  fetch next from Tests into @test
END

close Tests 
deallocate Tests


ROLLBACK TRANSACTION
--COMMIT TRANSACTION

Düzenleme 2 - Komut dosyası, adları bir kalıpla eşleşen sütunları, bu durumda bir "pct" öneki ile yeniden adlandırmak için tasarlanmıştır. Sütunlar, veritabanı içindeki çeşitli tablolarda yer alır. Tüm tablo adlarının önünde "TestData" bulunur.

İşte biraz değiştirilmiş versiyon. Değişiklikler kod açıklaması olarak not edilir.

BEGIN TRANSACTION

declare @cnt int
declare @test nvarchar(128)
-- variable to hold table name
declare @tableName nvarchar(255)
declare @cmd nvarchar(500) 
-- local means the cursor name is private to this code
-- fast_forward enables some speed optimizations
declare Tests cursor local fast_forward for
 SELECT COLUMN_NAME, TABLE_NAME
   FROM INFORMATION_SCHEMA.COLUMNS 
  WHERE COLUMN_NAME LIKE 'pct%' 
    AND TABLE_NAME LIKE 'TestData%'

open Tests
-- Instead of fetching twice, I rather set up no-exit loop
while 1 = 1
BEGIN
  -- And then fetch
  fetch next from Tests into @test, @tableName
  -- And then, if no row is fetched, exit the loop
  if @@fetch_status <> 0
  begin
     break
  end
  -- Quotename is needed if you ever use special characters
  -- in table/column names. Spaces, reserved words etc.
  -- Other changes add apostrophes at right places.
  set @cmd = N'exec sp_rename ''' 
           + quotename(@tableName) 
           + '.' 
           + quotename(@test) 
           + N''',''' 
           + RIGHT(@test,LEN(@test)-3) 
           + '_Pct''' 
           + N', ''column''' 

  print @cmd

  EXEC sp_executeSQL @cmd
END

close Tests 
deallocate Tests

ROLLBACK TRANSACTION
--COMMIT TRANSACTION