Windows makinemde JDK'nın yüklü olduğu yeri nasıl bulabilirim?

JDK'nın makinemde nerede olduğunu bilmem gerekiyor.

Çalışan üzerinde Java -versionde cmd , bu 1.6.xx 'olarak versiyonunu gösterir. Bu SDK'nın makinemdeki yerini bulmak için kullanmayı denedim echo %JAVA_HOME%ama sadece 'JAVA_HOME' gösteriyor (ortam değişkenlerimde 'JAVA_PATH' var ayarlanmadığı için).

Linux / Unix / Mac OS X kullanıyorsanız:

Bunu dene:

$ which java

Kesin yeri çıktı.

Bundan sonra, JAVA_HOMEortam değişkenini kendiniz ayarlayabilirsiniz .

Bilgisayarımda (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

Windows kullanıyorsanız:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i

Windows> Başlat> cmd>

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

Yüklü bir JDK'nız varsa, Yol görüntülenir,
örneğin:C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

Windows'ta komut isteminde

where javac

Pencerelerde varsayılan değer şudur: C:\Program Files\Java\jdk1.6.0_14(sayılar sürüm olduklarından farklı olabilir).

Java yükleyicisi birkaç dosyayı% WinDir% \ System32 klasörüne koyar (java.exe, javaws.exe ve diğerleri). Komut satırına java.exe yazdığınızda veya tam yol olmadan işlem oluşturduğunuzda, Windows% PATH% klasörlerinde eksikse bunları son çare olarak çalıştırır.

Kayıt defterinde yüklü tüm Java sürümlerini arayabilirsiniz. 64 bit Windows'ta 32 bit java için HKLM \ SOFTWARE \ JavaSoft \ Java Runtime Environment ve HKLM \ SOFTWARE \ Wow6432Node \ JavaSoft \ Java Runtime Environment'a göz atın.

Java'nın kendisinde yüklü farklı sürümleri bu şekilde bulur. Bu yüzden hem 32 bit hem de 64 bit sürüm birlikte var olabilir ve müdahale etmeden iyi çalışır.

Windows platformlarında sade ve basit:

nerede java

Aşağıdaki toplu komut dosyası, var olan varsayılan JRE'yi yazdırır. Java Runtime Environment yazılımını Java Development Kit ile değiştirerek yüklenen JDK sürümünü bulmak için kolayca değiştirilebilir .

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal

Windows 10'da, Denetim Masası> Java'ya giderek yolu bulabilirsiniz. Görünen panelde, yolu aşağıdaki ekran görüntüsünde gösterildiği gibi bulabilirsiniz. Java Denetim Masası'nda 'Java' sekmesine gidin ve ardından 'Java uygulamaları ve uygulamaları için Java Runtime sürümlerini ve ayarlarını görüntüleme ve yönetme' açıklamasının altındaki 'Görünüm' düğmesini tıklayın.

Bu, Windows 7 ve muhtemelen Windows'un diğer son sürümlerinde çalışmalıdır.

Windows komut istemine şunu yazın:

set java_home

Veya komut ortamını beğenmediyseniz, aşağıdakileri kontrol edebilirsiniz:

Başlat menüsü> Bilgisayar> Sistem Özellikleri> Gelişmiş Sistem Özellikleri. Ardından Gelişmiş sekmesi> Ortam Değişkenleri'ni açın ve sistem değişkeninde JAVA_HOME'u bulmaya çalışın.

Windows altında şunları kullanabilirsiniz:

C:>dir /b /s java.exe

PATH ortam değişkeninizde olup olmadıklarına bakılmaksızın, C: sürücünüzdeki her "java.exe" dosyasının tam yolunu yazdırmak için.

Windows hakkında daha fazlası ... değişken java.home her zaman çalıştırılan ikili dosya ile aynı konum değildir.

Denis Menace söylediği gibi, yükleyici koyar Java içine dosyaları Program Files aynı zamanda, java.exe içine System32 . Java ile ilgili hiçbir şey olmadan java -version hala çalışabilir. Ancak PeterMmm programı çalıştırıldığında java.home olarak Program Files'ın değerini bildirir , bu yanlış değildir (Java orada yüklüdür), ancak çalıştırılmakta olan gerçek ikili System32'da bulunur .

Yerini avlamak için bir yolu java.exe ikili, uzun süre çalışan bir program tutmak PeterMmm koduyla aşağıdaki satırı ekleyin:

try{Thread.sleep(60000);}catch(Exception e) {}

Derleyin ve çalıştırın, sonra java.exe görüntüsünün konumunu avlayın . Örneğin Windows 7'de görev yöneticisini açın, java.exe girişini bulun , sağ tıklayın ve 'dosya konumunu aç'ı seçin, bu Java ikili dosyasının tam konumunu açar. Bu durumda System32 olur .

Bu programı komut satırından çalıştırın:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main

Powershell bir astar:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome

% PATH% değişkeninize bakmayı denediniz mi? Windows'un herhangi bir yürütülebilir dosyayı bulmak için kullandığı budur.

setKomutu komut satırınızda yürütün . Ardından ayarladığınız tüm ortam değişkenlerini görürsünüz.

Veya Unix'te basitleştirebilirsiniz:

$ set | grep "JAVA_HOME" 

Bu işletim sistemine özgüdür. Unix'te:

which java

yürütülebilir dosyanın yolunu görüntüler. Bir Windows eşdeğeri bilmiyorum, ama orada genellikle binsistemde JDK yükleme klasörü var PATH:

echo %PATH%

Bin, docs, include, jre, lib, vb. Gibi alt dizinleri içeren evi arıyorsanız, bu yanıtların hiçbiri Linux için doğru değildir.

Ubuntu'da openjdk1.8.0 için: /usr/lib/jvm/java-1.8.0-openjdk-amd64

ve JAVA_HOMEJNI kaynak dosyaları oluşturursanız üstbilgileri bulabileceğiniz için bunu kullanmayı tercih edebilirsiniz . which javaİkili yolu sağlayacak doğru olsa da , gerçek JDK evi değildir.

MacOS'ta çalıştırın:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

Makinemde bu yazdırılıyor:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

which javaÇalışmanın JDK konumunu göstermediğini unutmayın , çünkü javakomut bunun yerine JavaVM.frameworkgerçek JDK'yı saran bir parçasıdır :

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

Windows cmd'de:

set "JAVA_HOME" 

#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

Pencereler için:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

Bu bağlantı bash'dan java çalıştırılabilir dosyasının nasıl bulunacağını açıklamaya yardımcı olabilir: http://srcode.org/2014/05/07/detect-java-executable/

Gerekirse 64-bit ve 32-bit kayıtlarda kayıt defteri anahtarını test ederek munsingh'in cevabını iyileştirdim :

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

bit kayıt defterine erişim için başvuru

32/64 bit Windows için komut dosyası.

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal