SQL Server: Tüm BÜYÜK durumu Uygun Durum / Başlık Durumuna Oluşturun

Tamamen BÜYÜK ÖRNEK olarak içe aktarılmış bir masam var ve bunu Düzgün Durum'a dönüştürmek istiyorum. Bunu tamamlamak için kullandığınız komut dosyası nedir?

İşte hile yapacak bir UDF ...

create function ProperCase(@Text as varchar(8000))
returns varchar(8000)
as
begin
  declare @Reset bit;
  declare @Ret varchar(8000);
  declare @i int;
  declare @c char(1);

  if @Text is null
    return null;

  select @Reset = 1, @i = 1, @Ret = '';

  while (@i <= len(@Text))
    select @c = substring(@Text, @i, 1),
      @Ret = @Ret + case when @Reset = 1 then UPPER(@c) else LOWER(@c) end,
      @Reset = case when @c like '[a-zA-Z]' then 0 else 1 end,
      @i = @i + 1
  return @Ret
end

Yine de verilerinizi güncellemek için onu kullanmanız gerekecektir.

Bu işlev:

• Beyaz boşlukla ayrılmış tüm "BÜYÜK HARF" sözcükleri "Uygun Durumlar"
• "küçük harfli kelimeleri" tek başına bırakır
• İngilizce olmayan alfabeler için bile düzgün çalışıyor
• son SQL sunucu sürümlerinin süslü özelliklerini kullanmadığı için taşınabilir
• Unicode desteği için NCHAR ve NVARCHAR'ı kullanmanın yanı sıra uygun gördüğünüz herhangi bir parametre uzunluğunu kullanmak için kolayca değiştirilebilir
• beyaz boşluk tanımı yapılandırılabilir

CREATE FUNCTION ToProperCase(@string VARCHAR(255)) RETURNS VARCHAR(255)
AS
BEGIN
  DECLARE @i INT           -- index
  DECLARE @l INT           -- input length
  DECLARE @c NCHAR(1)      -- current char
  DECLARE @f INT           -- first letter flag (1/0)
  DECLARE @o VARCHAR(255)  -- output string
  DECLARE @w VARCHAR(10)   -- characters considered as white space

  SET @w = '[' + CHAR(13) + CHAR(10) + CHAR(9) + CHAR(160) + ' ' + ']'
  SET @i = 1
  SET @l = LEN(@string)
  SET @f = 1
  SET @o = ''

  WHILE @i <= @l
  BEGIN
    SET @c = SUBSTRING(@string, @i, 1)
    IF @f = 1 
    BEGIN
     SET @o = @o + @c
     SET @f = 0
    END
    ELSE
    BEGIN
     SET @o = @o + LOWER(@c)
    END

    IF @c LIKE @w SET @f = 1

    SET @i = @i + 1
  END

  RETURN @o
END

Sonuç:

dbo.ToProperCase('ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')
-----------------------------------------------------------------
All Upper Case and      Some lower Ää Öö Üü Éé Øø Cc Ææ

UPDATE titles
  SET title =
      UPPER(LEFT(title, 1)) +
        LOWER(RIGHT(title, LEN(title) - 1))

http://sqlmag.com/t-sql/how-title-case-column-value

CLR'yi SQL Server'da etkinleştirebilirseniz (2005 veya sonraki bir sürümü gerektirir) , TextInfo.ToTitleCase yerleşik işlevini kullanan bir CLR işlevi oluşturabilirsiniz; Kod satırları.

Bunun bu konudaki geç yazı olduğunu biliyorum ama bakmaya değer. Bu işlev benim için her zaman çalışıyor. Öyleyse paylaşmayı düşündüm.

CREATE FUNCTION [dbo].[fnConvert_TitleCase] (@InputString VARCHAR(4000) )
RETURNS VARCHAR(4000)
AS
BEGIN
DECLARE @Index INT
DECLARE @Char CHAR(1)
DECLARE @OutputString VARCHAR(255)

SET @OutputString = LOWER(@InputString)
SET @Index = 2
SET @OutputString = STUFF(@OutputString, 1, 1,UPPER(SUBSTRING(@InputString,1,1)))

WHILE @Index <= LEN(@InputString)
BEGIN
    SET @Char = SUBSTRING(@InputString, @Index, 1)
    IF @Char IN (' ', ';', ':', '!', '?', ',', '.', '_', '-', '/', '&','''','(')
    IF @Index + 1 <= LEN(@InputString)
BEGIN
    IF @Char != ''''
    OR
    UPPER(SUBSTRING(@InputString, @Index + 1, 1)) != 'S'
    SET @OutputString =
    STUFF(@OutputString, @Index + 1, 1,UPPER(SUBSTRING(@InputString, @Index + 1, 1)))
END
    SET @Index = @Index + 1
END

RETURN ISNULL(@OutputString,'')
END

Test aramaları:

select dbo.fnConvert_TitleCase(Upper('ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ')) as test
select dbo.fnConvert_TitleCase(upper('Whatever the mind of man can conceive and believe, it can achieve. – Napoleon hill')) as test

Sonuçlar:

Oyunda biraz geç kaldım, ancak bunun daha işlevsel olduğuna ve Rusça, Almanca, Tayca, Vietnamca vb. Dahil herhangi bir dilde çalıştığına inanıyorum. 'Veya - veya' den sonra büyük harf yapacaktır. veya (veya) veya boşluk (açıkça :).

CREATE FUNCTION [dbo].[fnToProperCase]( @name nvarchar(500) )
RETURNS nvarchar(500)
AS
BEGIN
declare @pos    int = 1
      , @pos2   int

if (@name <> '')--or @name = lower(@name) collate SQL_Latin1_General_CP1_CS_AS or @name = upper(@name) collate SQL_Latin1_General_CP1_CS_AS)
begin
    set @name = lower(rtrim(@name))
    while (1 = 1)
    begin
        set @name = stuff(@name, @pos, 1, upper(substring(@name, @pos, 1)))
        set @pos2 = patindex('%[- ''.)(]%', substring(@name, @pos, 500))
        set @pos += @pos2
        if (isnull(@pos2, 0) = 0 or @pos > len(@name))
            break
    end
end

return @name
END
GO

Karışık kasalı verileri içe aktaran SSIS içindeyseniz ve uygun büyük / küçük harfe sahip bir sütunda arama yapmanız gerekiyorsa, kaynağın karıştırıldığı ve arama kaynağının uygun olduğu durumda aramanın başarısız olduğunu fark edeceksiniz. Ayrıca türetilmiş sütunlar için SQL Server 2008r2 için sağ ve sol işlevleri kullanamayacağınızı da fark edeceksiniz. İşte benim için çalışan bir çözüm:

UPPER(substring(input_column_name,1,1)) + LOWER(substring(input_column_name, 2, len(input_column_name)-1))

İşte döngü yerine sıra veya sayı tablosu kullanan bir sürüm. Bir karakterin ne zaman büyük harfe dönüştürüleceğine ilişkin kişisel kurallarınızı düzenlemek için WHERE cümlesini değiştirebilirsiniz. Kesme işaretleri haricinde, harf olmayan bir harfle devam eden her harfi büyük harf yapacak basit bir küme ekledim. Bu, 123apple'ın "a" ile eşleşeceği anlamına gelir çünkü "3" bir harf değildir. Yalnızca beyaz boşluk istiyorsanız (boşluk, sekme, satır başı, satır besleme), deseni '[^a-z]'ile değiştirebilirsiniz '[' + Char(32) + Char(9) + Char(13) + Char(10) + ']'.

CREATE FUNCTION String.InitCap( @string nvarchar(4000) ) RETURNS nvarchar(4000) AS
BEGIN

-- 1. Convert all letters to lower case
    DECLARE @InitCap nvarchar(4000); SET @InitCap = Lower(@string);

-- 2. Using a Sequence, replace the letters that should be upper case with their upper case version
    SELECT @InitCap = Stuff( @InitCap, n, 1, Upper( SubString( @InitCap, n, 1 ) ) )
    FROM (
        SELECT (1 + n1.n + n10.n + n100.n + n1000.n) AS n
        FROM       (SELECT 0 AS n UNION SELECT    1 UNION SELECT    2 UNION SELECT    3 UNION SELECT    4 UNION SELECT    5 UNION SELECT    6 UNION SELECT    7 UNION SELECT    8 UNION SELECT    9) AS    n1
        CROSS JOIN (SELECT 0 AS n UNION SELECT   10 UNION SELECT   20 UNION SELECT   30 UNION SELECT   40 UNION SELECT   50 UNION SELECT   60 UNION SELECT   70 UNION SELECT   80 UNION SELECT   90) AS   n10
        CROSS JOIN (SELECT 0 AS n UNION SELECT  100 UNION SELECT  200 UNION SELECT  300 UNION SELECT  400 UNION SELECT  500 UNION SELECT  600 UNION SELECT  700 UNION SELECT  800 UNION SELECT  900) AS  n100
        CROSS JOIN (SELECT 0 AS n UNION SELECT 1000 UNION SELECT 2000 UNION SELECT 3000)                                                                                                             AS n1000
        ) AS Sequence
    WHERE 
        n BETWEEN 1 AND Len( @InitCap )
    AND SubString( @InitCap, n, 1 ) LIKE '[a-z]'                 /* this character is a letter */
    AND (
        n = 1                                                    /* this character is the first `character` */
        OR SubString( @InitCap, n-1, 1 ) LIKE '[^a-z]'           /* the previous character is NOT a letter */
        )
    AND (
        n < 3                                                    /* only test the 3rd or greater characters for this exception */
        OR SubString( @InitCap, n-2, 3 ) NOT LIKE '[a-z]''[a-z]' /* exception: The pattern <letter>'<letter> should not capatolize the letter following the apostrophy */
        )

-- 3. Return the modified version of the input
    RETURN @InitCap

END

Yukarıda yayınladığım bağlantı, ana sorunu ele alan harika bir seçenektir: en azından zarif bir şekilde tüm vakaları (Smith-Jones, von Haussen, John Smith MD) programlı olarak asla açıklayamayız. Tony, bu durumların üstesinden gelmek için bir istisna / kopma karakteri kavramını sunar. Her neyse, Cervo'nun fikrine dayanarak (boşluktan önce gelen tüm alt karakterlerin üstünde), değiştirme ifadeleri bunun yerine tek bir tablo tabanlı değiştirmeye sarılabilir. Gerçekten, herhangi bir düşük / yukarı karakter kombinasyonu @alpha'ya eklenebilir ve ifade değişmez:

declare @str    nvarchar(8000)
declare @alpha  table (low nchar(1), up nchar(1))


set @str = 'ALL UPPER CASE and    SOME lower ÄÄ ÖÖ ÜÜ ÉÉ ØØ ĈĈ ÆÆ'

-- stage the alpha (needs number table)
insert into @alpha
    -- A-Z / a-z
    select      nchar(n+32),
                nchar(n)
    from        dbo.Number
    where       n between 65 and 90 or
                n between 192 and 223

-- append space at start of str
set @str = lower(' ' + @str)

-- upper all lower case chars preceded by space
select  @str = replace(@str, ' ' + low, ' ' + up) 
from    @Alpha

select @str

The von Neumann's, McCain's, DeGuzman's ve Johnson-Smith ile ilgilenmek için istisnalar aramak mantıklı olacaktır.

@Richard Sayakanit cevabından ödünç alındı ​​ve geliştirildi. Bu, birden çok kelimeyi işler. Cevabı gibi, bu da herhangi bir UDF kullanmıyor, yalnızca yerleşik işlevler ( STRING_SPLITve STRING_AGG) kullanmıyor ve oldukça hızlı. STRING_AGGSQL Server 2017 gerektirir, ancak her zaman STUFF/XMLhileyi kullanabilirsiniz . Her istisnanın üstesinden gelmez, ancak birçok gereksinim için harika çalışabilir.

SELECT StateName = 'North Carolina' 
INTO #States
UNION ALL
SELECT 'Texas'


;WITH cteData AS 
(
    SELECT 
        UPPER(LEFT(value, 1)) +
            LOWER(RIGHT(value, LEN(value) - 1)) value, op.StateName
    FROM   #States op
    CROSS APPLY STRING_SPLIT(op.StateName, ' ') AS ss
)
SELECT 
    STRING_AGG(value, ' ')
FROM cteData c 
GROUP BY StateName

Galwegian cevabı @ için hafif bir modifikasyon - dönüşler örneğin St Elizabeth'siçine St Elizabeth'S.

Bu değişiklik kesme işaretlerini küçük harf olarak tutar; burada s, sağlanan dizenin sonunda gelir veya s'den sonra bir boşluk gelir (ve yalnızca bu durumlarda).

create function properCase(@text as varchar(8000))
returns varchar(8000)
as
begin
    declare @reset int;
    declare @ret varchar(8000);
    declare @i int;
    declare @c char(1);
    declare @d char(1);

    if @text is null
    return null;

    select @reset = 1, @i = 1, @ret = '';

    while (@i <= len(@text))
    select
        @c = substring(@text, @i, 1),
        @d = substring(@text, @i+1, 1),
        @ret = @ret + case when @reset = 1 or (@reset=-1 and @c!='s') or (@reset=-1 and @c='s' and @d!=' ') then upper(@c) else lower(@c) end,
        @reset = case when @c like '[a-za-z]' then 0 when @c='''' then -1 else 1 end,
        @i = @i + 1
    return @ret
end

Döner:

• st elizabeth's içine St Elizabeth's
• o'keefe içine O'Keefe
• o'sullivan içine O'Sullivan

Diğerlerinin, İngilizce olmayan girdiler için farklı çözümlerin tercih edilebilir olduğu yönündeki yorumları durum devam etmektedir.

Sanırım aşağıdakilerin daha verimli olduğunu göreceksiniz:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
    SET @str = REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE( @str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Replace ifadesi kesilebilir ve doğrudan bir SQL sorgusuna yapıştırılabilir. Bu son derece çirkin, ancak @str'i ilgilendiğiniz sütunla değiştirirseniz, bu şekilde gönderilen udf'lerde yapacağınız gibi örtük bir imleç için bir fiyat ödemeyeceksiniz. UDF'mi kullanmanın bile çok daha verimli olduğunu görüyorum.

Oh ve el ile değiştirme ifadesini oluşturmak yerine şunu kullanın:

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000)
SET @x = 0
SET @sql = '@str' -- actual variable/column you want to replace
WHILE @x < 26
BEGIN
    SET @c = CHAR(ASCII('a') + @x)
    SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
    SET @x = @x + 1
END
PRINT @sql

Her neyse, satır sayısına bağlı. Keşke sadece s / \ b ([az]) / uc $ 1 / yapabilseydiniz, ama elimizdeki araçlarla çalışıyoruz.

NOT olarak kullanmak zorunda kalacağınız için bunu kullanmanız gerekirdi .... SELECT dbo.ProperCase (LOWER (sütun)) sütun büyük harftir. Aslında 5.000 girişlik tablomda (bir saniye bile değil) daha düşük olanlarda bile oldukça hızlı çalışıyor.

Uluslararasılaştırma ile ilgili yorumların telaşına yanıt olarak, yalnızca SQL Server'ın üst ve alt uygulamasına dayanan her ascii karakterini işleyen aşağıdaki uygulamayı sunuyoruz. Unutmayın, burada kullandığımız değişkenler VARCHAR'dır, yani yalnızca ASCII değerlerini tutabilirler. Daha fazla uluslararası alfabe kullanmak için NVARCHAR kullanmanız gerekir. Mantık benzer olacaktır, ancak ASCII VE CHAR yerine UNICODE ve NCHAR kullanmanız gerekir ve değiştirme ifadesi çok daha büyük olur ...

-- Code Generator for expression
DECLARE @x  INT,
    @c  CHAR(1),
    @sql    VARCHAR(8000),
    @count  INT
SEt @x = 0
SET @count = 0
SET @sql = '@str' -- actual variable you want to replace
WHILE @x < 256
BEGIN
    SET @c = CHAR(@x)
    -- Only generate replacement expression for characters where upper and lowercase differ
    IF @x = ASCII(LOWER(@c)) AND @x != ASCII(UPPER(@c))
    BEGIN
        SET @sql = 'REPLACE(' + @sql + ', '' ' + @c+  ''', '' ' + UPPER(@c) + ''')'
        SET @count = @count + 1
    END
    SET @x = @x + 1
END
PRINT @sql
PRINT 'Total characters substituted: ' + CONVERT(VARCHAR(255), @count)

Temel olarak benim yöntemimin temeli, verimlilik için ön hesaplamayla ticaret yapmaktır. Tam ASCII uygulaması aşağıdaki gibidir:

IF OBJECT_ID('dbo.ProperCase') IS NOT NULL
    DROP FUNCTION dbo.ProperCase
GO
CREATE FUNCTION dbo.PROPERCASE (
    @str VARCHAR(8000))
RETURNS VARCHAR(8000)
AS
BEGIN
    SET @str = ' ' + @str
SET @str =     REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(REPLACE(@str, ' a', ' A'), ' b', ' B'), ' c', ' C'), ' d', ' D'), ' e', ' E'), ' f', ' F'), ' g', ' G'), ' h', ' H'), ' i', ' I'), ' j', ' J'), ' k', ' K'), ' l', ' L'), ' m', ' M'), ' n', ' N'), ' o', ' O'), ' p', ' P'), ' q', ' Q'), ' r', ' R'), ' s', ' S'), ' t', ' T'), ' u', ' U'), ' v', ' V'), ' w', ' W'), ' x', ' X'), ' y', ' Y'), ' z', ' Z'), ' š', ' Š'), ' œ', ' Œ'), ' ž', ' Ž'), ' à', ' À'), ' á', ' Á'), ' â', ' Â'), ' ã', ' Ã'), ' ä', ' Ä'), ' å', ' Å'), ' æ', ' Æ'), ' ç', ' Ç'), ' è', ' È'), ' é', ' É'), ' ê', ' Ê'), ' ë', ' Ë'), ' ì', ' Ì'), ' í', ' Í'), ' î', ' Î'), ' ï', ' Ï'), ' ð', ' Ð'), ' ñ', ' Ñ'), ' ò', ' Ò'), ' ó', ' Ó'), ' ô', ' Ô'), ' õ', ' Õ'), ' ö', ' Ö'), ' ø', ' Ø'), ' ù', ' Ù'), ' ú', ' Ú'), ' û', ' Û'), ' ü', ' Ü'), ' ý', ' Ý'), ' þ', ' Þ'), ' ÿ', ' Ÿ')
    RETURN RIGHT(@str, LEN(@str) - 1)
END
GO

Geri dönüp büyük olmayan verileri almak için çok mu geç?

Müşterilerinizin von Neumann's, McCain's, DeGuzman's ve Johnson-Smith'in, işleminizin sonucundan hoşlanmayabilir ...

Ayrıca, bunun verilerin tek seferlik bir yükseltilmesi olduğunu tahmin ediyorum. Düzeltilmiş adları veritabanına aktarmak, filtrelemek / değiştirmek ve yeniden içe aktarmak daha kolay olabilir ve ardından ad sabitleme için SQL dışı yaklaşımları kullanabilirsiniz ...

İşte SQLTeam.com Forumlarında bulduğum başka bir varyasyon @ http://www.sqlteam.com/forums/topic.asp?TOPIC_ID=47718

create FUNCTION PROPERCASE
(
--The string to be converted to proper case
@input varchar(8000)
)
--This function returns the proper case string of varchar type
RETURNS varchar(8000)
AS
BEGIN
IF @input IS NULL
BEGIN
--Just return NULL if input string is NULL
RETURN NULL
END

--Character variable declarations
DECLARE @output varchar(8000)
--Integer variable declarations
DECLARE @ctr int, @len int, @found_at int
--Constant declarations
DECLARE @LOWER_CASE_a int, @LOWER_CASE_z int, @Delimiter char(3), @UPPER_CASE_A int, @UPPER_CASE_Z int

--Variable/Constant initializations
SET @ctr = 1
SET @len = LEN(@input)
SET @output = ''
SET @LOWER_CASE_a = 97
SET @LOWER_CASE_z = 122
SET @Delimiter = ' ,-'
SET @UPPER_CASE_A = 65
SET @UPPER_CASE_Z = 90

WHILE @ctr <= @len
BEGIN
--This loop will take care of reccuring white spaces
WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) > 0
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
SET @ctr = @ctr + 1
END

IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @LOWER_CASE_a AND @LOWER_CASE_z
BEGIN
--Converting the first character to upper case
SET @output = @output + UPPER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END

SET @ctr = @ctr + 1

WHILE CHARINDEX(SUBSTRING(@input,@ctr,1), @Delimiter) = 0 AND (@ctr <= @len)
BEGIN
IF ASCII(SUBSTRING(@input,@ctr,1)) BETWEEN @UPPER_CASE_A AND @UPPER_CASE_Z
BEGIN
SET @output = @output + LOWER(SUBSTRING(@input,@ctr,1))
END
ELSE
BEGIN
SET @output = @output + SUBSTRING(@input,@ctr,1)
END
SET @ctr = @ctr + 1
END

END
RETURN @output
END



GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON
GO

Şeytanın ayrıntıda olduğunu biliyorum (özellikle insanların kişisel verileri söz konusu olduğunda) ve doğru şekilde büyük harfle yazılmış isimlere sahip olmanın çok güzel olacağını biliyorum, ancak yukarıdaki türden güçlük, aramızdaki pragmatik, zamana duyarlı olanların aşağıdakileri kullanmasının nedenidir. :

SELECT UPPER('Put YoUR O'So oddLy casED McWeird-nAme von rightHERE here')

Tecrübelerime göre, insanlar Cümlenin yarısı bile olsa ONLARIN ADINI görmekte sorun yaşamıyorlar.

Bakın: Ruslar kalem kullandı!

Yeni öğrendim InitCap().

İşte bazı örnek kodlar:

SELECT ID
      ,InitCap(LastName ||', '|| FirstName ||' '|| Nvl(MiddleName,'')) AS RecipientName
FROM SomeTable

Bu SSMS'de çalıştı:

Select Jobtitle,
concat(Upper(LEFT(jobtitle,1)), SUBSTRING(jobtitle,2,LEN(jobtitle))) as Propercase
From [HumanResources].[Employee]

Tüm verilerin yalnızca tek bir kelime olduğunu biliyorsanız, işte bir çözüm. Önce sütunu tamamen aşağıya güncelleyin ve ardından aşağıdakileri çalıştırın

    update tableName set columnName = 
    upper(SUBSTRING(columnName, 1, 1)) + substring(columnName, 2, len(columnName)) from tableName

Son zamanlarda bunun üstesinden gelmek zorunda kaldı ve istediğim her şeye tam olarak uymayan hiçbir şeyden sonra aşağıdakileri buldum. Bu, özel kelime işleme durumları gibi tam bir cümle yapacak. Ayrıca, daha basit yöntemlerin çoğunun ele aldığı, ancak daha karmaşık yöntemlerin olmadığı tek karakterli 'kelimeler' ile ilgili sorunlarımız vardı. Tek dönüşlü değişken, döngü veya imleç de yok.

CREATE FUNCTION ProperCase(@Text AS NVARCHAR(MAX))
RETURNS NVARCHAR(MAX)
AS BEGIN

    DECLARE @return NVARCHAR(MAX)

    SELECT @return = COALESCE(@return + ' ', '') + Word FROM (
         SELECT CASE
            WHEN LOWER(value) = 'llc' THEN UPPER(value)
            WHEN LOWER(value) = 'lp' THEN UPPER(value) --Add as many new special cases as needed
            ELSE
               CASE WHEN LEN(value) = 1
               THEN UPPER(value)
               ELSE UPPER(LEFT(value, 1)) + (LOWER(RIGHT(value, LEN(value) - 1)))
              END
            END AS Word
         FROM STRING_SPLIT(@Text, ' ')
     ) tmp

     RETURN @return
END

Verilerinizi kopyalayıp MS Word'e yapıştırın ve "Her Kelimeyi Büyük Harf Yapmak" için yerleşik metin dönüştürmeyi kullanın. İstisnaları ele almak için orijinal verilerinizle karşılaştırın. "MacDonald" ve "IBM" tür istisnalarını manuel olarak atlamanın bir yolunu göremiyorum, ancak FWIW'yi bu şekilde yaptım.

Server Server 2016 ve daha yeni sürümlerde STRING_SPLIT kullanabilirsiniz

with t as (
    select 'GOOFYEAR Tire and Rubber Company' as n
    union all
    select 'THE HAPPY BEAR' as n
    union all
    select 'MONK HOUSE SALES' as n
    union all
    select 'FORUM COMMUNICATIONS' as n
)
select
    n,
    (
        select ' ' + (
            upper(left(value, 1))
            + lower(substring(value, 2, 999))
        )
        from (
            select value
            from string_split(t.n, ' ')
        ) as sq
        for xml path ('')
    ) as title_cased
from t

Misal