Bir Windows toplu iş dosyasındaki% PATH% içinde bir yürütülebilir dosya olup olmadığı nasıl test edilir?

Bir Windows toplu iş dosyasındaki PATH ortam değişkeninde bir yürütülebilir dosya olup olmadığını test etmenin basit bir yolunu arıyorum.

İşletim sistemi tarafından sağlanmayan harici araçların kullanımına izin verilmez. Gereken minimum Windows sürümü Windows XP'dir.

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Buna farklı uzantılar için ihtiyacınız varsa, tekrarlayın PATHEXT:

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

O olabilir whereben söyleyemem böylece, aynı zamanda eski Windows sürümlerinde zaten var, ama ben birine erişimi yok. Makinemde aşağıdakiler de çalışıyor:

where myExecutable

ve bulunamazsa sıfır olmayan bir çıkış koduyla döner. Yine de bir toplu işte, muhtemelen çıktıyı da yönlendirmek istersiniz NUL.

Aklında tut

Batch ( .bat) dosyalarında ve komut satırında ayrıştırma farklıdır (çünkü toplu iş dosyalarında %0- %9) vardır, bu yüzden %orayı ikiye katlamanız gerekir . Komut satırında bu gerekli değildir, bu nedenle değişkenler için sadece vardır %X.

Windows Vista ve sonraki sürümler where.exe, yoldaki programları arayan bir programla birlikte gelir. Şu şekilde çalışır:

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Bir toplu iş dosyasında kullanmak için /q, ERRORLEVELherhangi bir çıktıyı ayarlayan ve üretmeyen anahtarı kullanabilirsiniz .

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Veya mesajı yazdırıp uygulamanızdan çıkan basit (ancak daha az okunabilir) bir kısaltma versiyonu:

where /q myapplication || ECHO Cound not find app. && EXIT /B

İşte uygulamayı çalıştırmayı deneyen ve daha sonra herhangi bir hatayı ele alan basit bir çözüm .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Hata kodu 9009 genellikle dosyanın bulunamadığı anlamına gelir.

Tek dezavantajı, file.exebulunursa fiilen yürütülmesidir (bazı durumlarda bu arzu edilmez).

Bu, parametre ikamesi yoluyla gerçekleştirilebilir.

%~$PATH:1

Bu,% 1'deki yürütülebilir dosya adının tam yolunu döndürür, aksi takdirde boş bir dize.

Bu, kullanıcı tanımlı değişkenlerle çalışmaz. Dolayısıyla, yürütülebilir dosya adı betiğiniz için bir parametre değilse, bir alt yordama ihtiyacınız vardır. Örneğin:

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Bkz. Http://ss64.com/nt/syntax-args.html

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....

Bazen bu basit çözüm, çıktının beklediğinizle eşleşip eşleşmediğini kontrol ettiğiniz yerde çalışır. İlk satır komutu çalıştırır ve standart çıktının son satırını alır.

FOR /F "tokens=*" %%i in (' "xcopy /? 2> nul" ') do SET xcopyoutput=%%i
if "%xcopyoutput%"=="" echo xcopy not in path.

Başlangıç ​​klasöründe benim gibi bir şey arıyorsanız, klasöre gitmelisiniz. Örneğin başlangıç ​​klasöründe exe araştırıyorum ve bu kodu şu şekilde kullanıyorum:

@echo off
cd C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp
where /q program.exe
IF ERRORLEVEL 1 (
echo F | xcopy /Y /S /I /E "\\programsetup\programsetup.exe" 
"C:\ProgramData\Microsoft\Windows\Start Menu\Programs\StartUp\program.exe"
) ELSE (
ECHO Application exists. Let's go!
)

Şu komutu kullanın: powershell Test-Yolu "aradığınız exe"

Mevcutsa True, aksi takdirde False döndürür.

PowerShell seçeneği arayanlar için. Get-Commandİki öğeyi geçiren cmdlet'i kullanabilirsiniz . Önce geçerli dir konumunu .\önekli olarak verin, sonra sadece exe adını verin.

(Get-Command ".\notepad", "notepad" -ErrorAction Ignore -CommandType Application) -ne $null

Bu, yerel veya sistem genelindeki yollarda bulunursa doğru olarak dönecektir.