UltiSnips ve YouCompleteMe

Macvim'imde paket ultisnips ve youcompleteme yüklü. Sorun, sekme ycm'ye bağlı olduğu için ultisnips'in çalışmamasıdır. let g:UltiSnipsExpandTrigger = "<s-tab>"Snippet tamamlamasını shift-tab ile tetikleyebilmek için koymayı denedim , ancak bilinmeyen bir nedenden dolayı çalışmıyor. Tetik olarak büyük harf kullanabilirdim, ancak şimdiye kadar bunu yapmanın bir yolunu bulamadım.

Bu iki eklentiyi birlikte kullanan var mı? Vardiya sekmesinin çalışmasını sağlamak için ne yapabilirim? Parçacıkları tetiklemek için başka bir anahtar önerebilir misiniz?

Diğer bir seçenek ise SuperTab eklentisini kullanmaktır:

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Burada YouCompleteMe farklı bir kombinasyona bağlıdır Ctrln, ancak daha sonra bu kombinasyon SuperTab aracılığıyla sekmeye bağlanır. UltiSnips ve SuperTab birlikte güzel çalışır, böylece UltiSnips'i doğrudan sekmeye bağlayabilirsiniz ve her şey yoluna girecektir.

YouCompleteMe sorun izleyicisinden bir sayfada bu öneriyi deneyin . .Vimrc dosyanızda:

let g:UltiSnipsExpandTrigger="<c-j>"

Bu ayar, bir parçacığı genişletmenin bir parçacık içinde ileri atlamak için varsayılan eşlemeyi paylaşmasını sağlarken, UltiSnips yardım etiketlerinde belirtildiği gibi TextMates'in davranışını simüle eder.

Caps Lock tuşumu Ctrl ile eşlediğim için bu eşleme oldukça sorunsuz çalışıyor.

Aşağıdaki kodu vimrc'nize kopyalayın ve keyfini çıkarın. Bu işlev, YCM ve UltiSnips arasındaki tüm sorunları çözecektir.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

bu benim vimrc'imde var

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

Bu ilk denememde yaptığım şeydi, ancak UltiSnips'i Ultisnips ile yanlış yazdım .. oh iyi, sonunda işe yaradı!

Kişisel <tab>olarak YouCompleteMe ile kullanmayı değil, manuel olarak gezinmeyi seçtim .

Ben de şunu ekledim .vimrc:

let g:ycm_key_list_select_completion=[]
let g:ycm_key_list_previous_completion=[]

bu da tabYCM anahtarını devre dışı bırakır . Bunun yerine hareket tuşlarını (oklar veya CTRL-N/ CTRL-P) kullanın ve girişi ile seçin CR. UltiSnips varsayılan olarak tab.

Michaelslec, Joey Liu'nun cevaplarını bir araya getirerek ve bu konu başlığında bulduğum çözümlerle ve bu adamın vimrc'iyle birlikte , şimdi hemen hemen tüm sorunları çözen buna sahibim.

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippet()
  if g:ulti_expand_res == 0
    if pumvisible()
      return "\<C-n>"
    else
      call UltiSnips#JumpForwards()
      if g:ulti_jump_forwards_res == 0
        return "\<TAB>"
      endif
    endif
  endif
  return ""
endfunction

function! g:UltiSnips_Reverse()
  call UltiSnips#JumpBackwards()
  if g:ulti_jump_backwards_res == 0
    return "\<C-P>"
  endif

  return ""
endfunction


if !exists("g:UltiSnipsJumpForwardTrigger")
  let g:UltiSnipsJumpForwardTrigger = "<tab>"
endif

if !exists("g:UltiSnipsJumpBackwardTrigger")
  let g:UltiSnipsJumpBackwardTrigger="<s-tab>"
endif

au InsertEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger     . " <C-R>=g:UltiSnips_Complete()<cr>"
au InsertEnter * exec "inoremap <silent> " .     g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Bu yazının biraz eski olduğunu bilmeme rağmen, yukarıda verilenden biraz daha optimize edilmiş kendi işlevim var:

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Tabii ki, Joey Liu'nun sağladığı ayarları koruduğunuzda ve sonra sadece bu işlevi kullanırsanız, her şey mükemmel şekilde çalışacaktır!

DÜZENLEME: Ayrıca, YouCompleteMe ve UltiSnips arasında geri adım atma işlevini artırmak için başka bir işlev kullanıyorum. Ne demek istediğimi sana göstereceğim:

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Sonra bunu .vimrc dosyanıza koyun:

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Yanı sıra let g:UltiSnipsJumpBackwardTrigger="<s-tab>"ve setiniz!

İkisini birlikte kullanıyorum. Varsayılan YouCompleteMe bağlamalar ile <Tab>ve <Down>ayrıca bir sonraki tamamlama öğeyi ve seçmek için <S-Tab>ve <Up>önceki tamamlama öğeyi seçin. YouCompleteMe bağlamalarını g: ycm_key_list_select_completion ve g: ycm_key_list_previous_completion seçenekleriyle değiştirebilirsiniz. Bu seçeneklerin adlarının, seçenek tek bir dizeden dizeler listesine dönüştürüldüğünde yakın zamanda değiştirildiğine dikkat edin.

UltiSnips eklentisini YouCompleteMe eklentisinden sonra kurdum, bu yüzden çelişkili olduklarını düşündüm, ancak gerçekte daha müdahaleci bir şeyim vardı:

set paste

.vimrcVarsa onu çıkardığınızdan emin olun .

Pek çok cevap bu yazıda iyi çalışsa da, sorunun YCM ve UltiSnip arasındaki anahtar bağlanma çarpışmasından kaynaklandığını söylemek istiyorum, YCM varsayılan olarak UltiSnip parçacıkları desteklerken <tab>, tamamlama seçme anahtarı olarak varsayılan UltiSnip genişletme tetikleyicisini alır , bu nedenle UltiSnip parçacıkları, tarafından genişletilmeyecektir <tab>. Onlara farklı anahtar bağlama vermek sorunu çözecek, kişisel olarak <c-nve <c-p>YCM için kullanıyorum ve UltiSnip için varsayılanı <tab>kullanıyorum. help youcompletemeVim'deki doc ile daha fazla ayrıntı alabilirsiniz .

Siegfried'in cevabına göre, daha doğal görünen aşağıdakileri kullanıyorum:

let g:ycm_key_list_select_completion = ['<C-j>']
let g:ycm_key_list_previous_completion = ['<C-k>']

let g:UltiSnipsExpandTrigger = "<C-l>"
let g:UltiSnipsJumpForwardTrigger = "<C-j>"
let g:UltiSnipsJumpBackwardTrigger = "<C-k>"

c-hjklBağlamaları başka bir yerde de kullanıyorum (bir bölmeden diğerine geçiyorum), ancak bu yalnızca normal modda olacak, bu yüzden sorun yok.

Kullandığım ;UltiSnips genişletmek için, bu benim için çok şık var

let g:UltiSnipsExpandTrigger = ";"

Ben kullanıyorum kj. Bu benim .vimrc:

let g:UltisnipsExpandTrigger="kj".

İçinde olan kelimeyle karşılaşmam nadiren oluyor kj. Bu durumda, yazdıktan sonra birkaç saniye beklerim kve bu tür j.

Başkalarının da bahsettiği gibi, Cj'yi ultisnips ile eşleştirmek harika çalışıyor.
let g:UltiSnipsExpandTrigger="<c-j>"

Şimdi, biraz daha ileri gidip xcape'i kurup kullanırsanız
xcape -e "Shift_L=Control_R|J"

Uçtan uca ipuçları için sadece shift tuşunu kullanmanın gücünü açığa çıkarırsınız.