VBA kullanmadan Excel'de nasıl ters dize araması yapabilirim?

Dizelerin listesini içeren bir Excel elektronik tablosu var. Her dize birkaç kelimeden oluşur, ancak her dizedeki kelime sayısı farklıdır.

Yerleşik Excel işlevlerini (VBA yok) kullanarak, her dizedeki son sözcüğü izole etmenin bir yolu var mı?

Örnekler:

  İnsan olarak sınıflandırıldınız mı? -> insan?
Olumsuz, ben bir et buzlu şekeriyim -> buzlu şeker
                  Aziz! Işık! -> Işık!

Bu test edilir ve işe yarar (Brad'in orijinal postasına dayanarak):

=RIGHT(A1,LEN(A1)-FIND("|",SUBSTITUTE(A1," ","|",
     LEN(A1)-LEN(SUBSTITUTE(A1," ","")))))

Orijinal dizelerinizde bir boru "|" sonra, her ikisini de kaynağınızda görünmeyen başka bir karakterle değiştirin. (Çeviride yazdırılamayan bir karakter kaldırıldığı için Brad'in orijinalinin kırıldığından şüpheleniyorum).

Bonus: Nasıl çalışır (sağdan sola):

LEN(A1)-LEN(SUBSTITUTE(A1," ",""))- Orijinal dizedeki boşluk sayısı
SUBSTITUTE(A1," ","|", ... )- Yalnızca son boşluğu a ile değiştirir |
FIND("|", ... )- Değiştirilenin |(son boşluk olan) mutlak konumunu bulur
Right(A1,LEN(A1) - ... ))- Bundan sonraki tüm karakterleri döndürür|

DÜZENLE: kaynak metinde boşluk bulunmadığı durumu hesaba katmak için formülün başına aşağıdakileri ekleyin:

=IF(ISERROR(FIND(" ",A1)),A1, ... )

tüm formülü şimdi yapmak:

=IF(ISERROR(FIND(" ",A1)),A1, RIGHT(A1,LEN(A1) - FIND("|",
    SUBSTITUTE(A1," ","|",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))))

Veya =IF(COUNTIF(A1,"* *")diğer sürümün sözdizimini kullanabilirsiniz .

Orijinal dize son konumda bir boşluk içerebiliyorsa, tüm boşlukları sayarken bir kırpma işlevi ekleyin: İşlevi şu şekilde yapmak:

=IF(ISERROR(FIND(" ",B2)),B2, RIGHT(B2,LEN(B2) - FIND("|",
    SUBSTITUTE(B2," ","|",LEN(TRIM(B2))-LEN(SUBSTITUTE(B2," ",""))))))

Büyük bir başarıyla kullandığım teknik:

=TRIM(RIGHT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Bir dizedeki ilk kelimeyi almak için SAĞ'dan SOLA

=TRIM(LEFT(SUBSTITUTE(A1, " ", REPT(" ", 100)), 100))

Ayrıca, A1'i metni tutan hücre ile değiştirin.

Jerry'nin cevabının daha sağlam bir versiyonu:

=TRIM(RIGHT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(TRIM(A1))))

Bu, ipin uzunluğuna, önde gelen veya arkadaki boşluklara veya başka herhangi bir şeye bakılmaksızın çalışır ve hala oldukça kısa ve basittir.

Bulduğum bu Excel 2003'te test, google & o benim için çalışıyor:

=IF(COUNTIF(A1,"* *"),RIGHT(A1,LEN(A1)-LOOKUP(LEN(A1),FIND(" ",A1,ROW(INDEX($A:$A,1,1):INDEX($A:$A,LEN(A1),1))))),A1)

Yorum yapmak için yeterli temsilcim yok, bu yüzden bu en iyi yer gibi görünüyor ... BradC'nin cevabı da sondaki boşluklarla veya boş hücrelerle
çalışmıyor ... [2. düzenleme] aslında, bunun için çalışmıyor ya tek kelimeler ...

=RIGHT(TRIM(A1),LEN(TRIM(A1))-FIND(CHAR(7),SUBSTITUTE(" "&TRIM(A1)," ",CHAR(7),
LEN(TRIM(A1))-LEN(SUBSTITUTE(" "&TRIM(A1)," ",""))+1))+1)

Bu çok sağlam - boşluk içermeyen cümleler için çalışır, önde / sonda boşlukları, çoklu boşluklar, çoklu önde gelen / sondaki boşluklar ... ve dikey çubuk yerine | | İstenilen bir metin öğesi olması durumunda.

Bu çok temiz ve kompakt ve iyi çalışıyor.

{=RIGHT(A1,LEN(A1)-MAX(IF(MID(A1,ROW(1:999),1)=" ",ROW(1:999),0)))}

Boşluk veya bir kelime için tuzak hatası yapmaz, ancak eklemek kolaydır.

Düzenle:
Sondaki boşlukları, tek sözcük ve boş hücre senaryolarını yönetir. Onu kırmanın bir yolunu bulamadım.

{=RIGHT(TRIM(A1),LEN(TRIM(A1))-MAX(IF(MID(TRIM(A1),ROW($1:$999),1)=" ",ROW($1:$999),0)))}

=RIGHT(A1,LEN(A1)-FIND("`*`",SUBSTITUTE(A1," ","`*`",LEN(A1)-LEN(SUBSTITUTE(A1," ",""))))) 

Jerry ve Joe'nun cevaplarına eklemek için, kullanabileceğiniz son kelimeden ÖNCE metni bulmak istiyorsanız:

=TRIM(LEFT(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))), LEN(SUBSTITUTE(TRIM(A1), " ", REPT(" ", LEN(TRIM(A1)))))-LEN(TRIM(A1))))

A1'deki 'benim küçük kedim' ile 'Benim küçük'üm olur (Joe ve Jerry'nin' kedi 'vereceği yer)

Jerry ve Joe'nun son kelimeyi izole ettiği gibi, bu da her şeyi bunun soluna getirir (sonra geri keser)

Dizenin ters çevrilebileceğini düşünün. O zaman gerçekten kolay. Dize üzerinde çalışmak yerine:

"My little cat" (1)

ile çalışıyorsun

"tac elttil yM" (2)

İle =LEFT(A1;FIND(" ";A1)-1)A2 Alacağınız "My"(1) ile ve "tac"ters (2) ile "cat", (1) son kelime.

Bir dizgeyi tersine çevirmek için birkaç VBA vardır. Genel VBA işlevini tercih ederim ReverseString.

Yukarıda anlatıldığı gibi kurun. Sonra dizeniz A1'de, örneğin "My little cat"A2'de bu işlevle:

=ReverseString(LEFT(ReverseString(A1);IF(ISERROR(FIND(" ";A1));
  LEN(A1);(FIND(" ";ReverseString(A1))-1))))

"cat"A2'de göreceksiniz .

Yukarıdaki yöntem, kelimelerin boşluklarla ayrıldığını varsayar. IFMaddesi tek kelime = hücre içinde hiç boşlukları içeren hücrelerin içindir. Not: TRIMve CLEANorijinal dize de yararlıdır. Prensip olarak A1'in tüm dizesini tersine çevirir ve tersine çevrilmiş dizede ilk (boş) sözcüğün (yani) yanındaki ilk boşluğu bulur "tac ". LEFTbu kelimeyi alır ve başka bir dize tersine çevirme, kelimenin ( " cat") orijinal sırasını yeniden oluşturur . -1Sonunda FINDdeyimi boş kaldırır.

Fikir, bir dizideki ilk (!) Kelimeyi ilk boş ile birlikte LEFTve ayıklamak kolay olmasıdır FIND. Ancak, son (!) Sözcüğü için RIGHTbunu yapmaya çalıştığınızda işlev yanlış seçimdir, çünkü ne yazık ki FIND, dizenizi analiz etmek istediğiniz yöne yönelik bir bayrağa sahip değildir.

Bu nedenle tüm dize basitçe tersine çevrilir. LEFTve FINDnormal olarak çalışır ancak çıkarılan dize ters çevrilir. Ama bir ipi nasıl tersine çevireceğinizi bildiğinizde onun büyük bir önemi yok. ReverseStringFormüldeki ilk ifade bu işi yapar.

=LEFT(A1,FIND(IF(
 ISERROR(
  FIND("_",A1)
 ),A1,RIGHT(A1,
  LEN(A1)-FIND("~",
   SUBSTITUTE(A1,"_","~",
    LEN(A1)-LEN(SUBSTITUTE(A1,"_",""))
   )
  )
 )
),A1,1)-2)

Bir sütuna kopyalayın, o sütunu seçin ve HOME> Düzenleme> Bul ve Seç, Değiştir:

Replace All.

Yıldız işaretinden sonra bir boşluk var.

Buna ihtiyacım olduğu için PT-BR'ye çevirdim.

(Alanı \yalnızca yol dizelerinin dosya adına ihtiyacım olduğu için olarak değiştirdiğimi lütfen unutmayın .)

=SE(ÉERRO(PROCURAR("\",A1)),A1,DIREITA(A1,NÚM.CARACT(A1)-PROCURAR("|", SUBSTITUIR(A1,"\","|",NÚM.CARACT(A1)-NÚM.CARACT(SUBSTITUIR(A1,"\",""))))))

Bunu başarmanın başka bir yolu aşağıdaki gibidir

=IF(ISERROR(TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14))))),TRIM(D14),TRIM(MID(TRIM(D14),SEARCH("|",SUBSTITUTE(TRIM(D14)," ","|",LEN(TRIM(D14))-LEN(SUBSTITUTE(TRIM(D14)," ","")))),LEN(TRIM(D14)))))

Ayrıca böyle bir görev vardı ve bittiğinde, yukarıdaki yöntemi kullanarak, bana yeni bir yöntem oluştu: Neden bunu yapmıyorsun:

1. Dizeyi tersine çevirin ("dize bir" "eno gnirts" olur).
2. İyi eski Bul'u (soldan sağa için kodlanmış) kullanın.
3. Tekrar okunabilir dizeye geri çevirin.

Kulağa nasıl geliyor?