notepad++.exeOrtamdaki Yol değişkenlerime ekledim .

Şimdi komuta istemi içinde, notepad++.exe filename.txtaçılır filename.txt. Ama sadece np filename.txtdosyayı açmak için yapmak istiyorum .

Kullanmayı denedim DOSKEY np=notepad++. Ancak, sadece açılmış bir notepad ++ dosyasını açmadan ön plana çıkarıyor. Dosyayı nasıl açabilirim?

Teşekkürler.

Josh'un cevabına eklemek için,

diğer adları aşağıdaki adımlarla kalıcı hale getirebilirsiniz ,

1. DOSKEYKomutlarınızla bir .bat veya .cmd dosyası oluşturun .
2. Regedit'i çalıştırın ve şu adrese gidin: HKEY_CURRENT_USER\Software\Microsoft\Command Processor

3. .Bat / .cmd dosyanızın adı AutoRunve tam yoluyla Dize Değeri girdisini ekleyin .

   Örneğin %USERPROFILE%\alias.cmd, yolun ilk segmentini değiştirmek, %USERPROFILE%birden çok makine arasında senkronizasyon için kullanışlıdır.

Bu şekilde cmd her çalıştırıldığında takma adlar yüklenir.

Windows 10 için girişi buraya ekleyin HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Command Processor.

Bütünlük için, burada yararlı bulabileceğiniz takma ad türlerini gösteren bir şablon bulunmaktadır.

@echo off

:: Temporary system path at cmd startup

set PATH=%PATH%;"C:\Program Files\Sublime Text 2\"

:: Add to path by command

DOSKEY add_python26=set PATH=%PATH%;"C:\Python26\"
DOSKEY add_python33=set PATH=%PATH%;"C:\Python33\"

:: Commands

DOSKEY ls=dir /B
DOSKEY sublime=sublime_text $*  
    ::sublime_text.exe is name of the executable. By adding a temporary entry to system path, we don't have to write the whole directory anymore.
DOSKEY gsp="C:\Program Files (x86)\Sketchpad5\GSP505en.exe"
DOSKEY alias=notepad %USERPROFILE%\Dropbox\alias.cmd

:: Common directories

DOSKEY dropbox=cd "%USERPROFILE%\Dropbox\$*"
DOSKEY research=cd %USERPROFILE%\Dropbox\Research\

• $*Sözdiziminin, bir dizin dizesinin yanı sıra bağımsız değişkenleri alan bir yürütülebilir dosyadan sonra çalıştığını unutmayın . Yukarıdaki örnekte, kullanıcı tanımlı komut dropbox researchile aynı dizini gösterir research.
• Rivenfall'un işaret ettiği gibi, alias.cmddosyanın rahat bir şekilde düzenlenmesine izin veren bir komut eklemek iyi bir fikirdir . Bkz aliasyukarıda. Bir cmd oturumundaysanız, cmdcmd'yi yeniden başlatmak ve alias.cmddosyayı yeniden yüklemek için girin .

Soruyu cevaplamak için internette arama yaptığımda, tartışmalar ya sadece sebat etmeye ya da sadece DOSKEY'in kullanımına odaklanmıştı. Umarım birisi burada birlikte olmak bu iki yönünden faydalanacaktır!

İşte .regyüklemenize yardımcı olacak bir dosya alias.cmd. Şimdi yukarıda önerildiği gibi bir dropbox klasörüne örnek olarak ayarlanmıştır.

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="%USERPROFILE%\\alias.cmd"

Tek kullanıcılı uygulamalar için yukarıdakiler yapılacaktır. Bununla birlikte, alias.cmdkayıt defteri anahtarında ilk olup olmadığını denetlemenin gerekli olduğu durumlar vardır . Aşağıdaki örneğe bakın.

C:\Users\Public\init.cmdPotansiyel kullanıcılar arası yapılandırmaları barındıran bir dosyada:

@ECHO OFF
REM Add other configurations as needed
IF EXIST "%USERPROFILE%\alias.cmd" ( CALL "%USERPROFILE%\alias.cmd" )

Kayıt defteri anahtarı C:\Users\Public\init.cmd, .regdosyaya karşılık gelen veya şu dosya kullanılarak güncelleştirilmelidir :

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"AutoRun"="C:\\Users\\Public\\init.cmd"

Parametreleri geçmeniz gerekiyor, şunu deneyin:

doskey np=notepad++.exe $*

Düzenleme (Romonov'un yorumuna yanıt olarak) S: Komut istemini hatırlatmanın herhangi bir yolu var mı, bu yüzden her yeni komut istemi açtığımda bunu çalıştırmam gerekmiyor mu?

doskey komut işlemcisi (örneğin cmd.exe) tarafından yorumlanan bir metin komutudur, başka bir işlemde (özellikle henüz başlatılmamış olan) durumu değiştirmeyi bilemez.

doskeyİlk komut kabuğu ortamlarını kurmak için kullanılan kişiler genellikle /Ktüm ortak ayarları (ayarlanan pencerenin başlığı, renkleri, vb.) Yapan bir toplu iş dosyasını çalıştırmak için seçeneği (genellikle bir kısayol aracılığıyla) kullanır.

cmd.exe /K env.cmd

env.cmd:

title "Foo Bar"
doskey np=notepad++.exe $*
...

Sadece basit komutlar arıyorsanız şu adımları uygulayabilirsiniz:

1. C: \ Aliases adlı bir klasör oluşturun
2. Ekle C: \ diğer adları yolunuzun (içinde herhangi bir dosya her seferinde bulunacaktır böylece)
3. İstediğiniz her takma ad için C: \ Takma adda bir .bat dosyası oluşturun

Belki aşırıya kaçma, ama @Argyll'den (aksi halde mükemmel) cevabın aksine, bu her zaman bu yükleme sorununu çözer.

Örneğin, içinde aşağıdakileri içeren dig2.bat adlı bir dosya var:

@echo off
echo.
dig +noall +answer %1

Kişisel np dosyası sadece aşağıdaki gibi olabilir:

@echo off
echo.
notepad++.exe %1

Ardından , PATH ortam değişkeninize C: \ Aliases klasörünü eklemeniz yeterlidir . CMD veya PowerShell'i zaten açtıysanız, yeniden başlatmanız gerekir.

FWIW, C: \ Aliases dizinimde yaklaşık 20 takma adım var (ayrı .bat dosyaları) - Gerektiğinde yenilerini oluşturuyorum. Belki en güzel değil, ama iyi çalışıyor.

GÜNCELLEME : @Mav kullanıcısının mükemmel bir önerisi doğrultusunda, % 1 yerine % * kullanmak daha iyidir , böylece komuta birden fazla dosya aktarabilirsiniz, örneğin:

@echo off
echo.
notepad++.exe %*

Bu şekilde bunu yapabilirsiniz:

np c:\temp\abc.txt c:\temp\def.txt c:\temp\ghi.txt

ve tüm 3 dosyayı açacaktır.

Alternatif olarak, cmderlinux gibi takma adlar eklemenizi sağlar:

alias subl="C:\Program Files\Sublime Text 3\subl.exe" $*

PATH değişkeninize notepad ++. Exe eklediğiniz göz önüne alındığında, çok basit. System32 klasörünüzde np.bataşağıdaki kodla adlandırılan bir dosya oluşturun :

@echo off
call notepad++.exe %*

%*Geçtiği tüm argümanlar boyunca size vermek npüzere komutu notepad++.exekomutu.

EDIT: Dosyaları benim için biraz sakat olan System32 klasörüne kaydetmek için yönetici erişimine ihtiyacınız olacak. Dosyayı başka bir yerde yarattım ve manuel olarak System32'ye taşıdım.

Ayrıca, yolunuzda (örneğin C: \ Windows) komutuyla bir alias.cmd oluşturabilirsiniz.

@echo %2 %3 %4 %5 %6 > %windir%\%1.cmd

Bunu yaptıktan sonra, böyle bir şey yapabilirsiniz:

alias nameOfYourAlias commands to run 

Ve bundan sonra comman satırını yazabilirsiniz

nameOfYourAlias 

bu yürütülecek

commands to run 

AMA benim için en iyi yol sadece bir programın yolunu eklemektir.

setx PATH "%PATH%;%ProgramFiles%\Sublime Text 3" /M 

Ve şimdi yüce koşuyorum

subl index.html

Windows 10'da Konsol Takma Adları

Bir konsol diğer adı tanımlamak için, Doskey.exebir makro oluşturmak için veya AddConsoleAliasişlevi kullanın .

doskey

doskey test=cd \a_very_long_path\test

Parametreleri de geçmek $*için sonuna ekleyin :doskey short=longname $*

AddConsoleAlias

AddConsoleAlias( TEXT("test"), 
                 TEXT("cd \\<a_very_long_path>\\test"), 
                 TEXT("cmd.exe"));

Daha fazla bilgi burada Konsol Takma Adları , Doskey , Parametreler

Sadece şunu yazarak bir takma ad oluşturmak istiyorsunuz:

c:\>alias kgs kubectl get svc

Created alias for kgs=kubectl get svc

Ve takma adı aşağıdaki gibi kullanın:

c:\>kgs alfresco-svc

NAME           TYPE        CLUSTER-IP     EXTERNAL-IP   PORT(S)   AGE
alfresco-svc   ClusterIP   10.7.249.219   <none>        80/TCP    8d

Aşağıdaki alias.batdosyayı yolunuza eklemeniz yeterlidir. Kendisi ile aynı dizinde ek toplu iş dosyaları oluşturur.

  @echo off
  echo.
  for /f "tokens=1,* delims= " %%a in ("%*") do set ALL_BUT_FIRST=%%b
  echo @echo off > C:\Development\alias-script\%1.bat
  echo echo. >> C:\Development\alias-script\%1.bat
  echo %ALL_BUT_FIRST% %%* >> C:\Development\alias-script\%1.bat
  echo Created alias for %1=%ALL_BUT_FIRST%

Bu oluşturulan adlı toplu iş dosyası örneği kgs.bat:

@echo off 
echo. 
kubectl get svc %* 

Aslında, bir tane daha geliştireceğim ve bir Amiga'da programladığımdan beri kullandığım küçük bir tekniğe izin vereceğim. Kullandığınız herhangi bir yeni sistemde, kişisel veya profesyonel olsun, birinci adım iki klasör oluşturmaktır: C:\BINve C:\BATCH. Ardından yol ifadenizi, her ikisini de sıraya koymak için değiştirin C:\BATCH;C:\BIN;[rest of path].

Bunu yaptıktan sonra, onları C:\BINklasöre kopyalamak için erişmeniz gereken küçük yol dışı araçlarınız varsa ve bunlar yolunuzdadır. Bu atamaları geçici olarak geçersiz kılmak için, C:\BATCHklasöre yürütülebilir dosyayla aynı ada sahip bir toplu iş dosyası ekleyebilirsiniz ve yol dosyayı C: \ BIN dosyasından önce bulacaktır. Yapmanız gerekebilecek her şeyi kapsamalıdır.

Elbette, bu günlerde bunu yapmanın kanonik doğru yolu, dosyaya sembolik bir bağlantı oluşturmak olacaktır, ancak aynı prensip geçerlidir. Biraz ekstra katma bonus da var. Sisteme zaten yoldaki bir şeyle çakışan bir şey koymak istiyorsanız, onu C:\BINveya C:\Batchklasöre koymak orijinali önceden boşaltır - geçici veya kalıcı bir şekilde geçersiz kılmanıza veya bir şeyleri adlarınızla yeniden adlandırmanıza izin verir. daha rahat - orijinali değiştirmeden.

Roryhewitt cevabını genişletiyor .

DOSKEY üzerinde .cmd dosyalarını kullanmanın bir avantajı, bu "takma adların" PowerShell veya WSL (Linux için Windows alt sistemi) gibi diğer kabuklarda kullanılabilmesidir.

Bu komutları bash'de kullanmanın tek yolu, "takma adınızı" çağırmadan önce bazı yol manipülasyonları yapmanız gerekebileceğinden, biraz daha kurulum gerektirebilir.

örneğin, Visual Studio'da bir dosyayı düzenlemek için "takma adım" olan vs.cmd var

@echo off
if [%1]==[] goto nofiles
start "" "c:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" /edit %1
goto end
:nofiles
start "" "C:\Program Files (x86)\Microsoft Visual Studio 
11.0\Common7\IDE\devenv.exe" "[PATH TO MY NORMAL SLN]"
:end

Hangi VS verilen (bu durumda VS2012 - ama tadı ayarlamak) hiçbir dosya verilen "normal" projeyi kullanarak ama bir dosya verildiğinde bir dosya başlatmak yerine o proje "o proje" açılış çalışan bir VS eklemek için çalışacağız VS'nin yeni örneği.

Bunu bash'den kullanmak için, "vs Myfile" her zaman işe yaramayacağından fazladan bir dolaylama düzeyi ekliyorum

alias vs='/usr/bin/run_visual_studio.sh'

Hangi vscmd çağırmadan önce yolları ayarlar

#!/bin/bash
cmd.exe /C 'c:\Windows\System32\vs.cmd' "`wslpath.sh -w -r $1`"

Böylece bu şekilde yapabilirim

vs SomeFile.txt

Bir komut isteminde, Power Shell veya bash ve çalışan Visual Studio'mda düzenleme için açılır (bu sadece zayıf beynimi VI komutlarıyla uğraşmaktan kurtarır ya da VS'de saatlerdir düzenlediğimde böyle olur).

Bu çözüm uygun değildir, ancak bazı durumlarda amaca hizmet eder.

Önce bir klasör oluşturun ve sistem yolunuza ekleyin. Takma ad oluşturmak istediğiniz programın yürütülebilir dosyasına gidin. Sağ tıklayın ve Masaüstüne gönderin (Kısayol Oluştur). Kısayolu, diğer ad rahat olduğunda yeniden adlandırın. Şimdi kısayolu alın ve klasörünüze yerleştirin.

Çalışma isteminden doğrudan kısayol adını yazabilir ve programı sizin için açabilirsiniz. Ancak komut isteminden, .lnk eklemeniz ve enter tuşuna basmanız gerekir, program açılır.

Doğal olarak, hepsinden en uygun çözümü elde edene kadar dinlenmem. Geniş internetteki çok sayıda cevap ve konuyu birleştirerek, sahip olabileceğiniz şey burada.

• Her örneğinde otomatik olarak yüklenir cmd
• Takma DOSKEYadlar için anahtar kelime gerektirmez

Bunun büyük ölçüde Argyll'in cevabı ve yorumlarına dayandığını unutmayın , kavramları anlamak için kesinlikle okuyun.

Nasıl çalışır?

1) takma adları ile makro dosyası (veya da yayınlanmaya başka şeyler yarasa / cmd dosyası) oluşturmak
cmd her örneği üzerinde çalışacak şekilde Sicil bunu kayıt) 2
  - Ayrıca yalnızca isterseniz kısayol ile çalıştırabilirsiniz

Bu kadar

;==============================================================================
;= This file is registered via registry to auto load with each instance of cmd.
;================================ general info ================================
;= https://stackoverflow.com/a/59978163/985454  -  how to set it up?
;= https://gist.github.com/postcog/5c8c13f7f66330b493b8  -  example doskey macrofile
;========================= loading with cmd shortcut ==========================
;= create a cmd link with the following target :
;= %comspec% /k "(doskey /macrofile=%userprofile%\cmd\aliases.mac)"

alias=subl %USERPROFILE%\cmd\aliases.mac
hosts=runas /noprofile /savecred /user:QWERTY-XPS9370\administrator "subl C:\Windows\System32\drivers\etc\hosts" > NUL

ls=ls --color=auto $*
ll=ls -l --color=auto $*
la=ls -la --color=auto $*
grep=grep --color

~=cd %USERPROFILE%
cdr=cd c:\repos
cdd=cd c:\repos\dixons
cds=cd c:\repos\stekkie
cdu=cd c:\repos\uplus
cduo=cd c:\repos\uplus\oxbridge-fe
cdus=cd c:\repos\uplus\stratus

;============================= :end ============================
;= rem ******************************************************************
;= rem * EOF - Don't remove the following line.  It clears out the ';'
;= rem * macro. We're using it because there is no support for comments
;= rem * in a DOSKEY macro file.
;= rem ******************************************************************
;=

Şimdi iki seçeneğiniz var:
a) sadece makro dosyasını kaydetme
b) cmd/batrasgele komutları da çalıştırmak için normal bir dosya
kullanın Autorun.

  Autorun    REG_SZ    doskey /macrofile=%userprofile%\cmd\aliases.mac
  Autorun_    REG_SZ    %USERPROFILE%\cmd\env.cmd

Windows Registry Editor Version 5.00
[HKEY_CURRENT_USER\Software\Microsoft\Command Processor]
"Autorun"="doskey /macrofile=%userprofile%\\cmd\\aliases.mac"
"Autorun_"="%USERPROFILE%\\cmd\\env.cmd"

:: This file is registered via registry to auto load with each instance of cmd.
:: https://stackoverflow.com/a/59978163/985454

@echo off
doskey /macrofile=%userprofile%\cmd\aliases.mac

:: put other commands here

Zaten notepad++.exeyolunda olduğundan. Bu klasörde bir kısayol oluşturun npve üzerine gelin notepad++.exe.

İlk olarak, np.cmd adlı bir dosya oluşturabilir ve PATH arama listesinde bulunan klasöre koyabilirsiniz. Ardından, np.cmd dosyasını aşağıdaki gibi düzenleyin:

@echo off
notepad++.exe

Dizin başına / proje başına takma adı etkinleştirmek istiyorsanız aşağıdakileri deneyin:

1. İlk olarak, aliasesgeçerli dizinde adlandırılmış bir dosyayı arayacak ve ondan diğer adları başlatacak bir toplu iş dosyası oluşturun , diyelimmake-aliases.cmd

   @echo off
   if not exist aliases goto:eof
   echo [Loading aliases...]
   for /f "tokens=1* delims=^=" %%i in (aliases) do (
      echo   %%i ^<^=^> %%j
      doskey %%i=%%j
   )
   doskey aliases=doskey /macros
   echo   --------------------
   echo   aliases ^=^> list  all
   echo   alt+F10 ^=^> clear all
   echo [Done]
   

2. Ardından, aliasesaşağıdaki biçimi kullanarak ihtiyacınız olan her yerde oluşturun :

   alias1 = command1
   alias2 = command2
   ...
   

   Örneğin:

   b = nmake
   c = nmake clean
   r = nmake rebuild
   

3. Ardından, sistem genelinde yapmak veya değişkeninizi bilinen bir yerde tutmak make-aliases.cmdiçin %PATH%değişkeninizin konumunu ekleyin .

4. İle otomatik olarak başlamasını sağlayın cmd.

   • HKEY_CURRENT_USER\Software\Microsoft\Command Processor\AutoRunBazı geliştirme araçları oturum başına birden çok kez otomatik çalıştırma komut dosyasını tetikleyeceğinden, bunun için kesinlikle kullanmamanızı tavsiye ederim .

   • Eğer kullanırsanız ConEmu başka bir yol ve başlatma görevi komut dosyası başlayabileceğini ( Settings> Startup> Tasks), örneğin, ben adlı bir giriş yarattı {MSVC}:

     cmd.exe /k "vcvars64 && make-aliases",

     ve sonra Settings> Integration>ile Explorer bağlam menüsüne kaydettirdim Command: {MSVC} -cur_console:n, böylece bir klasöre sağ tıklayabilir ve aliaseso klasörde olmaları durumunda, yüklenen otomatik olarak bir VS geliştirici istemi başlatabilirim .

     ConEmu olmadan cmd.exe, karşılık gelen komutla bir kısayol oluşturmak veya make-aliasesher seferinde manuel olarak çalıştırmak isteyebilirsiniz .

Takma adlarınızı unutursanız, aliasesmakroyu kullanın ve bir şeyler ters giderse, yerleşik bir komut olan Alt+ tuşuna basarak geçerli oturumu sıfırlayın .F10cmd

Doskey kullanmak bunu yapmanın doğru yoludur, ancak Komut İstemi penceresi kapatıldığında sıfırlanır. Bu satırı .bashrc eşdeğeri gibi bir şeye eklemeniz gerekir. Bu yüzden aşağıdakileri yaptım:

1. Sistem yolu değişkenine "C: \ Program Files (x86) \ Notepad ++" ekleyin
2. Notepad ++. Exe dosyasının bir kopyasını oluşturun (aynı klasörde, tabii ki) ve np.exe olarak yeniden adlandırın

Sadece iyi çalışıyor!