VBA işlevinden sonuç döndürme

Bir işlevden nasıl sonuç döndürürüm?

Örneğin:

Public Function test() As Integer
    return 1
End Function

Bu bir derleme hatası verir.

Bu işlevin bir tamsayı döndürmesini nasıl sağlayabilirim?

Nesne dışı dönüş türleri için, değeri işlevinizin adına şu şekilde atamanız gerekir:

Public Function test() As Integer
    test = 1
End Function

Örnek kullanım:

Dim i As Integer
i = test()

İşlev bir Nesne türü döndürürse, Setanahtar sözcüğü aşağıdaki gibi kullanmanız gerekir :

Public Function testRange() As Range
    Set testRange = Range("A1")
End Function

Örnek kullanım:

Dim r As Range
Set r = testRange()

İşlev adına bir dönüş değeri atamanın, işlevinizin yürütülmesini sonlandırmayacağını unutmayın. İşlevden çıkmak istiyorsanız, açıkça söylemeniz gerekir Exit Function. Örneğin:

Function test(ByVal justReturnOne As Boolean) As Integer
    If justReturnOne Then
        test = 1
        Exit Function
    End If
    'more code...
    test = 2
End Function

Belgeler: http://msdn.microsoft.com/en-us/library/office/gg264233%28v=office.14%29.aspx

VBA işlevleri, işlev adının kendisine bir tür değişken olarak davranır. Yani, " return" ifadesi kullanmak yerine şunu söylerdiniz:

test = 1

Bununla birlikte, bunun işlevden kopmadığına dikkat edin. Bu ifadeden sonraki kodlar da yürütülür. Böylece, farklı değerler atayan birçok atama ifadeniz olabilir testve işlevin sonuna ulaştığınızda değer ne olursa olsun döndürülen değer olacaktır.

Dönüş değerinin işlev adına ayarlanması hala Java (veya diğer) ifadesiyle tam olarak aynı değildir return, çünkü returnjava'da işlevden şu şekilde çıkar:

public int test(int x) {
    if (x == 1) {
        return 1; // exits immediately
    }

    // still here? return 0 as default.
    return 0;
}

VB'de, işlevinizin sonunda dönüş değerini ayarlamıyorsanız tam eşdeğer iki satır alır . Yani, VB'de kesin sonuç şu şekilde görünecektir:

Public Function test(ByVal x As Integer) As Integer
    If x = 1 Then
        test = 1 ' does not exit immediately. You must manually terminate...
        Exit Function ' to exit
    End If

    ' Still here? return 0 as default.
    test = 0
    ' no need for an Exit Function because we're about to exit anyway.
End Function 

Bu durumda, dönüş değişkenini yöntemdeki diğer değişkenler gibi kullanabileceğinizi bilmek de güzel. Bunun gibi:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test <> 1 Then ' Test the currently set return value
        test = 0 ' Reset the return value to a *new* value
    End If

End Function 

Ya da, dönüş değişkeninin nasıl çalıştığına dair en uç örnek (ancak aslında nasıl kod yazmanız gerektiğine dair iyi bir örnek değil) - sizi geceleri ayakta tutacak olan:

Public Function test(ByVal x As Integer) As Integer

    test = x ' <-- set the return value

    If test > 0 Then

        ' RECURSIVE CALL...WITH THE RETURN VALUE AS AN ARGUMENT,
        ' AND THE RESULT RESETTING THE RETURN VALUE.
        test = test(test - 1)

    End If

End Function

Değişkene kod mağaza aşağıdaki dönüş değeri retValve daha sonra MsgBoxdeğerini göstermek için kullanılabilir:

Dim retVal As Integer
retVal = test()
Msgbox retVal