Windows toplu iş dosyalarının gizli özellikleri

Windows toplu iş dosyalarının daha az bilinen, ancak önemli ve yararlı özelliklerinden bazıları nelerdir?

Kuralları:

• Yanıt başına bir özellik
• Yalnızca dokümantasyon bağlantısı için değil , özelliğin kısa bir açıklamasını ve bir örneğini verin
• Yanıtları yerel işlevlere sınırlayın , yani Windows Kaynak Seti gibi ek yazılım gerektirmez

Açıklama: Burada, WinNT varyantlarında varsayılan olan cmd.exe tarafından işlenen komut dosyalarına atıfta bulunuyoruz.

(Ayrıca bkz: Windows toplu iş dosyaları: .bat vs .cmd? )

Hattın devamı:

call C:\WINDOWS\system32\ntbackup.exe ^
    backup ^
    /V:yes ^
    /R:no ^
    /RS:no ^
    /HC:off ^
    /M normal ^
    /L:s ^
    @daily.bks ^
    /F daily.bkf

PUSHD path

Sizi yol tarafından belirtilen dizine götürür .

POPD

Sizi "ittiğiniz" dizine geri götürür.

Bunun bir toplu iş dosyasında ne kadar yararlı olacağından emin değilim , ancak komut isteminde kullanmak için çok uygun bir komut:

C:\some_directory> start .

Bu, Windows Gezgini'ni "bazı_dizini" klasöründe açar.

Bunu harika bir zaman kazandırıcı buldum.

Her satırda bir anahtar kelime ile işaretlenmiş yorumları okumak zor buldum:

REM blah blah blah

Daha kolay okunabilir:

:: blah blah blah

Değişken alt dizeler:

> set str=0123456789
> echo %str:~0,5%
01234
> echo %str:~-5,5%
56789
> echo %str:~3,-3%
3456

FOR komutu ! Toplu iş dosyaları yazmaktan nefret ederken, bunun için minnettarım.

FOR /F "eol=; tokens=2,3* delims=, " %i in (myfile.txt) do @echo %i %j %k

noktalı virgülle başlayan satırları yok sayarak, virgül ve / veya boşluklarla sınırlanmış jetonlarla birlikte, her satırdan gövdeye 2. ve 3. jetonu geçiren satırları yok sayar. For body ifadelerinin 2. jetonu almak için% i, 3. jetonu almak için% j ve 3.dan sonra kalan tüm jetonları almak için% k olduğuna dikkat edin.

Bunu dizinler, dizin içerikleri vb. Üzerinden yinelemek için de kullanabilirsiniz.

REM veya :: satırları içeren bir komut dosyasını alt etmek yerine, her komut dosyasının üst kısmında aşağıdakileri yaparım:

@echo OFF
goto :START

Description of the script.

Usage:
   myscript -parm1|parm2 > result.txt

:START

Yöneltme ve yönlendirme karakterlerini kaçmadan nasıl kullanabileceğinizi unutmayın.

Komut dosyasının bulunduğu yol (sürücü ile): ~ dp0

set BAT_HOME=%~dp0
echo %BAT_HOME%
cd %BAT_HOME%

% ~ Dp0 parçasından daha önce bahsedilmişti, ama aslında daha fazlası var: ~ işaretinden sonraki karakter (ler) ayıklanan bilgiyi tanımlar.
Yama dosyası adı dönüşü yok mektup sonucu
d - sürücü harfi döndürür
döndürür yolu - p
s - getirileri kısa yol
x - döndürür dosya uzantısı
Eğer c aşağıda komut TEST.BAT yürütmek Yani: \ Temp \ long dir name \ klasörü,

@echo off
echo %0
echo %~d0
echo %~p0
echo %~dp0
echo %~x0
echo %~s0
echo %~sp0

aşağıdaki çıktıyı alırsınız

test
c:
\Temp\long dir name\
c:\Temp\long dir name\
.bat
c:\Temp\LONGDI~1\test.bat
\Temp\LONGDI~1\

Ve betiğinize
test c: \ temp \ mysrc \ test.cpp'deki gibi bir parametre iletilirse
,% 1 değişkeni ile aynı manipülasyonlar yapılabilir.

Ancak% 0 genişlemesinin sonucu konuma bağlıdır!
Toplu işin "üst düzeyinde" geçerli toplu iş dosya adına genişler.
Bir işlevde (çağrı), işlev adına genişler.

@echo off
echo %0
call :test
goto :eof

:test
echo %0
echo %~0
echo %~n0

Çıktı (batchfile myBatch.bat ile başlatılır)

myBatch.bat
:test
:test
myBatch

CALL, EXIT / B, SETLOCAL ve ENDLOCAL tuşlarını kullanarak yerel değişkenlerle alt rutinler uygulayabilirsiniz.

misal:

@echo off

set x=xxxxx
call :sub 10
echo %x%
exit /b

:sub
setlocal
set /a x=%1 + 1
echo %x%
endlocal
exit /b

Bu yazdırılacak

11
xxxxx

rağmen: sub x'i değiştirir.

N saniye beklemek için gizli numara (cmd.exe'nin bir parçası değil, Windows ile birlikte geldiğinden fazladan bir yazılım değildir), ping hattına bakın. İlk ping gecikmeden söneceği için N + 1 pinglerine ihtiyacınız var.

    echo %time%
    call :waitfor 5
    echo %time%
    goto :eof
:waitfor
    setlocal
    set /a "t = %1 + 1"
    >nul ping 127.0.0.1 -n %t%
    endlocal
    goto :eof

"Sıhhi tesisat" kaçan:

echo ^| ^< ^> ^& ^\ ^^

Komutları çalıştırabilme ve çıktıları işleyebilme (bash içindeki '$ ()' in tersi gibi).

for /f %i in ('dir /on /b *.jpg') do echo --^> %i

Dosya adlarında boşluk varsa bunu kullanın:

for /f "tokens=*" %i in ('dir /on /b *.jpg') do echo --^> %i

Boş bir dosya oluşturma:

> copy nul filename.ext

Bir komuttaki tüm çıktıları gizlemek için> nul 2> & 1'e yönlendirin.

Örneğin, bazı komut satırı programları> nul'e yönlendirseniz bile çıktı görüntüler. Ancak, çıktıyı aşağıdaki satır gibi yönlendirirseniz, tüm çıktılar bastırılır.

PSKILL NOTEPAD >nul 2>&1

DÜZENLEME: Bunun nasıl çalıştığına dair açıklama için bkz . Bir komutun çıkışını yoksayma .

PAUSE

Yürütmeyi durdurur ve aşağıdaki istemi görüntüler:

Devam etmek için herhangi bir tuşa basın . . .

Bir toplu işi Windows Gezgini'nde çift tıklatarak çalıştırmak ve çıktıyı yalnızca komut penceresinin yanıp sönmesi yerine görmek istiyorsanız kullanışlıdır.

Bash (ve diğer mermilerin) eşdeğeri

echo -n Hello # or
echo Hello\\c

" Hello", sondaki yeni satır olmadan çıktı . Bunu yapmak için bir cmd hack:

<nul set /p any-variable-name=Hello

set /pkullanıcıdan girdi girmesini istemenin bir yoludur. Verilen dizeyi yayar ve kullanıcının bir yanıt yazmasını bekler (aynı satırda, yani CRLF yok).

<nulsadece set /pkomuta boş bir yanıt verir , böylece net sonuç yayılan bilgi istemi dizesidir. (Kullanılan değişken, boş yanıt nedeniyle değişmeden kalır.)

Sorunlar: Önde gelen eşittir işaretinin çıktısı alınamaz ve Vista'da önde gelen boşluk karakterleri kaldırılır, ancak XP'de kaldırılmaz.

Ortam değişkenlerini ayarlarken arama ve değiştirme:

> @set fname=%date:/=%

... zaman damgalı dosya adlarında kullanılmak üzere "/" tarihini kaldırır.

ve alt dizeleri de ...

> @set dayofweek=%fname:~0,3%

Tam sayı aritmetiği:

> SET /A result=10/3 + 1
4

Komut ayırıcılar:

cls & dir
copy a b && echo Success
copy a b || echo Failure

2. satırda, && 'den sonraki komut yalnızca ilk komut başarılı olduğunda çalışır.

3. satırda || yalnızca ilk komut başarısız olduğunda çalışır.

Boş satır çıktısı:

echo.

Kısa devre yapan bir boole `ve 'gibi bir etki elde etmek için if ifadelerini zincirleyebilirsiniz.

if foo if bar baz

Bir Unicode metin dosyasını (16bit / char) hızlı bir şekilde ASCII DOS dosyasına (8bit / char) dönüştürmek için.

C:\> type unicodeencoded.txt > dosencoded.txt

bonus olarak, mümkünse karakterler doğru şekilde eşlenir.

blok yapısı ise:

if "%VS90COMNTOOLS%"=="" (
  echo: Visual Studio 2008 is not installed
  exit /b
)

Değişkenlerin gecikmeli genişlemesi (iyi ölçüm için alt dizeler atılmış):

    @echo off
    setlocal enableextensions enabledelayedexpansion
    set full=/u01/users/pax
:loop1
    if not "!full:~-1!" == "/" (
        set full2=!full:~-1!!full2!
        set full=!full:~,-1!
        goto :loop1
    )
    echo !full!
    endlocal

Çok fazla işlevsellik sağlamaz, ancak görev çubuğundaki uzun bir komut dosyasında durum sağlamak veya yalnızca kullanıcı geri bildirimlerini geliştirmek için title komutunu birkaç kullanım için kullanabilirsiniz.

@title Searching for ...
:: processing search
@title preparing search results
:: data processing

Kullanışlı bir düzenleyiciniz yok ve toplu iş dosyası mı oluşturmanız gerekiyor?

copy con test.bat

Sadece komutları yazın, yeni bir satır için enter tuşuna basın. Dosyayı kapatmak için Ctrl-Z ve Enter tuşlarına basın.

"YYYY-AA-GG SS: DD: SS.txt" adlı dosyayı almak dateve timealmak için dize çıkarma örneği

echo test > "%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%_%time:~3,2%_%time:~6,2%.txt"

kullanırım colorBetiğimin başarılı bir şekilde bitip bitmediğini, başarısız olduğunu veya metin ve arka plan rengini değiştirerek bazı girdilere ihtiyaç duyduğunu belirtmek için . Görüş alanınıza erişebileceğiniz ancak oldukça uzaktaki bir makineniz olduğunda gerçekten yardımcı olur

renk XY

burada X ve Y, 0ila arasındaki onaltılık değerdirF , burada X = Y rengi değişmediğinde X - arka planı, Y - metni.

renk Z

metin rengini 'Z' olarak değiştirir ve siyah arka planı ayarlar, 'renk 0' çalışmaz

renk isimleri için

renk ?

Boşluk ve kaçış karakterleriyle çıktı üzerinde tam kontrol:

echo.    ^<resourceDir^>/%basedir%/resources^</resourceDir^>

TheSoftwareJedi zaten for komutundan bahsetti, ama çok güçlü olduğu için tekrar anlatacağım.

Aşağıdaki geçerli tarihi YYYYMMDD biçiminde çıktılar, ben yedekleme için dizinler oluştururken bunu kullanın.

for /f "tokens=2-4 delims=/- " %a in ('DATE/T') do echo %c%b%a