Gnuplot içindeki döngü yapısı?

Birden fazla dosyadan yinelemeli olarak veri almanın ve bunları gnuplot'ta aynı grafikte çizmenin herhangi bir yolu var mı? Data1.txt, data2.txt ...... data1000.txt gibi dosyalarım olduğunu varsayalım; her biri aynı sayıda sütuna sahip. Şimdi şöyle bir şey yazabilirim-

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

Ancak bu gerçekten sakıncalı olacaktır. Gnuplot'ta olay örgüsü kısmında döngü yapmanın bir yolu olup olmadığını merak ediyordum .

Elbette (gnuplot 4.4+ sürümünde):

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

Değişken i, değişken veya dize olarak yorumlanabilir, böylece

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

satırların birbirinden uzak olmasını istiyorsanız.

Tip help iterationfazla bilgi için gnuplot komut satırına.

Ayrıca @ DarioP'nin do forsözdizimi hakkındaki yanıtını gördüğünüzden emin olun ; bu size geleneksel bir fordöngüye daha yakın bir şey verir .

do { ... }Gnuplot 4.6'dan beri çok güçlü olduğu için komuta da bir göz atın :

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

Bende all.p

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

Burada son iki satır, sezgisel değil gerçek anlamındadır. Sonra koşarım

$ gnuplot -p all.p

Sahip *.datolduğunuz dosya türünü değiştirin veya dosya türleri ekleyin.

Sonraki adım: Bu satıra ~ / .bashrc ekleyin

alias p='gnuplot -p ~/./all.p'

ve dosyanızı all.pana dizininize ve işinize yerleştirin . P yazıp enter ile herhangi bir dizindeki tüm dosyaları çizebilirsiniz.

EDIT İşe yaramadığı için komutu değiştirdim. Daha önce içeriyordu list(i)=word(system(ls -1B *.dat),i).

Bir grafikte çizmek için ayrı sütunlarınız varsa aşağıdakileri kullanın

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

Herhangi bir dizinden çalışırken, genellikle farklı dizinlere yerleştirilmiş birden çok dosyayı çizmek için joker karakterler kullanmak istedim. Bulduğum çözüm, aşağıdaki işlevi oluşturmaktı.~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

ve bunu, örneğin , geçerli dizindeki tüm dosyaları ve bir dizindeki tüm dosyaları bir seviye yukarı olan ve çağrılan plo *.dat ../../dir2/*.outtüm .datdosyaları çizmek için kullanın ..outdir2

İşte alternatif komut:

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'