Vim: Kaydederken ana dizinler oluşturma

Çağırırsam vim foo/bar/somefileama foo/barhalihazırda var olmazsam, Vim kaydetmeyi reddediyor.

Bir kabuğa geçebileceğimi veya :!mkdir foo/barVim'den yapabileceğimi biliyorum ama tembelim :) Arabelleği kaydettiğinde Vim'in bunu otomatik olarak yapmasını sağlamanın bir yolu var mı?

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

Koşullara dikkat edin: expand("<afile>")!~#'^\w\+:/'vim'in pahalı mkdir çağrısı gibi dosyalar için dizin oluşturmasını engelleyecek ftp://*ve !isdirectoryönleyecektir.

Güncelleme : Boş olmayan buftype'ı da kontrol eden ve aşağıdakileri kullanan biraz daha iyi bir çözüm mkdir():

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

Soruma verilen önerilere dayanarak, işte şunu buldum:

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

Bu, :Wkomutu tanımlar . İdeal olarak, ben hepsine sahip istiyorum :w!, :wq, :wq!, :wallaynı işe vs, ama temelde özel fonksiyonları ile hepsini reimplementing olmadan mümkün olup olmadığından emin değilim.

Bunu ~ / .vimrc dosyama ekledim

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

Bulunduğum dizini oluşturmam gerekirse, yazıyorum :mk.ve bu dizini "! Mkdir -p / yol / / / dosyam /" ile değiştiriyor ve komutu çalıştırmadan önce gözden geçirmeme izin veriyor.

Ben made :saveas!eksik eğer dizin oluşturun: https://github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

Bu kod sizden dizini oluşturmanızı :wveya sadece şununla yapmanızı ister :w!:

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

Sanırım bunu, başkalarının bu cevapta söylediklerini birleştirerek üç satırda yapmayı başardım.

Bu hile yapıyor gibi görünüyor:

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

Bir arabelleği kaydederken klasörü otomatik olarak oluşturmaya çalışır. Kötü bir şey olursa (örneğin izin sorunları), sadece kapanır ve dosya yazma işleminin başarısız olmasına izin verir.

Herhangi biri bariz bir kusur görürse, lütfen bir yorum gönderin. Vimscript konusunda pek bilgili değilim.

DÜZENLEME: ZyX sayesinde notlar

• Klasörlerinizde boşluklar varsa bu işe yaramayacaktır (görünüşe göre bunlar düzgün şekilde önlenmemiş veya başka bir şey)
• Ya da sözde dosyalar yapıyorsanız.
• Ya da vimrc'nizi tedarik ediyorsanız.
• Ama oğlum, bu kısa.