Cihazınıza bir düğme eklediniz DataGridViewve tıklandığında bir kod çalıştırmak istiyorsunuz.
Kolay peasy - sadece şu adımları izleyin:
Yapılmaması Gerekenler:
İlk olarak, YAPMAYINIZ :
Ben burada diğer cevapların bazı önerileri önlemek ve hatta bir belge tıklanmış olup olmadığını belirlemek için sütun dizini veya sütun adını sabit kodlamak için MSDN belgeleri tarafından sağlanan bile . Click olayı tüm ızgaraya kaydolur, bu nedenle bir şekilde bir düğmenin tıklandığını belirlemeniz gerekir, ancak düğmenizin belirli bir sütun adında veya dizinde yaşadığını varsayarak bunu yapmamalısınız ... daha kolay bir yol var ...
Ayrıca, hangi etkinliği gerçekleştirmek istediğinize dikkat edin. Yine, belgeler ve birçok örnek bunu yanlış anlıyor. Çoğu örnek, işlenecek olan CellClickolayı ele alır :
bir hücrenin herhangi bir parçası tıklandığında.
... ancak satır başlığı her tıklandığında tetiklenir. Bu, e.RowIndexdeğerin 0'dan küçük olup olmadığını belirlemek için ekstra kod eklemeyi gerektirir
Bunun yerine CellContentClicksadece gerçekleşen işlemek :
bir hücredeki içerik tıklandığında
Hangi nedenle olursa olsun, sütun başlığı da bir hücre içinde 'içerik' olarak kabul edilir, bu yüzden aşağıda bunu kontrol etmemiz gerekir.
Dos:
İşte yapmanız gerekenler:
İlk olarak, döküm tipine gönderenDataGridView tasarım esnasında iç özelliklerini bulunuyor ortaya çıkarmak. Parametredeki türü değiştirebilirsiniz, ancak bu bazen işleyicileri eklemeyi veya kaldırmayı zorlaştırabilir.
Ardından, bir düğmenin tıklanıp tıklanmadığını görmek için, etkinliği artıran sütunun türünde olduğundan emin olun DataGridViewButtonColumn. Göndereni zaten yazmak için yayınladığımızdan DataGridView, Columnskoleksiyonu alabilir ve geçerli sütunu kullanarak seçebiliriz e.ColumnIndex. Sonra bu nesnenin türünü kontrol edin DataGridViewButtonColumn.
Tabii ki, ızgara başına birden çok düğmeyi ayırt etmeniz gerekiyorsa, sütun adına veya dizinine göre seçim yapabilirsiniz, ancak bu ilk kontrolünüz olmamalıdır. Her zaman önce bir düğmenin tıklandığından emin olun ve sonra başka bir şeyi uygun şekilde kullanın. Izgara başına yalnızca tek bir düğmenizin olduğu çoğu durumda, hemen yarışlara atlayabilirsiniz.
Hepsini bir araya koy:
C # :
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB :
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
Güncelleme 1 - Özel Etkinlik
Biraz eğlenmek istiyorsanız, DataGrid'de bir düğmeye her tıklandığında kendi etkinliğinizi ekleyebilirsiniz. Kalıtım vb.Ile karışmadan DataGrid'e ekleyemezsiniz, ancak formunuza özel bir olay ekleyebilir ve uygun olduğunda tetikleyebilirsiniz. Bu biraz daha kod, ancak üst kısım, bir düğmeye tıklandığında ne yapmak istediğinizi, bir düğmenin tıklanıp tıklanmadığını nasıl belirleyeceğinizi ayırmanızdır.
Bir olayı beyan edin, uygun olduğunda yükseltin ve yönetin. Bunun gibi görünecek:
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
Güncelleme 2 - Genişletilmiş Izgara
Bizim için sadece bu şeyleri yapan bir ızgarayla çalışsaydık harika olurdu. Biz kolayca başlangıç soruya cevap verebilir: you've added a button to your DataGridView and you want to run some code when it's clicked. İşte bu yaklaşımı genişleten bir yaklaşım DataGridView. Her kitaplıkla özel bir denetim sunmak zorunda kalmaya değmeyebilir, ancak en azından bir düğmenin tıklanıp tıklanmadığını belirlemek için kullanılan kodu en üst düzeyde kullanır.
Sadece montajınıza ekleyin:
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
Bu kadar. Bir daha asla dokunmayın. DataGrid'inizin, DataGridView ile DataGridViewExttam olarak aynı şekilde çalışması gereken türde olduğundan emin olun . Bunun dışında şu şekilde başa çıkabileceğiniz fazladan bir olay ortaya çıkarır:
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
