Soruya birkaç yıl geç kaldı, ancak bazı hızlı ve kirli kod üretimi için böyle bir şeye ihtiyacım vardı. Diğerlerinin belirttiği gibi, geçici tabloyu önceden tanımlamanın daha kolay olduğuna inanıyorum, ancak bu yöntem basit saklı yordam sorguları veya sql ifadeleri için çalışmalıdır.
Bu biraz kıvrımlı olacak, ancak burada katkıda bulunanlardan ve Paul White'ın DBA Stack Exchange'den çözümü Saklı yordam sonucu sütun türlerini alıyor . Yine, bu yaklaşımı tekrarlamak ve örnek çok kullanıcılı bir ortamdaki işlemler için tasarlanmamıştır. Bu durumda, tablo tanımı, bir kod oluşturma şablonu işlemi tarafından referans olarak bir genel geçici tabloda kısa bir süre için ayarlanmaktadır.
Paul White'ın cevabındaki MSDN bağlantısına gitmek isteyebileceğinizden uyarılar olabileceğinden bunu tamamen test etmedim. Bu, SQL 2012 ve sonraki sürümler için geçerlidir.
Öncelikle Oracle'ın açıklamasına benzeyen saklı yordamı sp_describe_first_result_set kullanın .
Bu, ilk sonuç kümesinin ilk satırını değerlendirir, böylece saklı yordamınız veya deyiminiz birden çok sorgu döndürürse, yalnızca ilk sonucu açıklar.
Geçici tablo tanımı oluşturmak için seçim için tek bir alan döndüren görevleri yıkmak için bir saklı proc oluşturdum.
CREATE OR ALTER PROCEDURE [dbo].[sp_GetTableDefinitionFromSqlBatch_DescribeFirstResultSet]
(
@sql NVARCHAR(4000)
,@table_name VARCHAR(100)
,@TableDefinition NVARCHAR(MAX) OUTPUT
)
AS
BEGIN
SET NOCOUNT ON
DECLARE @TempTableDefinition NVARCHAR(MAX)
DECLARE @NewLine NVARCHAR(4) = CHAR(13)+CHAR(10)
DECLARE @ResultDefinition TABLE ( --The View Definition per MSDN
is_hidden bit NOT NULL
, column_ordinal int NOT NULL
, [name] sysname NULL
, is_nullable bit NOT NULL
, system_type_id int NOT NULL
, system_type_name nvarchar(256) NULL
, max_length smallint NOT NULL
, [precision] tinyint NOT NULL
, scale tinyint NOT NULL
, collation_name sysname NULL
, user_type_id int NULL
, user_type_database sysname NULL
, user_type_schema sysname NULL
, user_type_name sysname NULL
, assembly_qualified_type_name nvarchar(4000)
, xml_collection_id int NULL
, xml_collection_database sysname NULL
, xml_collection_schema sysname NULL
, xml_collection_name sysname NULL
, is_xml_document bit NOT NULL
, is_case_sensitive bit NOT NULL
, is_fixed_length_clr_type bit NOT NULL
, source_server sysname NULL
, source_database sysname NULL
, source_schema sysname NULL
, source_table sysname NULL
, source_column sysname NULL
, is_identity_column bit NULL
, is_part_of_unique_key bit NULL
, is_updateable bit NULL
, is_computed_column bit NULL
, is_sparse_column_set bit NULL
, ordinal_in_order_by_list smallint NULL
, order_by_is_descending smallint NULL
, order_by_list_length smallint NULL
, tds_type_id int NOT NULL
, tds_length int NOT NULL
, tds_collation_id int NULL
, tds_collation_sort_id tinyint NULL
)
--Insert the description into table variable
INSERT @ResultDefinition
EXEC sp_describe_first_result_set @sql
--Now Build the string to create the table via union select statement
;WITH STMT AS (
SELECT N'CREATE TABLE ' + @table_name + N' (' AS TextVal
UNION ALL
SELECT
CONCAT(
CASE column_ordinal
WHEN 1 THEN ' ' ELSE ' , ' END --Determines if comma should precede
, QUOTENAME([name]) , ' ', system_type_name -- Column Name and SQL TYPE
,CASE is_nullable
WHEN 0 THEN ' NOT NULL' ELSE ' NULL' END --NULLABLE CONSTRAINT
) AS TextVal
FROM @ResultDefinition WHERE is_hidden = 0 -- May not be needed
UNION ALL
SELECT N');' + @NewLine
)
--Now Combine the rows to a single String
SELECT @TempTableDefinition = COALESCE (@TempTableDefinition + @NewLine + TextVal, TextVal) FROM STMT
SELECT @TableDefinition = @TempTableDefinition
END
Bilmeniz, küresel bir masa kullanmanız gerektiğidir, ancak bir çarpışmadan endişe etmeden sık sık düşüp yaratabileceğiniz kadar benzersiz hale getirmeniz gerekir.
Örnekte, genel değişken için kısa çizgileri alt çizgi ile değiştiren bir Kılavuz (FE264BF5_9C32_438F_8462_8A5DC8DEE49E) kullandım
DECLARE @sql NVARCHAR(4000) = N'SELECT @@SERVERNAME as ServerName, GETDATE() AS Today;'
DECLARE @GlobalTempTable VARCHAR(100) = N'##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable'
--@sql can be a stored procedure name like dbo.foo without parameters
DECLARE @TableDef NVARCHAR(MAX)
DROP TABLE IF EXISTS #MyTempTable
DROP TABLE IF EXISTS ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC [dbo].[sp_GetTableDefinitionFromSqlBatch_DescribeFirstResultSet]
@sql, @GlobalTempTable, @TableDef OUTPUT
--Creates the global table ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC sp_executesql @TableDef
--Now Call the stored procedure, SQL Statement with Params etc.
INSERT ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
EXEC sp_executesql @sql
--Select the results into your undefined Temp Table from the Global Table
SELECT *
INTO #MyTempTable
FROM ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
SELECT * FROM #MyTempTable
DROP TABLE IF EXISTS #MyTempTable
DROP TABLE IF EXISTS ##FE264BF5_9C32_438F_8462_8A5DC8DEE49E_MyTempTable
Yine, sadece basit saklı yordam sorguları ve basit sorgularla test ettim, böylece kilometre değişebilir. Umarım bu birine yardımcı olur.
