Gerektiğinde UAC yönetici haklarından istemek için toplu iş dosyamı otomatik olarak nasıl yükseltebilirim?

Toplu iş dosyamın yalnızca yükseltilmiş olarak çalışmasını istiyorum. Yükseltilmezse, kullanıcının toplu işi yükseltilmiş olarak yeniden başlatma seçeneği sağlayın.

Bir sistem değişkeni ayarlamak, iki dosyayı bir Program Files konumuna kopyalamak ve bir sürücü yükleyici başlatmak için bir toplu iş dosyası yazıyorum . Bir Windows 7 / Windows Vista kullanıcısı ( UAC etkinleştirilmiş ve yerel bir yönetici olsalar bile) sağ tıklamadan ve "Yönetici Olarak Çalıştır" ı seçmeden çalıştırırsa, iki dosyayı kopyalayıp sistem değişkenini yazma 'Erişim Reddedildi' .

Kullanıcı aslında bir yönetici ise toplu olarak yükseltilmiş olarak otomatik olarak yeniden başlatmak için bir komut kullanmak istiyorum. Aksi takdirde, yönetici değilse, toplu iş dosyasını çalıştırmak için yönetici ayrıcalıklarına ihtiyaç duyduklarını söylemek istiyorum. Ben kullanıyorum xcopy dosyaları kopyalamak için ve REG ADD sistem değişkeni yazmak için. Olası Windows XP makineleriyle uğraşmak için bu komutları kullanıyorum. Bu konuda benzer sorular buldum, ancak bir toplu iş dosyasını yükseltilmiş olarak yeniden başlatmayla ilgili hiçbir şey yok.

Sen ile komut çağrı kendisi olabilir psexec 'ın -hseçeneği yükselmiş çalıştırmak için.

Zaten yükseltilmiş olarak çalışıp çalışmadığını nasıl tespit edeceğinizden emin değilim ... belki sadece bir erişim reddedildi hatası varsa yükseltilmiş izinlerle yeniden deneyin?

Veya, sadece komutları alabilir xcopyve reg.exeher zaman çalıştırılabilir psexec -h, ancak her seferinde şifrelerini girmeleri gerekiyorsa (veya şifreyi betiğe eklediyseniz güvensizdir) son kullanıcı için rahatsız edici olacaktır ...

Harici bir araç kullanmaya gerek kalmadan kolay bir yol vardır - Windows 7, 8, 8.1 ve 10 ile iyi çalışır ve geriye dönük olarak da uyumludur (Windows XP'de UAC yoktur, bu nedenle yükseklik gerekmez - betiğin ilerlemesi durumunda).

Bu kodu göz atın (Ben iş parçacığında yayınlanan NIronwolf tarafından kod esinlenerek Toplu Dosya - "Erişim Engellendi" Windows 7? ), Ama ben geliştirdim - benim sürümde oluşturulan ve kaldırıldı herhangi bir dizin yok yönetici ayrıcalıklarını kontrol edin):

::::::::::::::::::::::::::::::::::::::::::::
:: Elevate.cmd - Version 4
:: Automatically check & get admin rights
:: see "https://stackoverflow.com/a/12264592/1016343" for description
::::::::::::::::::::::::::::::::::::::::::::
 @echo off
 CLS
 ECHO.
 ECHO =============================
 ECHO Running Admin shell
 ECHO =============================

:init
 setlocal DisableDelayedExpansion
 set cmdInvoke=1
 set winSysFolder=System32
 set "batchPath=%~0"
 for %%k in (%0) do set batchName=%%~nk
 set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
 setlocal EnableDelayedExpansion

:checkPrivileges
  NET FILE 1>NUL 2>NUL
  if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )

:getPrivileges
  if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
  ECHO.
  ECHO **************************************
  ECHO Invoking UAC for Privilege Escalation
  ECHO **************************************

  ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
  ECHO args = "ELEV " >> "%vbsGetPrivileges%"
  ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
  ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
  ECHO Next >> "%vbsGetPrivileges%"

  if '%cmdInvoke%'=='1' goto InvokeCmd 

  ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
  goto ExecElevation

:InvokeCmd
  ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
  ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"

:ExecElevation
 "%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
 exit /B

:gotPrivileges
 setlocal & cd /d %~dp0
 if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)

 ::::::::::::::::::::::::::::
 ::START
 ::::::::::::::::::::::::::::
 REM Run shell as admin (example) - put here code as you like
 ECHO %batchName% Arguments: P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 P6=%6 P7=%7 P8=%8 P9=%9
 cmd /k

Komut dosyası, NET FILEyönetici ayrıcalığı gerektiren errorlevel 1durumdan yararlanır ve sahip değilseniz geri döner . Yükseltme, ayrıcalıklar elde etmek için toplu iş dosyasını yeniden başlatan bir komut dosyası oluşturarak elde edilir. Bu, Windows'un UAC iletişim kutusunu göstermesine neden olur ve yönetici hesabı ve parola ister.

Windows 7, 8, 8.1, 10 ve Windows XP ile test ettim - herkes için iyi çalışıyor. Bunun avantajı, başlangıç ​​noktasından sonra, örneğin bir Windows hizmetini hata ayıklama amacıyla yeniden yüklemek ve yeniden çalıştırmak istiyorsanız (mypackage.msi dosyasının bir hizmet yükleyici paketi olduğu varsayılırsa) sistem yöneticisi ayrıcalıkları gerektiren her şeyi yerleştirebilirsiniz. :

msiexec /passive /x mypackage.msi
msiexec /passive /i mypackage.msi
net start myservice

Bu ayrıcalık yükseltme betiği olmadan, UAC size yönetici kullanıcı ve şifrenizi üç kez soracaktır - şimdi sizden yalnızca bir kez başlangıçta ve sadece gerekirse istenir.

Komut dosyanızın yalnızca bir hata mesajı göstermesi ve otomatik yükseltme yerine yönetici ayrıcalıkları yoksa çıkması gerekiyorsa , bu daha da basittir: Komut dosyanızın başına aşağıdakileri ekleyerek bunu elde edebilirsiniz:

@ECHO OFF & CLS & ECHO.
NET FILE 1>NUL 2>NUL & IF ERRORLEVEL 1 (ECHO You must right-click and select &
  ECHO "RUN AS ADMINISTRATOR"  to run this batch. Exiting... & ECHO. &
  PAUSE & EXIT /D)
REM ... proceed here with admin rights ...

Bu şekilde, kullanıcının sağ tıklaması ve "Yönetici olarak çalıştır" ı seçmesi gerekir . Komut dosyası, REMyönetici haklarını algılarsa ifadeden sonra devam eder, aksi takdirde bir hata ile çıkılır. Gereksinim duymuyorsanız PAUSE, kaldırın. Önemli: NET FILE [...] EXIT /D) aynı satırda olmalıdır. Daha iyi okunabilirlik için burada birden fazla satırda görüntülenir!

Bazı makinelerde, yukarıdaki yeni sürümde çözülen sorunlarla karşılaştım. Birincisi farklı çift tırnak işleminden kaynaklanmıştı ve diğer sorun, UAC'nin bir Windows 7 makinesinde devre dışı bırakılması (en düşük seviyeye ayarlanmış) nedeniyle, betiğin kendisini tekrar tekrar çağırmasıydı.

Ben şimdi tırnak tırnak yolunda sıyırma ve daha sonra yeniden ekleyerek düzeltildi ve komut dosyası yükseltilmiş haklarla yeniden başlatıldığında eklenen ekstra bir parametre ekledim.

Çift tırnak işaretleri aşağıdakiler tarafından kaldırılır (ayrıntılar buradadır ):

setlocal DisableDelayedExpansion
set "batchPath=%~0"
setlocal EnableDelayedExpansion

Ardından yolu kullanarak erişebilirsiniz !batchPath!. Herhangi bir çift tırnak içermez, bu yüzden "!batchPath!"komut dosyasında daha sonra söylemek güvenlidir .

Çizgi

if '%1'=='ELEV' (shift & goto gotPrivileges)

betiğin VBScript betiği tarafından hakları yükseltmek için çağrılıp çağrılmadığını kontrol eder , böylece sonsuz özyinelemeleri önler. Kullanarak parametreyi kaldırır shift.

Güncelleme:

• Kayıt zorunda kalmamak için .vbsuzantı , Windows 10 , ben çizgiyi yerini almıştır
  "%temp%\OEgetPrivileges.vbs"
  tarafından
  "%SystemRoot%\System32\WScript.exe" "%temp%\OEgetPrivileges.vbs"
  komut yukarıdaki; Ayrıca cd /d %~dp0Stephen (ayrı cevap) ve Tomáš Zato (yorum) tarafından önerildiği gibi komut dizini varsayılan olarak ayarlamak için eklendi.

• Komut dosyası, kendisine iletilen komut satırı parametrelerini onurlandırıyor. Gözlemler ve ilhamlar için jxmallet, TanisDLJ ve Peter Mortensen'e teşekkürler.

• Artjom B.'nin ipucu göre, bunu analiz ve yerini SHIFTtarafından SHIFT /1dosya adını korur, hangi %0parametre

• Temizlemek del "%temp%\OEgetPrivileges_%batchName%.vbs"için :gotPrivilegesbölüme eklendi ( mlt önerildiği gibi). Eklenen %batchName%Eğer paralel olarak farklı toplu çalıştırırsanız etkisini önlemek için. Yalnızca dosya adını ayıklayan forgibi gelişmiş dize işlevlerinden yararlanabilmek için kullanmanız gerektiğini unutmayın %%~nk.

• Optimize edilmiş komut dosyası yapısı, iyileştirmeler ( vbsGetPrivilegesartık her yerde referans verilen ve dosyanın yolunu veya adını kolayca değiştirmeye izin veren değişken eklendi , yalnızca .vbstoplu işin yükseltilmesi gerekiyorsa dosyayı silin )

• Bazı durumlarda, yükseklik için farklı bir çağrı sözdizimi gerekiyordu. Komut dosyası çalışmazsa, aşağıdaki parametreleri kontrol edin:
  set cmdInvoke=0
set winSysFolder=System32
  1. parametreyi değiştirin set cmdInvoke=1ve sorunun giderilip giderilmediğini kontrol edin. cmd.exeYüksekliği gerçekleştiren komut dosyasına eklenir .
  Veya 2. parametreyi değiştirmeye çalışın winSysFolder=Sysnative, bu 64 bit sistemlerde yardımcı olabilir (ancak çoğu zaman gerekli değildir). (ADBailey bunu bildirdi). "Sysnative" yalnızca 32-bit komut dosyası ana bilgisayarından 64-bit uygulamaları başlatmak için gereklidir (örneğin, bir Visual Studio oluşturma işlemi veya başka bir 32-bit uygulamadan komut dosyası çağırma).

• Parametrelerin nasıl yorumlandığını daha açık hale getirmek için, şimdi onu gösteriyorum P1=value1 P2=value2 ... P9=value9. Bu, özellikle yollar gibi parametreleri çift tırnak içine almanız gerektiğinde kullanışlıdır "C:\Program Files".

• VBS komut dosyasında hata ayıklamak istiyorsanız, //Xparametreyi burada önerildiği gibi ilk parametre olarak WScript.exe dosyasına ekleyebilirsiniz (CScript.exe için açıklanmıştır, ancak WScript.exe için de çalışır).

Kullanışlı bağlantılar:

• Toplu iş dosyasındaki özel karakterlerin anlamı:
  Tırnak işaretleri (") , Bang (!) , Düzeltme işareti ( ^) , Ve işareti (&) , Diğer özel karakterler

Jcoder ve Matt'in belirttiği gibi, PowerShell bunu kolaylaştırdı ve hatta yeni bir komut dosyası oluşturmadan toplu komut dosyasına gömülebilir.

Matt'in senaryosunu değiştirdim:

:: Check privileges 
net file 1>NUL 2>NUL
if not '%errorlevel%' == '0' (
    powershell Start-Process -FilePath "%0" -ArgumentList "%cd%" -verb runas >NUL 2>&1
    exit /b
)

:: Change directory with passed argument. Processes started with
:: "runas" start with forced C:\Windows\System32 workdir
cd /d %1

:: Actual work

Matt'in mükemmel yanıtını kullanıyorum, ancak yükseltilmiş komut dosyalarını çalıştırırken Windows 7 ve Windows 8 sistemlerim arasında bir fark görüyorum.

Komut dosyası Windows 8'de yükseltildiğinde, geçerli dizin olarak ayarlanır C:\Windows\system32. Neyse ki, geçerli dizini geçerli komut dosyasının yoluna değiştirerek kolay bir çözüm vardır:

cd /d %~dp0

Not: cd /dSürücü harfinin de değiştiğinden emin olmak için kullanın .

Bunu test etmek için aşağıdakileri bir komut dosyasına kopyalayabilirsiniz. Aynı sonucu görmek için her iki sürümde de normal şekilde çalıştırın. Yönetici olarak çalıştırın ve Windows 8'deki farkı görün:

@echo off
echo Current path is %cd%
echo Changing directory to the path of the current script
cd %~dp0
echo Current path is %cd%
pause

Bunu şu şekilde yaparım:

NET SESSION
IF %ERRORLEVEL% NEQ 0 GOTO ELEVATE
GOTO ADMINTASKS

:ELEVATE
CD /d %~dp0
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
EXIT

:ADMINTASKS
(Do whatever you need to do here)
EXIT

Bu şekilde basittir ve yalnızca Windows varsayılan komutlarını kullanır. Toplu iş dosyasını yeniden dağıtmanız gerekiyorsa harika.

CD /d %~dp0Geçerli dizini dosyanın geçerli dizinine ayarlar (zaten değilse, /dseçenek sayesinde dosyanın bulunduğu sürücüye bakılmaksızın ).

%~nx0 Uzantılı geçerli dosya adını döndürür (Uzantıyı eklemezseniz ve klasörde aynı ada sahip bir exe varsa, exe'yi çağıracaktır).

Bu yazıda o kadar çok cevap var ki cevabımın görülüp görülmeyeceğini bile bilmiyorum.

Her neyse, bu yolu diğer yanıtlarda önerilen diğer çözümlerden daha basit buluyorum, umarım birine yardımcı olur.

Matt'in harika bir cevabı var, ama senaryoya geçirilen argümanları ortadan kaldırıyor. İşte benim argümanları tutan modifikasyonum. Stephen'ın Windows 8'deki çalışma dizini sorununa yönelik düzeltmesini de dahil ettim.

@ECHO OFF
setlocal EnableDelayedExpansion

NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto START ) else ( goto getPrivileges ) 

:getPrivileges
if '%1'=='ELEV' ( goto START )

set "batchPath=%~f0"
set "batchArgs=ELEV"

::Add quotes to the batch path, if needed
set "script=%0"
set script=%script:"=%
IF '%0'=='!script!' ( GOTO PathQuotesDone )
    set "batchPath=""%batchPath%"""
:PathQuotesDone

::Add quotes to the arguments, if needed.
:ArgLoop
IF '%1'=='' ( GOTO EndArgLoop ) else ( GOTO AddArg )
    :AddArg
    set "arg=%1"
    set arg=%arg:"=%
    IF '%1'=='!arg!' ( GOTO NoQuotes )
        set "batchArgs=%batchArgs% "%1""
        GOTO QuotesDone
        :NoQuotes
        set "batchArgs=%batchArgs% %1"
    :QuotesDone
    shift
    GOTO ArgLoop
:EndArgLoop

::Create and run the vb script to elevate the batch file
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%temp%\OEgetPrivileges.vbs"
ECHO UAC.ShellExecute "cmd", "/c ""!batchPath! !batchArgs!""", "", "runas", 1 >> "%temp%\OEgetPrivileges.vbs"
"%temp%\OEgetPrivileges.vbs" 
exit /B

:START
::Remove the elevation tag and set the correct working directory
IF '%1'=='ELEV' ( shift /1 )
cd /d %~dp0

::Do your adminy thing here...

Değilse yükseltilmiş komut dosyasını yeniden başlatmak için PowerShell kullanın. Bu satırları senaryonuzun en üstüne koyun.

net file 1>nul 2>nul && goto :run || powershell -ex unrestricted -Command "Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c %~fnx0 %*'"
goto :eof
:run
:: TODO: Put code here that needs elevation

@ Matt'in cevabından 'net name' yöntemini kopyaladım. Cevabı çok daha iyi belgelenmiştir ve hata mesajları ve benzeri vardır. Bu, PowerShell'in zaten Windows 7 ve üzeri sürümlerde yüklü ve kullanılabilir olması avantajına sahiptir. Geçici VBScript (* .vbs) dosyası yoktur ve araçları indirmenize gerek yoktur.

PowerShell yürütme izinleriniz kilitli olmadığı sürece bu yöntem herhangi bir yapılandırma veya kurulum olmadan çalışmalıdır.

Süper gizli ayarı bazı programlar için __COMPAT_LAYERçevre değişkeni RunAsInvoker çalışacaktır olmadýný kontrol edin bu:

set "__COMPAT_LAYER=RunAsInvoker"
start regedit.exe

Buna rağmen, kullanıcıya yönetici izinleri olmadan devam etmesini isteyen hiçbir UAC olmayacaktır.

Ben betiğin başında yapıştırdım:

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\icacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo args = "" >> "%temp%\getadmin.vbs"
    echo For Each strArg in WScript.Arguments >> "%temp%\getadmin.vbs"
    echo args = args ^& strArg ^& " "  >> "%temp%\getadmin.vbs"
    echo Next >> "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", args, "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs" %*
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

Yazdığım gsudo, bir sudopencereler için de yükseltip o: Geçerli konsolda bir kimlik önbelleği ile (hiçbir bağlam yeni pencerede geçiş), (UAC pop-up azaltılmış) ve aynı zamanda yükseltir PowerShell komutları .

İsterseniz yönetici ayrıcalıkları veya tüm toplu işlem gerektiren komutların yükseltilmesine izin verir. Sadece başagsudo yükseltilmesi gereken herhangi bir şeyden önce .

Gsudo kullanarak kendisini yükselten örnek toplu iş dosyası:

DÜZENLEME: Herhangi bir pencere dili ile çalışan ve whoami sorunlarını önleyen yeni bir astar sürümü :

net session >nul 2>nul & net session >nul 2>nul || gsudo "%~f0" && exit /b || exit /b
:: This will run as admin ::

Alternatif (orijinal sürüm):

@echo off
  rem Test if current context is already elevated:
  whoami /groups | findstr /b BUILTIN\Administrators | findstr /c:"Enabled group" 1> nul 2>nul && goto :isadministrator
  echo You are not admin. (yet)
  :: Use gsudo to launch this batch file elevated.
  gsudo "%~f0"
  goto end
:isadministrator
  echo You are admin.
  echo (Do admin stuff now).
:end

Yüklemek:

• chocolatey aracılığıyla: choco install gsudo
• veya kepçe: scoop install gsudo
• veya github'dan yakalayın: https://github.com/gerardog/gsudo

Gsudo'yu çalışırken görün:

Bu soruya doğrudan uygulanabilir olmasa da, kullanıcı için bazı bilgiler istediğinden, görev zamanlayıcıdan yükseltilmiş .bat dosyamı çalıştırmak istediğimde google beni buraya getirdi.

En basit yaklaşım .bat dosyasına bir kısayol oluşturmaktı, çünkü bir kısayol için Run as administratordoğrudan gelişmiş özelliklerden ayarlayabilirsiniz .

Kısayolu görev zamanlayıcıdan çalıştırdığınızda, yükseltilmiş .bat dosyasını çalıştırır.

Powershell kullanma.

Cmd dosyası uzunsa, yükseklik istemek için bir ilk kullanın ve sonra gerçek işi yapan birini arayın.

Komut dosyası basit bir komutsa, her şey bir cmd dosyasına sığabilir. Komut dosyasını dosya yoluna eklemeyi unutmayın.

Şablon:

@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c " comands or another script.cmd go here "'"

Örnek 1:

@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c "powershell.exe -NoProfile -ExecutionPolicy Bypass -File C:\BIN\x.ps1"'"

Örnek 2:

@echo off
powershell -Command "Start-Process 'cmd' -Verb RunAs -ArgumentList '/c "c:\bin\myScript.cmd"'"

Bunu dene:

@echo off
CLS
:init
setlocal DisableDelayedExpansion
set cmdInvoke=1
set winSysFolder=System32
set "batchPath=%~0"
for %%k in (%0) do set batchName=%%~nk
set "vbsGetPrivileges=%temp%\OEgetPriv_%batchName%.vbs"
setlocal EnableDelayedExpansion
:checkPrivileges
NET FILE 1>NUL 2>NUL
if '%errorlevel%' == '0' ( goto gotPrivileges ) else ( goto getPrivileges )
:getPrivileges
if '%1'=='ELEV' (echo ELEV & shift /1 & goto gotPrivileges)
ECHO.
ECHO Set UAC = CreateObject^("Shell.Application"^) > "%vbsGetPrivileges%"
ECHO args = "ELEV " >> "%vbsGetPrivileges%"
ECHO For Each strArg in WScript.Arguments >> "%vbsGetPrivileges%"
ECHO args = args ^& strArg ^& " "  >> "%vbsGetPrivileges%"
ECHO Next >> "%vbsGetPrivileges%"
if '%cmdInvoke%'=='1' goto InvokeCmd 
ECHO UAC.ShellExecute "!batchPath!", args, "", "runas", 1 >> "%vbsGetPrivileges%"
goto ExecElevation
:InvokeCmd
ECHO args = "/c """ + "!batchPath!" + """ " + args >> "%vbsGetPrivileges%"
ECHO UAC.ShellExecute "%SystemRoot%\%winSysFolder%\cmd.exe", args, "", "runas", 1 >> "%vbsGetPrivileges%"
:ExecElevation
"%SystemRoot%\%winSysFolder%\WScript.exe" "%vbsGetPrivileges%" %*
exit /B
:gotPrivileges
setlocal & cd /d %~dp0
if '%1'=='ELEV' (del "%vbsGetPrivileges%" 1>nul 2>nul  &  shift /1)
REM Run shell as admin (example) - put here code as you like
ECHO %batchName% Arguments: P1=%1 P2=%2 P3=%3 P4=%4 P5=%5 P6=%6 P7=%7 P8=%8 P9=%9
cmd /k

Bu toplu iş dosyası hakkında bilgiye ihtiyacınız varsa, HTML / JS / CSS Snippet'ini çalıştırın:

document.getElementsByTagName("data")[0].innerHTML="ElevateBatch, version 4, release<br>Required Commands:<ul><li>CLS</li><li>SETLOCAL</li><li>SET</li><li>FOR</li><li>NET</li><li>IF</li><li>ECHO</li><li>GOTO</li><li>EXIT</li><li>DEL</li></ul>It auto-elevates the system and if the user presses No, it just doesn't do anything.<br>This CANNOT be used to create an Elevated Explorer.";

data{font-family:arial;text-decoration:none}

<data></data>

Argümanları iletmeniz gerekmiyorsa, burada tek satır uzunluğunda küçük bir UAC komut dosyası var. Bu, en çok oy verilen cevaptaki yükseklik betiği ile benzer bir şey yapar, ancak zehir karakterlerinin her olası kombinasyonunu işleyen kusursuz bir yol olmadığı için argümanları iletmez.

@echo off
net sess>nul 2>&1||(echo(CreateObject("Shell.Application"^).ShellExecute"%~0",,,"RunAs",1:CreateObject("Scripting.FileSystemObject"^).DeleteFile(wsh.ScriptFullName^)>"%temp%\%~nx0.vbs"&start wscript.exe "%temp%\%~nx0.vbs"&exit)

:: Your batch file goes here

Aşağıdaki çözüm temiz ve mükemmel çalışıyor.

1. Elevate zip dosyasını https://www.winability.com/download/Elevate.zip adresinden indirin.

2. Zip içinde iki dosya bulmalısınız: Elevate.exe ve Elevate64.exe. (Sonuncusu yerel 64 bit derlemedir, normal 32 bit sürüm olmasına rağmen, Elevate.exe'nin Windows'un 32 ve 64 bit sürümleriyle iyi çalışmasını gerektirir)

3. Elevate.exe dosyasını Windows'un her zaman bulabileceği bir klasöre kopyalayın (C: / Windows gibi). Veya bat dosyanızı saklamayı planladığınız klasöre kopyalayabilirsiniz.

4. Bir toplu iş dosyasında kullanmak için, yükselt komutuyla yönetici olarak yürütmek istediğiniz komutu aşağıdaki gibi eklemeniz yeterlidir:

 elevate net start service ...