Google SpreadSheet Query: Sütun başlığını kaldırabilir miyim?

102

Bu sorguyu google elektronik tablomda yapıyorum:

=QUERY(H4:L35;"select sum(L) where H='First Week'"; -1)

Ancak, başlık olarak "toplam" ve altında sonuç olan küçük bir tablo döndürür. İstediğim sadece sonuç! Başlığı nasıl kaldırırım? Yapabilirmiyim?

— Poliane Brito
kaynak

Bu daha basit görünüyor: stackoverflow.com/a/41797729/5316231

— user19581

194

Bunu dene:

=QUERY(H4:L35,"select sum(L) where H='First Week' label sum(L) ''")

Umarım yardımcı olur!

— KRR
kaynak

3

Bunu sayfalarımdan birinde test ettim ve başlığı döndürülen sonuçlardan kaldırıyor; bu doğru cevap olarak işaretlenmelidir. :)

— FooBar

1

Bu harika ve işe yarıyor, ama sonunda iki tek tırnak işaretine neden ihtiyaç duyulduğunu kimse açıklayabilir mi? Sözdizimi açısından bakıldığında bu ne yapar?

— y-i_guy

2

Tek tırnak, toplam başlığını boş alanla değiştirir. Umarım bu sorunuzu açıklar !!

— KRR

2

Cevap için teşekkürler! Aynı şeyi birden fazla sütunla yapmam gerekiyor ama başaramıyorum! Bunun işe yarayacağını bekliyordum: = QUERY (H4: L35, "toplamı (L), toplamı (H) seçin, burada H = 'İlk Hafta' etiket toplamı (L) '' etiket toplamı (H) ''")

— Emilio Nicolás

12

LABEL B 'Label1', C 'Label2'birden çok sütun için

— sojim2

31

=QUERY(QUERY(A1:D, "SELECT *", 1), "SELECT * OFFSET 1", 0)

Dış sorgu: "SELECT * OFFSET 1"ilk satırı (başlık) hariç tutar.

İç sorgu açıkça bir satır üstbilgi belirtir (üçüncü bağımsız değişken aracılığıyla QUERY), dış sorgu ise hiçbirini belirtir.

— user280150
kaynak

3

Biraz açıklama mı?

— J Fabian Meier

İkincisi neden QUERYgerekli? "0" parametresi üstbilgileri düşürmez, böylece ilkinde kullanabilirsiniz QUERY, şu şekilde: QUERY('Form responses 3'!$A$2:$P$1017, "SELECT max(E),max(C), max(D) WHERE B='" & B14 & "' GROUP BY B LIMIT 1 ", 0)

— Steven M. Mortimer

3

OFFSET 1İkinci sorgunun, ilk satırdaki başlıkları değil, döndürülen veri kümesinin ilk satırını bırakacağına inanıyorum .

— Steven M. Mortimer

2

Bu cevap daha ayrıntılı olabilir, ancak aynı zamanda daha sağlamdır ve sütun toplama dizelerini çoğaltmaya gerek kalmadan kullanılabilir. Burada pivotbaşka herhangi bir cevapla çalışmayan ile bile kullanılabilir .

— 7yl4r

1

Yanılmadığım sürece, bu aslında orijinal gönderen tarafından sunulan spesifik zorluğu, yani SUM gibi toplama işlevlerini kullanırken QUERY tarafından otomatik olarak oluşturulan başlıkları kaldırmaz. SUM (veya başka bir toplama işlevi) kullanılırken, QUERY otomatik olarak gerçekleştirilen toplamayı belirten bir başlık satırı oluşturur, örneğin "toplam". Üstbilgileri 0'a ayarlasanız ve OFFSET 1 yan tümcesini uygulasanız bile bunu yapacaktır. Aşağıdaki formül yine de üstbilgi döndürür. = SORGU (Sayfa1! A: B, "SEÇ A, TOPLA (B) BİR OFSETE GÖRE GRUP 1", 0) Kabul edilen yanıt bu sorunu çözer.

— Dave Meindl

0

İlk 3'ü döndüren bir QUERY var. Birden çok satır döndürürken bunu çalıştıramadım. Formülü içeren satırı gizledim ve şimdi sadece cevaplar gösteriliyor.

— Brian Wochele
kaynak

0

=INDEX(QUERY(H4:L35;"select sum(L) where H='First Week'"; -1),2,1)

Bu sadece döndürülen diziyi ayrıştırır ve ilk sütunda döndürülen 2. kaydı seçer.

Bunu, daha az işlem gerektiren filtre işlevi ile de yapabilirsiniz.

=SUM(FILTER(L4:L35, H4:H35 = "First Week"))

— Dean Falconer
kaynak

-1

Sütun adlarını kullanarak boşluk olarak etiketlemek yerine, ''aşağıdaki gibi tüm başlıkları atlayabilirsiniz:

=QUERY(H4:L35,"select sum(L) where H='First Week'", 0)

— Steven M. Mortimer
kaynak

Kabul edilen yanıt teknik olarak daha doğru göründüğünde, bu sorunu çözmek için en basit yöntem ve hatırlanması daha kolay görünüyor. Bir şeyi kaçırmadıysam bu cevaba daha çok

— Ewen

16

Bu cevap, "toplamı" bir "başlık satırı" olarak kaldırmaz. Sorgu komutuna, sorgulanan verilerde dikkate alınacak başlık satırı olmadığını söyler, ancak sorgunun sonuçlar tablosuna "istenmeyen başlık" eklemesini durdurmaz.

— Jimmy

-3

Formata buradan bakın .

Misal:

=QUERY(B4:C38,
   "SELECT C, sum(B) where C!='' group by C label C 'Member', sum(B) 'Sum'"
)

— Andy
kaynak

2

Sağlanan örnek, başlıksız bir sonuç döndürmez.

— Rubén