CMake kullanarak C ++ programını Boost ile bağlama

Programımı Ubuntu altındaki Boost kitaplığına bağlamak için CMake dosyam nasıl görünmelidir?

Çalıştırma sırasında gösterilen hatalar make:

main.cpp:(.text+0x3b): undefined reference to `boost::program_options::options_description::m_default_line_length'

Ana dosya gerçekten çok basit:

#include <boost/program_options/options_description.hpp>
#include <boost/program_options/option.hpp>
using namespace std;
#include <iostream>

namespace po = boost::program_options;

int main(int argc, char** argv) {

    po::options_description desc("Allowed options");
    desc.add_options()
        ("help", "produce help message")
        ;

    return 0;
}

Ben bunu başardım. CMake dosyalarıma eklediğim tek satırlar şunlardı:

target_link_libraries(
my_target_file
${Boost_PROGRAM_OPTIONS_LIBRARY}
)

CMake'de find_packageihtiyacınız olan kitaplıkları bulmak için kullanabilirsiniz . Genellikle FindBoost.cmakeCMake kurulumunuzla birlikte bir tane vardır .

Hatırladığım kadarıyla, /usr/share/cmake/Modules/ortak kitaplıklar için diğer bulma betikleri ile birlikte yüklenecek . Nasıl çalıştığı hakkında daha fazla bilgi için o dosyadaki belgelere bakabilirsiniz.

Kafamdan bir örnek:

FIND_PACKAGE( Boost 1.40 COMPONENTS program_options REQUIRED )
INCLUDE_DIRECTORIES( ${Boost_INCLUDE_DIR} )

ADD_EXECUTABLE( anyExecutable myMain.cpp )

TARGET_LINK_LIBRARIES( anyExecutable LINK_PUBLIC ${Boost_LIBRARIES} )

Umarım bu kod yardımcı olur.

• FindBoost.cmake ile ilgili resmi belgeler burada .
• Ve gerçek FindBoost.cmake (GitHub'da barındırılır)

Aşağıdaki konfigürasyonum:

cmake_minimum_required(VERSION 2.8)
set(Boost_INCLUDE_DIR /usr/local/src/boost_1_46_1)
set(Boost_LIBRARY_DIR /usr/local/src/boost_1_46_1/stage/lib)
find_package(Boost COMPONENTS system filesystem REQUIRED)
include_directories(${Boost_INCLUDE_DIR})
link_directories(${Boost_LIBRARY_DIR})

add_executable(main main.cpp)
target_link_libraries( main ${Boost_LIBRARIES} )

@MOnsDaR yanıtını, içe aktarılan hedeflerle modern CMake sözdizimi için uyarlayarak, bu şöyle olur:

find_package(Boost 1.40 COMPONENTS program_options REQUIRED)

add_executable(anyExecutable myMain.cpp)

target_link_libraries(anyExecutable Boost::program_options)

İçerme dizinlerini manuel olarak belirtmenin gerekli olmadığını unutmayın, çünkü bu, içe aktarılan hedef aracılığıyla zaten halledilir Boost::program_options.

Hangi Boost kitaplığı? Birçoğu saf şablonlardır ve bağlantı gerektirmez.

Şimdi, bize Boost program seçeneklerini istediğinizi söyleyen somut bir örnekle (ve daha da fazlası bize Ubuntu'da olduğunuzu söyledi), iki şey yapmanız gerekir:

1. libboost-program-options-devKarşı bağlantı kurabilmek için kurun .
2. cmakeKarşı bağlantı kurmayı söyle libboost_program_options.

Çoğunlukla Makefiles kullanıyorum, bu yüzden doğrudan komut satırı kullanımı:

$ g++ boost_program_options_ex1.cpp -o bpo_ex1 -lboost_program_options
$ ./bpo_ex1
$ ./bpo_ex1 -h
$ ./bpo_ex1 --help
$ ./bpo_ex1 -help
$

Görünüşe göre pek bir şey yapmıyor.

CMake için, kütüphanelerin listesine boost_program_options eklemek gerekir ve IIRC bu aracılığıyla yapılır SET(liblist boost_program_options)Gözlerinde farklı CMakeLists.txt.

Sistem varsayılan yükleme yolunu kullanmanın iki yolu, genellikle /usr/lib/x86_64-linux-gnu/:

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}")
message("boost inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

Boost'u yerel bir dizine kurarsanız veya sistem kurulumu yerine yerel kurulumu seçerseniz, bunu şu şekilde yapabilirsiniz:

set( BOOST_ROOT "/home/xy/boost_install/lib/" CACHE PATH "Boost library path" )
set( Boost_NO_SYSTEM_PATHS on CACHE BOOL "Do not search system for Boost" )

find_package(Boost REQUIRED regex date_time system filesystem thread graph)
include_directories(${BOOST_INCLUDE_DIRS})
message("boost lib: ${Boost_LIBRARIES}, inc:${Boost_INCLUDE_DIR}")

add_executable(use_boost use_boost.cpp)
target_link_libraries(use_boost
        ${Boost_LIBRARIES}
        )

Yukarıdaki dizinin /home/xy/boost_install/lib/Boost'u kurduğum yer olduğunu unutmayın :

xy@xy:~/boost_install/lib$ ll -th
total 16K
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 lib/
drwxrwxr-x 3 xy xy 4.0K May 28 19:22 include/

xy@xy:~/boost_install/lib$ ll -th lib/
total 57M
drwxrwxr-x 2 xy xy 4.0K May 28 19:23 ./
-rw-rw-r-- 1 xy xy 2.3M May 28 19:23 libboost_test_exec_monitor.a
-rw-rw-r-- 1 xy xy 2.2M May 28 19:23 libboost_unit_test_framework.a
.......

xy@xy:~/boost_install/lib$ ll -th include/
total 20K
drwxrwxr-x 110 xy xy  12K May 28 19:22 boost/

Yerel olarak kurulu bir Boost'u nasıl kullanacağınızla ilgileniyorsanız, bu soruyu görebilirsiniz CMake'in alternatif Boost kurulumumu bulmasını nasıl sağlayabilirim? .

İşte benim almam:

cmake_minimum_required(VERSION 3.15)

project(TryOuts LANGUAGES CXX)

find_package(Boost QUIET REQUIRED COMPONENTS program_options)

if(NOT Boost_FOUND)
    message(FATAL_ERROR "Boost Not found")
endif()

add_executable(helloworld main.cpp)

target_link_libraries(helloworld PUBLIC Boost::program_options)