Göreli yoldan ve / veya dosya adından mutlak yolu çözümleme

Windows toplu komut dosyasında, dosya adı ve / veya göreli yol içeren bir değerden mutlak bir yol döndürmenin bir yolu var mı?

Verilen:

"..\"
"..\somefile.txt"

Toplu iş dosyasına göre mutlak yol gerekir.

Misal:

• "somefile.txt", "C: \ Foo \" konumunda bulunur
• "test.bat" "C: \ Foo \ Bar" içinde bulunur.
• Kullanıcı "C: \ Foo" da bir komut penceresi açar ve Bar\test.bat ..\somefile.txt
• Toplu iş dosyasında "C: \ Foo \ somefile.txt" %1

Toplu dosyalarda, standart C programlarında olduğu gibi, 0 bağımsız değişkeni o anda yürütülmekte olan komut dosyasının yolunu içerir. %~dp00. bağımsız değişkenin (geçerli komut dosyası olan) yalnızca yol bölümünü almak için kullanabilirsiniz - bu yol her zaman tam nitelikli bir yoldur.

Kullanarak ilk argümanınızın tam yolunu da alabilirsiniz %~f1, ancak bu geçerli çalışma dizinine göre bir yol verir, ki bu kesinlikle istediğiniz şey değildir.

Şahsen, %~dp0%~1toplu iş dosyamdaki deyimi sık sık kullanıyorum , bu da ilk argümanı yürütme toplu işleminin yoluna göre yorumlar. Yine de bir eksikliği var: ilk argüman tam olarak nitelendirilirse sefil bir şekilde başarısız olur.

Her iki akraba desteklemek gerekirse ve mutlak yolları, sen yararlanabilir Frédéric Menez çözümüyle : geçici olarak geçerli çalışma dizini değiştirin.

İşte bu tekniklerin her birini gösterecek bir örnek:

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

Bunu c: \ temp \ example.bat olarak kaydederseniz ve c: \ Users \ Public as

c: \ Kullanıcılar \ Herkese Açık> \ temp \ example.bat .. \ windows

... şu çıktıyı gözlemleyeceksiniz:

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

toplu iş argümanında izin verilen değiştirici kümesine ilişkin belgeleri burada bulabilirsiniz: https://docs.microsoft.com/en-us/windows-server/administration/windows-commands/call

Bu sabah benzer bir ihtiyaçla karşılaştım: göreceli bir yolu bir Windows komut komut dosyasının içindeki mutlak bir yola nasıl dönüştürürüm.

Aşağıdaki hile yaptı:

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

Bu cevapların çoğu karmaşık ve süper buggy üzerinde deli gibi görünüyor, işte benim - herhangi bir ortam değişkeni üzerinde çalışıyor, hayır %CD%veya PUSHD/ POPDveya for /fsaçmalık - sadece düz eski toplu işlevler. - Dizin ve dosyanın var olması bile gerekmez.

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~f1
  EXIT /B

Bağımsız değişkenleri başka bir toplu iş dosyasına aktarmak zorunda kalmadan (ve bağımsız değişken işleçlerini kullanmak zorunda kalmadan) şunları kullanabilirsiniz FOR /F:

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

burada iin %%~fi, adresinde tanımlanan değişkendir /F %%i. Örneğin. Eğer bunu değiştirirseniz /F %%a, son bölüm olurdu %%~fa.

Aynı şeyi komut isteminde (toplu iş dosyasında değil) %%yapmak için %...

Bu Adrien Plisson'ın cevabındaki boşlukları doldurmaya yardımcı olmak için (onu düzenler düzenlemez kaldırılması gerekir ;-):

% ~ f1 kullanarak ilk argümanınızın tam yolunu da alabilirsiniz, ancak bu geçerli yola göre bir yol verir, ki bu kesinlikle istediğiniz şey değildir.

ne yazık ki, birlikte nasıl karıştırılacağı bilmiyorum ...

Birisi de idare edebilir %0ve %1aynı şekilde:

• %~dpnx0tam toplu sürücü + yol + adı + toplu dosyanın kendisi uzantısı için
  %~f0de yeterlidir;
• %~dpnx1tam argüman + yol + isim + ilk argümanının genişletilmesi için [bu bir dosya adı ise]
  %~f1da yeterlidir;

%~f1ilk argümanınızı nasıl belirttiğinizden bağımsız olarak çalışır: göreli yollarla veya mutlak yollarla (adlandırma sırasında dosyanın uzantısını belirtmezseniz %1, kullansanız bile eklenmez%~dpnx1 .

Ama başka bir sürücüdeki bir dosyayı nasıl adlandırırsınız , ilk etapta komut satırında tam yol bilgisini vermeyecekseniz, ?

Ancak, %~p0 , %~n0, %~nx0ve %~x0uzantısı veya yalnızca dosya ismi uzantısı ile, (driveletter olmadan) yolu ile ilgilenen olmalıdır kullanışlı (uzantı olmadan) dosya adı, tam dosya adı gelebilir. Ama dikkat, süre %~p1ve %~n1ilk argüman yolunu veya adını bulmak için çalışacak, %~nx1ve %~x1+ ekle zaten komut satırında kullandı sürece, uzantıyı görünmez.

Bunun için toplu iş işlevlerini de kullanabilirsiniz:

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

BrainSlugs83'ün mükemmel çözümünde küçük bir gelişme . Aramadaki çıkış ortamı değişkeninin adlandırılmasına izin vermek için genelleştirilmiştir.

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

C:\projectÇıktıdan çalıştır :

C:\project\doc\build

Bu soruna çok fazla çözüm görmedim. Bazı çözümler CD kullanarak dizin geçişini kullanırken, diğerleri toplu işlevleri kullanır. Kişisel tercihim toplu işlevler ve özellikle MakeAbsolute içindi tarafından sağlanan işlevi olmuştur.

Bu işlevin bazı gerçek faydaları vardır, öncelikle geçerli çalışma dizininizi değiştirmez ve ikinci olarak değerlendirilen yolların var olması bile gerekmez. Burada işlevi nasıl kullanacağınıza ilişkin bazı yararlı ipuçları bulabilirsiniz .

İşte örnek bir komut dosyası ve çıktıları:

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

Ve çıktı:

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

Umarım bu yardımcı olur ... Kesinlikle bana yardımcı oldu :) PS DosTips için tekrar teşekkürler! Harikasın!

Bunları birleştirebilirsiniz.

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

yolunuzun ortasında \ .. \ ile garip görünüyor ama çalışıyor. Çılgınca bir şey yapmaya gerek yok :)

Örneğin, Bar \ test.bat dosyasında, DIR / B / S .. \ somefile.txt tam yolu döndürür.

PowerShell bu günlerde oldukça yaygındır, bu yüzden hemen hemen her şey için işlevleri olduğundan C #'yi çağırmanın hızlı bir yolu olarak kullanırım:

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

Biraz yavaş, ancak gerçek bir komut dosyası diline başvurmadan elde edilen işlevselliği yenmek zor.

stijn'in çözümü aşağıdaki alt klasörler ile çalışır C:\Program Files (86)\,

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

Dosyalar Diğer tüm cevapları görün

Dizinler

İle ..senin göreli yol olma ve varsayarak Şu anda bulunduğunuz D:\Projects\EditorProject:

cd .. & cd & cd EditorProject (göreceli yol)

mutlak yol döndürür örn.

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b