Vim'de birden çok tampon nasıl silinir?

Vim'de tampon olarak açılmış birden fazla dosyam olduğunu varsayarsak. Dosyalar var *.cpp, *.hve bazıları *.xml. Tüm XML dosyalarını ile kapatmak istiyorum :bd *.xml. Ancak Vim buna izin vermiyor (E93: Birden fazla maç ...).

Bunu yapmanın bir yolu var mı?

PS Bunun :bd file1 file2 file3işe yaradığını biliyorum . Bir şekilde Yani değerlendirebilir *.xmliçin file1.xml file2.xml file3.xml?

<C-a>Tüm maçları tamamlamak için kullanabilirsiniz . Yani yazıp :bd *.xmlsonra vurursanız <C-a>, vim komutunu tamamlayacaktır :bd file1.xml file2.xml file3.xml.

:3,5bd[elete]   

Arabellek aralığı 3'ten 5'e silinir.

Alternatif olarak şunları da kullanabilirsiniz:

    :.,$-bd[elete]    " to delete buffers from the current one to last but one
    :%bd[elete]       " to delete all buffers

Bunu kullanabilirsin.

:exe 'bd '. join(filter(map(copy(range(1, bufnr('$'))), 'bufname(v:val)'), 'v:val =~ "\.xml$"'), ' ')

Bir komuta eklemek oldukça kolay olmalı.

function! s:BDExt(ext)
  let buffers = filter(range(1, bufnr('$')), 'buflisted(v:val) && bufname(v:val) =~ "\.'.a:ext.'$"')
  if empty(buffers) |throw "no *.".a:ext." buffer" | endif
  exe 'bd '.join(buffers, ' ')
endfunction

command! -nargs=1 BDExt :call s:BDExt(<f-args>)

Aşağıdaki komut dosyasını deneyin. Örnek "txt" içindir, gerektiği gibi değiştirin, örneğin "xml" olarak. Değiştirilen tamponlar silinmez. Tamponları silmek için \ bd'ye basın.

map <Leader>bd :bufdo call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   if (matchstr(bufname("%"), ".".a:strExt."$") == ".".a:strExt )
      if (! &modified)
         bd
      endif
   endif
endfunction

[Düzenle] Aynı: bufdo (Luc Hermitte tarafından talep edildiği gibi, aşağıdaki yoruma bakın)

map <Leader>bd :call <SID>DeleteBufferByExtension("txt")

function!  <SID>DeleteBufferByExtension(strExt)
   let s:bufNr = bufnr("$")
   while s:bufNr > 0
       if buflisted(s:bufNr)
           if (matchstr(bufname(s:bufNr), ".".a:strExt."$") == ".".a:strExt )
              if getbufvar(s:bufNr, '&modified') == 0
                 execute "bd ".s:bufNr
              endif
           endif
       endif
       let s:bufNr = s:bufNr-1
   endwhile
endfunction

Benim de bu işlevselliğe her zaman ihtiyacım vardı. Vimrc'imde sahip olduğum çözüm bu.

function! GetBufferList()
    return filter(range(1,bufnr('$')), 'buflisted(v:val)')
endfunction

function! GetMatchingBuffers(pattern)
    return filter(GetBufferList(), 'bufname(v:val) =~ a:pattern')
endfunction

function! WipeMatchingBuffers(pattern)
    let l:matchList = GetMatchingBuffers(a:pattern)

    let l:count = len(l:matchList)
    if l:count < 1
        echo 'No buffers found matching pattern ' . a:pattern
        return
    endif

    if l:count == 1
        let l:suffix = ''
    else
        let l:suffix = 's'
    endif

    exec 'bw ' . join(l:matchList, ' ')

    echo 'Wiped ' . l:count . ' buffer' . l:suffix . '.'
endfunction

command! -nargs=1 BW call WipeMatchingBuffers('<args>')

Şimdi sadece yapabilirim :BW regex(örneğin:BW \.cpp$ ve yol adlarında bu kalıba uyan tüm eşleşen tamponları silebilirim.

Silmek yerine silmek isterseniz, elbette exec 'bw ' . join(l:matchList, ' ')şununla değiştirebilirsiniz:exec 'bd ' . join(l:matchList, ' ')

Çok basit: :bd[elete]komutu kullanın. Örneğin, :bd[elete] buf#1 buf#5 buf#31, 3 ve 5 arabelleklerini silecektir.

TABSadece Vim 7.4.282 itibariyle sizin için bir dosya otomatik olarak tamamlar
kullanım <c-a>tüm dosyaları otomatik olarak tamamlanması için.

Sadece kullanabilirsiniz:

bd filetype

daha sonra <c-a>belirtilen dosya türündeki tüm açık dosyaların tamamlanmasını kolaylaştırmak için kullanın .

örneğin, 1.xml, 2.xml, 3.xml ve 4.xml’ye sahipseniz şunları yapabilirsiniz:

bd xml

sonra basın <c-a>

vim sizin için şu şekilde otomatik tamamlayacaktır:

bd 1.xml 2.xml 3.xml 4.xml

Komutu tamamlamak için sadece enter tuşuna basabilirsiniz.

Yukarıda belirtilen dosyalardan birinde değişiklik yaptıysanız şunları yapmayı unutmayın:

bd! xml