Windows toplu komut dosyasında (.bat) iletilen bağımsız değişkenlerin listesini alma

Bash $@için bir betik içine aktarılan tüm argümanların bir listesini tutan bir Windows toplu karşılığı bulmak istiyorum .

Yoksa uğraşmak zorunda shiftmıyım?

dancavallaro , %*tüm komut satırı parametreleri için (komut dosyası adının kendisi hariç) buna sahiptir. Bunları da yararlı bulabilirsiniz:

%0- toplu iş dosyasını aramak için kullanılan komut (olabilir foo, ..\foo, c:\bats\foo.batvs.)
%1ilk komut satırı parametresidir
%2ikinci komut satırı parametresidir,
ve böylece dek üzerinde %9(ve SHIFT9 sonra olanlar için kullanılabilir).

%~nx0- çağrı yönteminden bağımsız olarak toplu iş dosyasının gerçek adı (some-batch.bat)
%~dp0- komut dosyasının sürücüsü ve yolu (d: \ komut dosyaları)
%~dpnx0- komut dosyasının tam yol adıdır (d: \ komut dosyaları \ bazı -batch.bat)

Https://www.ss64.com/nt/syntax-args.html ve https://www.robvanderwoude.com/parameters.html adresinden daha fazla bilgi örneği

%* senaryoya iletilen tüm argümanları barındırıyor gibi görünüyor.

%1... %nve %*argümanları tutar, ancak bunlara erişmek zor olabilir, çünkü içerik yorumlanacaktır.
Bu nedenle böyle bir şeyi normal ifadelerle ele almak imkansızdır

myBatch.bat "&"^&

Her satır başarısız olur, çünkü cmd.exe ve işaretlerinden birini yürütmeye çalışır (% 1 içeriği "&"&)

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Ancak geçici bir dosyaya sahip bir geçici çözüm var

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Hile, bir ifadeden sonra etkinleştirmek echo onve genişletmektir (% 2 ..% * ile de çalışır). Ancak çıktısını yeniden yönlendirebilmek için iki FOR-LOOPS'a ihtiyacınız var. %1rem
echo on

Ekstra karakterler * #, /?(REM yardımını gösterir) gibi içeriklere karşı güvenli olmak için kullanılır.
Veya satır sonundaki bir düzeltme işareti ^ çok satırlı bir karakter olarak çalışabilir.

FOR / F gecikmeli genişleme kapalı, "!" yok olur.
Ekstra karakterleri çıkardıktan sonra anladınız param1.

param1Güvenli bir şekilde kullanmak için, gecikmeli genişletmeyi etkinleştirin.

Düzenleme:% 0'a bir açıklama

%0Ayrıca olduğu gibi dava koruyarak toplu çağırmak için kullanılan komutu içeren FoO.BaT
bir işleve yapılan çağrının ardından But %0ve aynı zamanda %~0işlev adı (veya işlevi çağırmak için kullanılan daha iyi dize) içeriyor.
Ama %~f0seninle hala dosya adını hatırlayabilirsin.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Çıktı

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Bunu bir dahaki sefere bu bilgilere bakmanız gerektiğinde buldum. Bir tarayıcı açmak ve Google'ı kullanmak yerine, call /?cmd'nizi yazmanız yeterlidir:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

Bir komut dosyasına tüm argümanları almanın yolu burada:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

İşte args almak ve env vars olarak ayarlamak için oldukça basit bir yol. Bu örnekte, sadece Anahtarlar ve Değerler olarak bahsedeceğim.

Aşağıdaki kod örneğini "args.bat" olarak kaydedin. Ardından, komut satırından kaydettiğiniz toplu iş dosyasını çağırın. örnek: arg.bat --x 90 --y 120

İşlem boyunca size adım atmak için bazı yankı komutları sağladım. Ancak sonuç --x'in 90 ve --y'nin 120 değerine sahip olacağıdır (yani, yukarıda belirtilen örneği çalıştırırsanız ;-)).

Daha sonra kod bloğunuzun çalıştırılıp çalıştırılmayacağını belirlemek için 'tanımlanmışsa' koşullu ifadeyi kullanabilirsiniz. Yani diyelim run: "arg.bat --x hello-world" Daha sonra "IF DEFINED --x echo% - x%" ifadesini kullanabilirim ve sonuçlar "merhaba-dünya" olur. Toplu işi çalıştırmanız daha anlamlı olacaktır.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Tüm argümanları almak için saf döngüyü kullanmak için:

Obs: Olmadan kullanmak için:?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

Kodunuz ihtiyaç duyduğu argüman numarasıyla bir şeyler yapmaya hazır, örneğin ...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

Aşağıdaki kod bir diziyi simüle eder (' params') - kod tarafından alınan parametreleri alır ve bunları değişkenlere kaydeder params_1. params_nBurada n= params_0= dizinin elemanlarının sayısı:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

Tırnak içeren boşluk içeren parametreleriniz varsa, %*düzgün çalışmaz. Bulduğum en iyi çözüm, tüm argümanları birleştiren bir döngüye sahip olmak: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Kullanabilirsiniz ForArg listesini almak Commad'ı .

Yardım : For /? Yardım:Setlocal /?

İşte benim yolum =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Shift komutuna gerek yoktur.

@Eko kapalı
:Başlat

:: Kodunuzu buraya girin
echo. %% 1 şimdi:% ~ 1
:: Son kodunuzu buraya ekleyin

"% ~ 2" NEQ "" ise (
    vardiya
    goto: başlat
)

Yukarıdaki bilgilerin birçoğu beni daha fazla araştırmaya ve nihayetinde cevabımı getirdi, bu yüzden yaraladığım şeyin başka birine yardımcı olmasını umarak katkıda bulunmak istedim:

• Ayrıca dosya içinde işlenebilmesi için bir toplu iş dosyasına değişken sayıda geçmek istedim.

• Onları kullanarak toplu iş dosyasına geçirerek Tamam

• Bunların aşağıdakine benzer şekilde işlenmesini isterdim - ancak manuel olarak yazmak yerine bir döngü kullanarak:

Bu yüzden bunu yürütmek istedim:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

Ve döngülerin büyüsü aracılığıyla bunu toplu iş dosyasında yapın:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Sahip olduğum sorun, for döngüsü kullanmak için tüm girişimlerimin çalışmadığıydı. Aşağıdaki örnek:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

sadece yapardı:

set "_appPath=C:\Services\Logs\PCAP"

ve yok:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

ayarladıktan sonra bile

SETLOCAL EnableDelayedExpansion

Nedeni, for döngüsünün tüm satırı okuması ve döngünün ilk yinelemesi sırasında ikinci parametremi %% B'ye atamasıydı. % * Tüm bağımsız değişkenleri temsil ettiğinden, işlenecek yalnızca tek bir satır vardır - for döngüsünün yalnızca bir geçişi gerçekleşir. Bu tasarım gereği ortaya çıkıyor ve mantığım yanlıştı.

Bu yüzden bir for döngüsü kullanmaya çalışmayı bıraktım ve if, shift ve goto ifadelerini kullanarak yapmaya çalıştığım şeyi basitleştirdim. Anlaşıldı onun bir kesmek biraz ama benim ihtiyaçlarına daha uygundur. Tüm argümanlar arasında döngü ve sonra hepsini işledikten sonra döngü dışına bırakmak için bir if deyimi kullanabilirsiniz.

Yapmaya çalıştığım şeyin kazanan ifadesi:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

GÜNCELLEME - Bunun yerine aşağıdakileri değiştirmek zorunda kaldım,% 1'e başvurmaya çalışırken ve vardiyayı bu şekilde kullanırken tüm ortam değişkenlerini ortaya koydum:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Bazen birkaç komut satırı parametresini çıkarmam gerekiyor, ama bunların hepsini değil, birinciden değil. Aşağıdaki çağrıyı varsayalım:

Test.bat uno dos tres cuatro cinco seis siete

Tabii ki, ".bat" uzantısı en azından gerekli değil aynı klasörde test.exe var. İstediğimiz şey "tres cuatro cinco" çıktısını elde etmektir (bir satır veya üç olursa olsun). Amaç sadece üç parametreye ihtiyacım var ve üçüncü parametreden başlayarak. Basit bir örneğe sahip olmak için, her biri için eylem sadece "eko" dur, ancak seçilen parametreler üzerinde daha karmaşık bir eylem düşünebilirsiniz.

Hangisini daha iyi gördüğünüzü görebilmek için bazı örnekler (seçenekler) ürettim. Ne yazık ki, "için %% i (% 3, 1,% 5)" aralığı gibi bir for döngüsü temel alan güzel (veya bilmiyorum) bir yol yoktur.

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

Muhtemelen daha fazla seçenek bulabilir veya birkaçını birleştirebilirsiniz. Eğlen.

Windows sürümü (gerçi socat gerekir)

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

kurma:

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd