TSQL - BEGIN .. END bloğunun içinde GO nasıl kullanılır?

Değişiklikleri birden çok geliştirme veritabanından hazırlama / üretime otomatik olarak geçirmek için bir komut dosyası oluşturuyorum. Temel olarak, bir dizi değişiklik betiğini alır ve bunları tek bir betikte birleştirerek her bir komut dosyasını bir IF whatever BEGIN ... ENDifadeye sarar.

Ancak, bazı komut dosyaları GO, örneğin SQL ayrıştırıcısının oluşturulduktan sonra yeni bir sütun hakkında bilgi sahibi olması için bir ifade gerektirir .

ALTER TABLE dbo.EMPLOYEE 
ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO -- Necessary, or next line will generate "Unknown column:  EMP_IS_ADMIN"
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Ancak, bunu bir IFbloğa sardığımda:

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
    GO
    UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever
END

Başarısız oluyor çünkü BEGINeşleşme olmadan bir gönderiyorum END. Ancak, kaldırırsam, GObilinmeyen bir sütun hakkında tekrar şikayet ediyor.

Aynı sütunu tek bir IFblokta oluşturmanın ve güncellemenin herhangi bir yolu var mı ?

Aynı sorunu yaşadım ve sonunda SET NOEXEC kullanarak çözmeyi başardım .

IF not whatever
BEGIN
    SET NOEXEC ON; 
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

SET NOEXEC OFF; 

GO SQL değildir - sadece bazı MS SQL araçlarında kullanılan bir toplu ayırıcıdır.

Bunu kullanmazsanız, ifadelerin farklı gruplar halinde veya nüfus için dinamik SQL kullanarak ayrı ayrı yürütüldüğünden emin olmanız gerekir (teşekkürler @gbn):

IF whatever
BEGIN
    ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL;

    EXEC ('UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever')
END

Aşağıdaki örnekte gösterildiği gibi, sp_executesqlher bir GOifadenin içeriğini , yürütülecek ayrı bir dizeye bölmeyi deneyebilirsiniz . Ayrıca, bir istisna meydana geldiğinde kolay hata ayıklama için hangi ifadenin yürütüldüğünü izlemek için bir @statementNo değişkeni vardır. Satır numaraları, hataya neden olan ilgili ifade numarasının başlangıcına göre olacaktır.

BEGIN TRAN

DECLARE @statementNo INT
BEGIN TRY
    IF 1=1
    BEGIN
        SET @statementNo = 1
        EXEC sp_executesql
            N'  ALTER TABLE dbo.EMPLOYEE
                    ADD COLUMN EMP_IS_ADMIN BIT NOT NULL'

        SET @statementNo = 2
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1'

        SET @statementNo = 3
        EXEC sp_executesql
            N'  UPDATE dbo.EMPLOYEE
                    SET EMP_IS_ADMIN = 1x'
    END
END TRY
BEGIN CATCH
    PRINT 'Error occurred on line ' + cast(ERROR_LINE() as varchar(10)) 
       + ' of ' + 'statement # ' + cast(@statementNo as varchar(10)) 
       + ': ' + ERROR_MESSAGE()
    -- error occurred, so rollback the transaction
    ROLLBACK
END CATCH
-- if we were successful, we should still have a transaction, so commit it
IF @@TRANCOUNT > 0
    COMMIT

Ayrıca, yukarıdaki örnekte gösterildiği gibi, çok satırlı ifadeleri tek tırnak ( ') içine alarak kolayca yürütebilirsiniz . ''Komut dosyalarını oluştururken dize içinde bulunan tek tırnak işaretlerinden çift tek tırnak ( ) ile kaçmayı unutmayın .

Sonunda GOkendi satırındaki her örneğini şu şekilde değiştirerek çalıştırdım:

END
GO

---Automatic replacement of GO keyword, need to recheck IF conditional:
IF whatever
BEGIN

Bu, her ifade grubunu bir dizeye sarmak yerine büyük ölçüde tercih edilir, ancak yine de ideal olmaktan uzaktır . Herhangi biri daha iyi bir çözüm bulursa, bunu yayınlayın ve onun yerine kabul edeceğim.

İfadeleri arasında GO yerine BEGIN ve END'e ekleyebilirsiniz.

IF COL_LENGTH('Employees','EMP_IS_ADMIN') IS NULL --Column does not exist
BEGIN
    BEGIN
        ALTER TABLE dbo.Employees ADD EMP_IS_ADMIN BIT
    END

    BEGIN
        UPDATE EMPLOYEES SET EMP_IS_ADMIN = 0
    END
END

(Northwind veritabanında test edildi)

Düzenleme: (Muhtemelen SQL2012'de test edilmiştir)

Bu çözümü deneyebilirsiniz:

if exists(
SELECT...
)
BEGIN
PRINT 'NOT RUN'
RETURN
END

--if upper code not true

ALTER...
GO
UPDATE...
GO

Bunun RAISERRORiçin geçmişte kullandım

IF NOT whatever BEGIN
    RAISERROR('YOU''RE ALL SET, and sorry for the error!', 20, -1) WITH LOG
END

ALTER TABLE dbo.EMPLOYEE ADD COLUMN EMP_IS_ADMIN BIT NOT NULL
GO
UPDATE dbo.EMPLOYEE SET EMP_IS_ADMIN = whatever

Kodu atlamak için a GOTOve LABELifadeleri ekleyebilir, böylece GOanahtar kelimeleri olduğu gibi bırakabilirsiniz .