CMake ile CCache Nasıl Kullanılır?

Aşağıdakileri yapmak istiyorum: PATH'de CCache varsa, derleme için "ccache g ++" kullanın, yoksa g ++ kullanın. Küçük bir my-cmake betiği yazmayı denedim

    CC="ccache gcc" CXX="ccache g++" cmake $*

ancak çalışmıyor gibi görünüyor (make çalıştırmak hala ccache kullanmıyor; bunu CMAKE_VERBOSE_MAKEFILE üzerinde kullanarak kontrol ettim).

Güncelleme:

Gereğince bu bağlantı Ben benim komut değiştirme çalıştı

     cmake -D CMAKE_CXX_COMPILER="ccache" -D CMAKE_CXX_COMPILER_ARG1="g++" -D CMAKE_C_COMPILER="ccache" -D CMAKE_C_COMPILER_ARG1="gcc" $*

ancak cmake, derleyici ccache'yi kullanarak bir testin başarısız olmasından şikayet ederek kurtarır (beklenebilir).

Ben şahsen /usr/lib/ccachebenim $PATH. Bu dizin, derleyicinin çağrılabileceği her olası ad için ( gccve gibi gcc-4.3), tümü ccache'yi işaret eden bir sürü sembolik bağ içerir .

Ve sembolik bağları bile yaratmadım. Debian'a ccache kurduğumda bu dizin önceden doldurulmuş olarak geliyor.

CMAKE 3.4'ten itibaren şunları yapabilirsiniz:

-DCMAKE_CXX_COMPILER_LAUNCHER=ccache

Artık ccache'yi derleme komutları ve bağlantı komutları için bir başlatıcı olarak belirtmek mümkündür (cmake 2.8.0'dan beri). Bu Makefile ve Ninja oluşturucu için çalışıyor. Bunu yapmak için aşağıdaki özellikleri ayarlamanız yeterlidir:

find_program(CCACHE_FOUND ccache)
if(CCACHE_FOUND)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
    set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache) # Less useful to do it for linking, see edit2
endif(CCACHE_FOUND)

Bu özellikleri yalnızca belirli dizinler veya hedefler için ayarlamak da mümkündür.

Ninja için bu 3.4 sürümünden beri mümkündür. Craig Scott, XCode için cevabında bir geçici çözüm sunuyor.

Düzenleme: Uprego ve Lekensteyn'in yorumu sayesinde, başlatıcı olarak kullanmadan önce ccache'nin kullanılabilir olup olmadığını ve hangi üreticiler için bir derleme başlatıcısı kullanmanın mümkün olduğunu kontrol etmek için cevabı düzenledim.

Edit2: @Emilio Cobos, ccache bağlantı hızını artırmadığı ve sccache gibi diğer önbellek türleriyle uğraşabileceğinden, bağlantı parçası için bunu yapmaktan kaçınmayı önerdi

CMake 3.1'den itibaren ccache'yi Xcode oluşturucu ile kullanmak mümkündür ve Ninja, CMake 3.4'ten itibaren desteklenir. Ninja onurlandıracakRULE_LAUNCH_COMPILE , Unix Makefiles oluşturucu gibi (bu nedenle @ Babcool'un cevabı sizi Ninja için de oraya götürür), ancak Xcode oluşturucu için ccache'yi çalıştırmak biraz daha fazla iş gerektirir. Aşağıdaki makale, yöntemi ayrıntılı olarak açıklar, üç CMake oluşturucunun tümü için çalışan genel bir uygulamaya odaklanır ve ccache sembolik bağlarının veya kullanılan temel derleyicinin ayarlanması hakkında hiçbir varsayımda bulunmaz (yine de CMake'nin derleyiciye karar vermesine izin verir):

https://crascit.com/2016/04/09/using-ccache-with-cmake/

Makalenin genel özü aşağıdaki gibidir. CMakeLists.txtDosyanızın başlangıcı şu şekilde ayarlanmalıdır:

cmake_minimum_required(VERSION 2.8)

find_program(CCACHE_PROGRAM ccache)
if(CCACHE_PROGRAM)
    # Support Unix Makefiles and Ninja
    set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE "${CCACHE_PROGRAM}")
endif()

project(SomeProject)

get_property(RULE_LAUNCH_COMPILE GLOBAL PROPERTY RULE_LAUNCH_COMPILE)
if(RULE_LAUNCH_COMPILE AND CMAKE_GENERATOR STREQUAL "Xcode")
    # Set up wrapper scripts
    configure_file(launch-c.in   launch-c)
    configure_file(launch-cxx.in launch-cxx)
    execute_process(COMMAND chmod a+rx
                            "${CMAKE_BINARY_DIR}/launch-c"
                            "${CMAKE_BINARY_DIR}/launch-cxx")

    # Set Xcode project attributes to route compilation through our scripts
    set(CMAKE_XCODE_ATTRIBUTE_CC         "${CMAKE_BINARY_DIR}/launch-c")
    set(CMAKE_XCODE_ATTRIBUTE_CXX        "${CMAKE_BINARY_DIR}/launch-cxx")
    set(CMAKE_XCODE_ATTRIBUTE_LD         "${CMAKE_BINARY_DIR}/launch-c")
    set(CMAKE_XCODE_ATTRIBUTE_LDPLUSPLUS "${CMAKE_BINARY_DIR}/launch-cxx")
endif()

İki komut dosyası şablon dosyası launch-c.inve buna launch-cxx.inbenzer (bunlar,CMakeLists.txt dosya ile ):

launch-c.in:

#!/bin/sh
export CCACHE_CPP2=true
exec "${RULE_LAUNCH_COMPILE}" "${CMAKE_C_COMPILER}" "$@"

launch-cxx.in:

#!/bin/sh
export CCACHE_CPP2=true
exec "${RULE_LAUNCH_COMPILE}" "${CMAKE_CXX_COMPILER}" "$@"

Yukarıdakiler, RULE_LAUNCH_COMPILEUnix Makefiles ve Ninja için tek başına kullanır , ancak Xcode oluşturucu için CMake'nin CMAKE_XCODE_ATTRIBUTE_...değişken desteğinden gelen yardıma dayanır . Ayarı CCve CXXkullanıcı tanımlı Xcode derleyici komutu ve kontrol etmek niteliklerini LDve LDPLUSPLUS, bildiğim kadarıyla söyleyebilirim, Xcode projeleri belgelenmiş özelliği, ancak işe görünüyor değildir bağlayıcı komutu için. Apple tarafından resmi olarak desteklendiğini onaylayan biri varsa, bağlantılı makaleyi ve bu yanıtı buna göre güncelleyeceğim.

Bir sembolik ayarlamak gibi yapmadım g++için ccache. VeCXX="ccache g++" benim için işe yaramadı çünkü bazı cmake test durumları, öznitelikler olmadan sadece derleyici programına sahip olmak istedi.

Bunun yerine küçük bir bash betiği kullandım:

#!/bin/bash
ccache g++ "$@"

ve içinde yürütülebilir olarak kaydetti /usr/bin/ccache-g++.

Sonra C, cmake'yi /usr/bin/ccache-g++C ++ derleyicisi olarak kullanmak üzere yapılandırdı . Bu şekilde cmake test durumlarını geçer ve 2 veya 3 hafta içinde unutabileceğim sembolik bağlantılara sahip olmaktan daha rahat hissediyorum ve sonra belki bir şey işe yaramaz mı diye merak ediyorum ...

Aşağıdaki çalışmaları doğruladım (kaynak: bu bağlantı ):

        CC="gcc" CXX="g++" cmake -D CMAKE_CXX_COMPILER="ccache" -D CMAKE_CXX_COMPILER_ARG1="g++" -D CMAKE_C_COMPILER="ccache" -D CMAKE_C_COMPILER_ARG1="gcc" $*

Güncelleme : Daha sonra bunun bile işe yaramadığını anladım. Garip bir şekilde her seferinde çalışır (diğer zamanlarda şikayet eder).

Bence en iyi yol gcc, g ++ ile ccache'yi sembolize etmektir, ancak cmake içinde kullanmak istiyorsanız şunu deneyin:

export CC="ccache gcc" CXX="ccache g++" cmake ...

Burada daha önce bahsedilmeyen önemli bir maddeyi ekleyeyim.

Ubunutu: 18.04 docker görüntüsünden minimalist bir yapı sistemini önyüklerken, kurulum sırasının bir fark yarattığını gördüm.

Benim durumumda ccache arama sırasında iyi çalıştı gcc, ancak aynı derleyicinin çağrılarını diğer adlarla yakalayamadı: ccve c++. Ccache'yi tam olarak kurmak için, önce tüm derleyicilerin kurulduğundan emin olmanız veya güvenli olması için ccache sembolik bağlantılarını update çağrısı eklemeniz gerekir.

sudo apt-get install ccache build-essential # and everyhting ... sudo /usr/sbin/update-ccache-symlinks export PATH="/usr/lib/ccache/:$PATH"

... ve sonra (güncellenmiş sembolik bağlantılar nedeniyle) cc ve c ++ çağrıları da yakalanır!