SQL Server SELECT INTO @variable?

Ben mükemmel para cezası yürüten benim Sql (2008) Saklı Procs birinde aşağıdaki kodu var:

    CREATE PROCEDURE [dbo].[Item_AddItem]
        @CustomerId uniqueidentifier,
        @Description nvarchar(100),
        @Type int,
        @Username nvarchar(100),
    AS
    BEGIN

        DECLARE @TopRelatedItemId uniqueidentifier;
        SET @TopRelatedItemId = 
        (
           SELECT top(1) RelatedItemId 
           FROM RelatedItems 
           WHERE CustomerId = @CustomerId
        ) 

        DECLARE @TempItem TABLE
        (
            ItemId uniqueidentifier,
            CustomerId uniqueidentifier,
            Description nvarchar(100),
            Type int,
            Username nvarchar(100),
            TimeStamp datetime
        );

        INSERT INTO Item
        OUTPUT INSERTED.* INTO @TempItem
        SELECT NEWID(), @CustomerId, @Description, @Type, @Username, GETDATE()

        SELECT
            ItemId,
            CustomerId,
            @TopRelatedItemId,
            Description,
            Type,
            Username,
            TimeStamp
        FROM
            @TempItem
END
GO

Yani sizler için soru şu ki, şu konularda bir şeyler yapma olasılığı var:

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
INTO 
    @TempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Bu verileri aşağıdaki ifadelerde bellekten tekrar kullanabilmem için ne yapmalıyım? SQL Server, yukarıdaki ifade ile bir uyum atar, ancak ayrı değişkenler oluşturmak ve aynı tabloya karşı ayrı bir SELECT deyimi ile her birini başlatmak zorunda değilsiniz .... UGH !!!

Aynı tabloya karşı birden fazla sorgu olmadan satır boyunca bir şey elde etmek için herhangi bir öneriniz var mı?

TABLO DEĞİŞKENLİĞİNİ SEÇEBİLEMEZSİNİZ. Yapabileceğiniz en iyi şey önce onu oluşturmak, sonra içine eklemektir. İkinci pasajınız

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
INSERT INTO 
    @TempCustomer 
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Bazı değişkenleri daha sonra kullanmak üzere atamak istiyorsanız, bunları tek bir satırda aşağıdaki satırlarda bir şeyle yapabilirsiniz:

declare @var1 int,@var2 int,@var3 int;

select 
    @var1 = field1,
    @var2 = field2,
    @var3 = field3
from
    table
where
    condition

Eğer peşinde olduğun şey buysa

Bunu yapabilirsiniz:

SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email
INTO #tempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

daha sonra

SELECT CustomerId FROM #tempCustomer

#tempCustomer'ın yapısını bildirmeniz gerekmez

Sözdiziminiz biraz bitmiş gibi görünüyor. Bunun bazı iyi örnekleri var

DECLARE @TempCustomer TABLE
(
   CustomerId uniqueidentifier,
   FirstName nvarchar(100),
   LastName nvarchar(100),
   Email nvarchar(100)
);
INSERT @TempCustomer 
SELECT 
    CustomerId, 
    FirstName, 
    LastName, 
    Email 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId

Daha sonra

SELECT CustomerId FROM @TempCustomer

Temp masalarý istiyor gibisin. http://www.sqlteam.com/article/temporary-tables

#TempTable'ın tüm SP'nizde kullanılabildiğini unutmayın.

## TempTable herkes tarafından kullanılabilir.

Sorunuzu aynı soruna bir çözüm ararken buldum; ve diğer cevapların işaret etmediği, yordamınızın her yürütülmesi için tablonun adını geçici değil kalıcı bir biçimde değiştirmek için bir değişken kullanmanın bir yoludur.

Şimdiye kadar ne tüm SQL kodu kullanılacak değişkenlerle bitiştirmek olduğunu. Bunun gibi:

declare @table_name as varchar(30)
select @table_name = CONVERT(varchar(30), getdate(), 112)
set @table_name = 'DAILY_SNAPSHOT_' + @table_name

EXEC('
        SELECT var1, var2, var3
        INTO '+@table_name+'
        FROM my_view
        WHERE string = ''Strings must use double apostrophe''
    ');

Umarım yardımcı olur, ancak kod çok büyükse hantal olabilir, bu yüzden daha iyi bir yol bulduysanız, lütfen paylaşın!

"SELECT *
  INTO 
    @TempCustomer 
FROM 
    Customer
WHERE 
    CustomerId = @CustomerId"

Bu, yeni bir @tempCustomerdeğişkenli tablo oluşturma ve Müşteri'den veri ekleme anlamına gelir . Yukarıda zaten beyan etmişsinizdir, bu yüzden tekrar beyan etmeye gerek yoktur. Gitmek daha iyi

INSERT INTO @tempCustomer SELECT * FROM Customer