Bir URL'den Windows toplu dosya dosyası indirme

Bir Windows toplu iş dosyası kullanarak bir web sitesinden (ör. Http://www.example.com/package.zip ) dosya indirmeye çalışıyorum . Aşağıdaki işlevi yazdığımda bir hata kodu alıyorum:

xcopy /E /Y "http://www.example.com/package.zip"

Toplu iş dosyası http'den sonra "/" yi beğenmiyor gibi görünüyor. İşlev parametreleri olduklarını varsaymamak için bu karakterlerden kaçmanın herhangi bir yolu var mı?

PowerShell 2.0 (Windows 7 önceden yüklenmiş) ile şunları kullanabilirsiniz:

(New-Object Net.WebClient).DownloadFile('http://www.example.com/package.zip', 'package.zip')

PowerShell 3.0'dan (Windows 8 önceden yüklenmiş) başlayarak şunları kullanabilirsiniz Invoke-WebRequest:

Invoke-WebRequest http://www.example.com/package.zip -OutFile package.zip

Bir toplu iş dosyasından bunlara şunlar denir:

powershell -Command "(New-Object Net.WebClient).DownloadFile('http://www.example.com/package.zip', 'package.zip')"
powershell -Command "Invoke-WebRequest http://www.example.com/package.zip -OutFile package.zip"

(PowerShell 2.0, Windows 7 için XP, 3.0'a yüklenebilir)

Yapmaya çalıştığınız şeyi başarabilecek standart bir Windows bileşeni var: BITS . Windows'a XP ve 2000 SP3'ten beri dahil edilmiştir.

Çalıştırmak:

bitsadmin.exe /transfer "JobName" http://download.url/here.exe C:\destination\here.exe

İş adı, indirme işinin görünen adıdır - ne yaptığınızı açıklayan bir şeye ayarlayın.

Bu biraz konu dışı olabilir, ancak Powershell'i kullanarak bir dosyayı oldukça kolay bir şekilde indirebilirsiniz . Powershell, Windows'un modern sürümleriyle birlikte gelir, böylece bilgisayara fazladan herhangi bir şey yüklemeniz gerekmez. Bu sayfayı okuyarak nasıl yapılacağını öğrendim:

http://teusje.wordpress.com/2011/02/19/download-file-with-powershell/

Kod şuydu:

$webclient = New-Object System.Net.WebClient
$url = "http://www.example.com/file.txt"
$file = "$pwd\file.txt"
$webclient.DownloadFile($url,$file)

Son kontrol ettiğimde, MS komut satırından bir URL'ye bağlanmak için bir komut satırı komutu yok. Windows için wget'i deneyin:
http://gnuwin32.sourceforge.net/packages/wget.htm

veya URL2File:
http://www.chami.com/free/url2file_wincon.html

Linux'ta "wget" kullanabilirsiniz.

Alternatif olarak, VBScript'i deneyebilirsiniz. Komut satırı programları gibidirler, ancak wscript.exe komut dosyası ana bilgisayarı tarafından yorumlanan komut dosyalarıdır. VBS kullanarak bir dosya indirmeye bir örnek:
/server/29707/download-file-from-vbscript

Dosyaları PURE BATCH olarak indirme ...

Herhangi bir JScript, VBScript, Powershell, vb. Olmadan ... Sadece saf Batch!

Bazı insanlar, herhangi bir JScript veya VBScript vb. Kullanmadan toplu komut dosyasıyla dosya indirmenin mümkün olmadığını söylüyor ... Ama kesinlikle yanılıyorlar!

İşte toplu komut dosyalarınızdaki dosyaları indirmek için oldukça iyi çalışan basit bir yöntem. Neredeyse her dosyanın URL'si üzerinde çalışıyor olmalıdır. İhtiyaç duyduğunuzda bir proxy sunucusu kullanmak bile mümkündür.

Dosyaları indirmek için Windows sisteminden BITSADMIN.EXE kullanabiliriz . Herhangi bir şey indirmeye / yüklemeye veya herhangi bir JScript veya VBScript vb. Kullanmaya gerek yoktur. Bitsadmin.exe çoğu Windows sürümünde, muhtemelen XP'den Windows 10'a kadar mevcuttur.

Zevk almak!

KULLANIM:

BITSADMIN komutunu doğrudan şu şekilde kullanabilirsiniz:
bitsadmin /transfer mydownloadjob /download /priority FOREGROUND "http://example.com/File.zip" "C:\Downloads\File.zip"

Proxy Sunucusu: Proxy
kullanarak bağlanmak için, indirmeden önce bu komutu kullanın.
bitsadmin /setproxysettings mydownloadjob OVERRIDE "proxy-server.com:8080" "<local>"

BITSadmin.exe hakkında daha fazla bilgi istiyorsanız bu BAĞLANTIYI tıklayın

SORUN GİDERME:
Şu hatayı alırsanız: "BITS - 0x80070422'ye bağlanılamıyor"
Windows hizmetinin "Arka Plan Akıllı Aktarım Hizmeti (BITS)" etkin olduğundan emin olun ve yeniden deneyin. (Varsayılan olarak etkinleştirilmelidir.)

ÖZEL FONKSİYONLAR
Call :DOWNLOAD_FILE "URL"
Call :DOWNLOAD_PROXY_ON "SERVER:PORT"
Call :DOWNLOAD_PROXY_OFF

Bu 3 işlevi bitadmin komutlarını basitleştirmek için yaptım. Kullanması ve hatırlaması daha kolay. Komut dosyalarınızda birden çok kez kullanıyorsanız özellikle yararlı olabilir.

LÜTFEN DİKKAT EDİN ...
Bu işlevleri kullanmadan önce, bunları CUSTOM_FUNCTIONS.CMD'den betiğinizin sonuna kopyalamanız gerekir. Tam bir örnek de var: DOWNLOAD-EXAMPLE.CMD

: DOWNLOAD_FILE "URL"
Ana işlev, dosyaları URL'den indirecektir.

: DOWNLOAD_PROXY_ON "SUNUCU: PORT"
(İsteğe bağlı) Proxy sunucusu kullanmanız gerekirse bu işlevi kullanabilirsiniz.
DOWNLOAD_PROXY_OFF işlevinin çağrılması, proxy sunucusunu devre dışı bırakacaktır.

MİSAL:
CALL :DOWNLOAD_PROXY_ON "proxy-server.com:8080"
CALL :DOWNLOAD_FILE "http://example.com/File.zip" "C:\Downloads\File.zip"
CALL :DOWNLOAD_PROXY_OFF

CUSTOM_FUNCTIONS.CMD

:DOWNLOAD_FILE
    rem BITSADMIN COMMAND FOR DOWNLOADING FILES:
    bitsadmin /transfer mydownloadjob /download /priority FOREGROUND %1 %2
GOTO :EOF

:DOWNLOAD_PROXY_ON
    rem FUNCTION FOR USING A PROXY SERVER:
    bitsadmin /setproxysettings mydownloadjob OVERRIDE %1 "<local>"
GOTO :EOF

:DOWNLOAD_PROXY_OFF
    rem FUNCTION FOR STOP USING A PROXY SERVER:
    bitsadmin /setproxysettings mydownloadjob NO_PROXY
GOTO :EOF

İNDİR-EXAMPLE.CMD

@ECHO OFF
SETLOCAL

rem FOR DOWNLOADING FILES, THIS SCRIPT IS USING THE "BITSADMIN.EXE" SYSTEM FILE.
rem IT IS PRESENT ON MOST WINDOWS VERSION, PROBABLY FROM WINDOWS XP TO WINDOWS 10.


:SETUP

rem URL (5MB TEST FILE):
SET "FILE_URL=http://ipv4.download.thinkbroadband.com/5MB.zip"

rem SAVE IN CUSTOM LOCATION:
rem SET "SAVING_TO=C:\Folder\5MB.zip"

rem SAVE IN THE CURRENT DIRECTORY
SET "SAVING_TO=5MB.zip"
SET "SAVING_TO=%~dp0%SAVING_TO%"

:MAIN

ECHO.
ECHO DOWNLOAD SCRIPT EXAMPLE
ECHO.
ECHO FILE URL: "%FILE_URL%"
ECHO SAVING TO:  "%SAVING_TO%"
ECHO.

rem UNCOMENT AND MODIFY THE NEXT LINE IF YOU NEED TO USE A PROXY SERVER:
rem CALL :DOWNLOAD_PROXY_ON "PROXY-SERVER.COM:8080"

rem THE MAIN DOWNLOAD COMMAND:
CALL :DOWNLOAD_FILE "%FILE_URL%" "%SAVING_TO%"

rem UNCOMMENT NEXT LINE FOR DISABLING THE PROXY (IF YOU USED IT):
rem CALL :DOWNLOAD_PROXY_OFF

:RESULT
ECHO.
IF EXIST "%SAVING_TO%" ECHO YOUR FILE HAS BEEN SUCCESSFULLY DOWNLOADED.
IF NOT EXIST "%SAVING_TO%" ECHO ERROR, YOUR FILE COULDN'T BE DOWNLOADED.
ECHO.

:EXIT_SCRIPT
PAUSE
EXIT /B




rem FUNCTIONS SECTION


:DOWNLOAD_FILE
    rem BITSADMIN COMMAND FOR DOWNLOADING FILES:
    bitsadmin /transfer mydownloadjob /download /priority FOREGROUND %1 %2
GOTO :EOF

:DOWNLOAD_PROXY_ON
    rem FUNCTION FOR USING A PROXY SERVER:
    bitsadmin /setproxysettings mydownloadjob OVERRIDE %1 "<local>"
GOTO :EOF

:DOWNLOAD_PROXY_OFF
    rem FUNCTION FOR STOP USING A PROXY SERVER:
    bitsadmin /setproxysettings mydownloadjob NO_PROXY
GOTO :EOF

' Create an HTTP object
myURL = "http://www.google.com"
Set objHTTP = CreateObject( "WinHttp.WinHttpRequest.5.1" )

' Download the specified URL
objHTTP.Open "GET", myURL, False
objHTTP.Send
intStatus = objHTTP.Status

If intStatus = 200 Then
  WScript.Echo " " & intStatus & " A OK " +myURL
Else
  WScript.Echo "OOPS" +myURL
End If

sonra

C:\>cscript geturl.vbs
Microsoft (R) Windows Script Host Version 5.7
Copyright (C) Microsoft Corporation. All rights reserved.

200 A OK http://www.google.com

veya pencerelerde test etmek için sadece çift tıklayın

AFAIK, Windows'un bir dosyayı indirmek için yerleşik bir komut satırı aracı yoktur. Ancak bunu bir VBScript'ten yapabilir ve VBScript dosyasını yankı ve çıktı yeniden yönlendirmesini kullanarak toplu işten oluşturabilirsiniz:

@echo off

rem Windows has no built-in wget or curl, so generate a VBS script to do it:
rem -------------------------------------------------------------------------
set DLOAD_SCRIPT=download.vbs
echo Option Explicit                                                    >  %DLOAD_SCRIPT%
echo Dim args, http, fileSystem, adoStream, url, target, status         >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
echo Set args = Wscript.Arguments                                       >> %DLOAD_SCRIPT%
echo Set http = CreateObject("WinHttp.WinHttpRequest.5.1")              >> %DLOAD_SCRIPT%
echo url = args(0)                                                      >> %DLOAD_SCRIPT%
echo target = args(1)                                                   >> %DLOAD_SCRIPT%
echo WScript.Echo "Getting '" ^& target ^& "' from '" ^& url ^& "'..."  >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
echo http.Open "GET", url, False                                        >> %DLOAD_SCRIPT%
echo http.Send                                                          >> %DLOAD_SCRIPT%
echo status = http.Status                                               >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
echo If status ^<^> 200 Then                                            >> %DLOAD_SCRIPT%
echo    WScript.Echo "FAILED to download: HTTP Status " ^& status       >> %DLOAD_SCRIPT%
echo    WScript.Quit 1                                                  >> %DLOAD_SCRIPT%
echo End If                                                             >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
echo Set adoStream = CreateObject("ADODB.Stream")                       >> %DLOAD_SCRIPT%
echo adoStream.Open                                                     >> %DLOAD_SCRIPT%
echo adoStream.Type = 1                                                 >> %DLOAD_SCRIPT%
echo adoStream.Write http.ResponseBody                                  >> %DLOAD_SCRIPT%
echo adoStream.Position = 0                                             >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
echo Set fileSystem = CreateObject("Scripting.FileSystemObject")        >> %DLOAD_SCRIPT%
echo If fileSystem.FileExists(target) Then fileSystem.DeleteFile target >> %DLOAD_SCRIPT%
echo adoStream.SaveToFile target                                        >> %DLOAD_SCRIPT%
echo adoStream.Close                                                    >> %DLOAD_SCRIPT%
echo.                                                                   >> %DLOAD_SCRIPT%
rem -------------------------------------------------------------------------

cscript //Nologo %DLOAD_SCRIPT% http://example.com targetPathAndFile.html

Burada daha fazla açıklama

1. Wget'i buradan indirin http://downloads.sourceforge.net/gnuwin32/wget-1.11.4-1-setup.exe

2. Ardından kurun.

3. Sonra bir .bat dosyası oluşturun ve bunu içine koyun

   @echo off
   
   for /F "tokens=2,3,4 delims=/ " %%i in ('date/t') do set y=%%k
   for /F "tokens=2,3,4 delims=/ " %%i in ('date/t') do set d=%%k%%i%%j
   for /F "tokens=5-8 delims=:. " %%i in ('echo.^| time ^| find "current" ') do set t=%%i%%j
   set t=%t%_
   if "%t:~3,1%"=="_" set t=0%t%
   set t=%t:~0,4%
   set "theFilename=%d%%t%"
   echo %theFilename%
   
   
   cd "C:\Program Files\GnuWin32\bin"
   wget.exe --output-document C:\backup\file_%theFilename%.zip http://someurl/file.zip
   

4. Komut dosyasındaki URL'yi ve dosya yolunu ayarlayın

5. Dosyayı çalıştırın ve kar edin!

Http üzerinden xcopy kullanamazsınız. Windows için wget'i indirmeyi deneyin. Bu hile yapabilir. Dosyaların http üzerinden etkileşimli olmayan bir şekilde indirilmesi için bir komut satırı yardımcı programıdır. Bunu http://gnuwin32.sourceforge.net/packages/wget.htm adresinden edinebilirsiniz.

Bitsadmin sizin fincan çayınız değilse, bu PowerShell komutunu kullanabilirsiniz:

Start-BitsTransfer -Source http://www.foo.com/package.zip -Destination C:\somedir\package.zip

Bat To Exe Converter'ı kullanın

Bir toplu iş dosyası oluşturun ve aşağıdaki koda benzer bir şey koyun

%extd% /download http://www.examplesite.com/file.zip file.zip

veya

%extd% /download http://stackoverflow.com/questions/4619088/windows-batch-file-file-download-from-a-url thistopic.html

ve exe'ye dönüştürün.

Wget yerine, dosyayı belirli bir URL'den indirmek için aria2'yi de kullanabilirsiniz.

Aria2 hakkında daha fazla bilgi verecek olan aşağıdaki bağlantıya bakın:

https://aria2.github.io/

BATCH bunu yapamayabilir, ancak Windows ile varsayılan olarak yüklenmeyen araçları kullanmak istemiyorsanız JScript veya VBScript kullanabilirsiniz.

Bu sayfadaki ilk örnek, VBScript'te bir ikili dosya indirir: http://www.robvanderwoude.com/vbstech_internet_download.php

Bu SO yanıtı, JScript (IMO, daha iyi dil) kullanarak bir dosya indirir: Windows Komut Dosyası Ana Bilgisayarı (jscript): bir ikili dosyayı nasıl indirebilirim?

Toplu komut dosyanız daha sonra dosyayı indiren bir JScript veya VBScript'i çağırabilir.

Bu çalışmalı, bir oyun sunucusu projesi için aşağıdakileri yaptım. Zip dosyasını indirecek ve belirttiğiniz dizine çıkaracaktır.

Name.bat veya name.cmd olarak kaydedin

@echo off
set downloadurl=http://media.steampowered.com/installer/steamcmd.zip
set downloadpath=C:\steamcmd\steamcmd.zip
set directory=C:\steamcmd\
%WINDIR%\System32\WindowsPowerShell\v1.0\powershell.exe -Command "& {Import-Module BitsTransfer;Start-BitsTransfer '%downloadurl%' '%downloadpath%';$shell = new-object -com shell.application;$zip = $shell.NameSpace('%downloadpath%');foreach($item in $zip.items()){$shell.Namespace('%directory%').copyhere($item);};remove-item '%downloadpath%';}"
echo download complete and extracted to the directory.
pause

Orijinal: https://github.com/C0nw0nk/SteamCMD-AutoUpdate-Any-Gameserver/blob/master/steam.cmd

Bu VB komut dosyasını buldum:

http://www.olafrv.com/?p=385

Tıkır tıkır çalışıyor. Çok basit bir işlev çağrısı olan bir işlev olarak yapılandırılmıştır:

SaveWebBinary "http://server/file1.ext1", "C:/file2.ext2"

Orijinal olarak: http://www.ericphelps.com/scripting/samples/BinaryDownload/index.htm

İşte artıklık için tam kod:

Function SaveWebBinary(strUrl, strFile) 'As Boolean
Const adTypeBinary = 1
Const adSaveCreateOverWrite = 2
Const ForWriting = 2
Dim web, varByteArray, strData, strBuffer, lngCounter, ado
    On Error Resume Next
    'Download the file with any available object
    Err.Clear
    Set web = Nothing
    Set web = CreateObject("WinHttp.WinHttpRequest.5.1")
    If web Is Nothing Then Set web = CreateObject("WinHttp.WinHttpRequest")
    If web Is Nothing Then Set web = CreateObject("MSXML2.ServerXMLHTTP")
    If web Is Nothing Then Set web = CreateObject("Microsoft.XMLHTTP")
    web.Open "GET", strURL, False
    web.Send
    If Err.Number <> 0 Then
        SaveWebBinary = False
        Set web = Nothing
        Exit Function
    End If
    If web.Status <> "200" Then
        SaveWebBinary = False
        Set web = Nothing
        Exit Function
    End If
    varByteArray = web.ResponseBody
    Set web = Nothing
    'Now save the file with any available method
    On Error Resume Next
    Set ado = Nothing
    Set ado = CreateObject("ADODB.Stream")
    If ado Is Nothing Then
        Set fs = CreateObject("Scripting.FileSystemObject")
        Set ts = fs.OpenTextFile(strFile, ForWriting, True)
        strData = ""
        strBuffer = ""
        For lngCounter = 0 to UBound(varByteArray)
            ts.Write Chr(255 And Ascb(Midb(varByteArray,lngCounter + 1, 1)))
        Next
        ts.Close
    Else
        ado.Type = adTypeBinary
        ado.Open
        ado.Write varByteArray
        ado.SaveToFile strFile, adSaveCreateOverWrite
        ado.Close
    End If
    SaveWebBinary = True
End Function

Bu sorunun burada çok güzel cevabı var . Kodum, bazı değişikliklerle birlikte tamamen bu yanıta dayanmaktadır.

Aşağıdaki parçacığı wget.bat olarak kaydedin ve sistem yolunuza koyun (örneğin, bir dizine koyun ve bu dizini sistem yoluna ekleyin.)

Bunu klibinizde aşağıdaki şekilde kullanabilirsiniz:

wget url/to/file [?custom_name]

nerede url_to_filezorunlu ve custom_nameisteğe bağlıdır

1. Ad belirtilmezse, indirilen dosya url'den kendi adıyla kaydedilir.
2. Ad verilirse, dosya yeni adla kaydedilir.

Dosya url'si ve kaydedilen dosya adları, renkli metin olarak görüntülenir. Bu sizin için sorun yaratıyorsa, bu github projesini kontrol edin .

@echo OFF
setLocal EnableDelayedExpansion
set Url=%1
set Url=!Url:http://=!
set Url=!Url:/=,!
set Url=!Url:%%20=?!
set Url=!Url: =?!

call :LOOP !Url!

set FileName=%2
if "%2"=="" set FileName=!FN!

echo.
echo.Downloading: [1;33m%1[0m to [1;33m\!FileName![0m

powershell.exe -Command wget %1 -OutFile !FileName!

goto :EOF
:LOOP
if "%1"=="" goto :EOF
set FN=%1
set FN=!FN:?= !
shift
goto :LOOP

PS Bu kod, PowerShell'in kurulu olmasını gerektirir.

Wget kullanarak zamanlanmış bir görev kurabilir, zamanlanmış görevde "Çalıştır" alanını şu şekilde kullanabilirsiniz:

C:\wget\wget.exe -q -O nul "http://www.google.com/shedule.me"

Windows'ta CMD'den çalıştırılabilen bir yardımcı program (CMD'de bulunur) (yazma erişiminiz varsa):

set url=https://www.nsa.org/content/hl-images/2017/02/09/NSA.jpg
set file=file.jpg
certutil -urlcache -split -f %url% %file%
echo Done.

Windows uygulamasında yerleşik. Dışarıdan indirmeye gerek yok.

Win 10'da test edildi

ftp kullanın:

(ftp *yourewebsite.com*-a)
cd *directory*
get *filename.doc*
close

Durumunuza uyması için yıldız işaretindeki her şeyi değiştirin.