Vim'de tüm satırı yukarı ve aşağı taşı

Notepad ++ uygulamasında Ctrl+Shift ile geçerli satırı yukarı ve aşağı taşımak için + Up/ tuşlarınıDown . Vim'de buna benzer bir komut var mı? Sonsuz rehberlere baktım ama hiçbir şey bulamadım.

Yoksa, işlemi bu tuş kombinasyonuna nasıl bağlayabilirim?

Düzenleme: Mykola'nın yanıtı, arabellek başında ve sonunda olanlar dışında tüm satırlar için çalışır. İlk satırı yukarı veya alt satırı aşağı taşımak satırı siler ve alt satırı yukarı hareket ettirirken piyon gibi başlangıçta iki boşluk atlar! Herkes herhangi bir ayrıntılandırma sunabilir mi?

İşi yapmak için aşağıdakileri .vimrc'nize koyun

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Hattın kaybolması bir Vim hatası gibi görünüyor. Bundan kaçınmak için bir kesmek koydum. Muhtemelen daha doğru bir çözüm var.

Güncelleme

Sadece Vim kombinasyonlarını kullanırken açıklanamayan birçok zorluk var. Bunlar çizgi eksik ve ekstra çizgi atlama.

İşte .vimrc veya ~ / .vim / plugin / swap_lines.vim içine yerleştirilebilen komut dosyası çözümü

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

Bir çizgiyi yukarıdaki çizgiyle değiştirmek istersem genellikle aşağıdakileri yaparım

ddkP

açıklama

• dd satırı siler ve varsayılan kayıt defterine ekler.
• k bir satır yukarı hareket eder (j bir satır aşağı hareket eder)
• P, geçerli satırın üstüne yapışır

İmlecin taşımak istediğiniz satırda olduğunu varsayarsak.

Yukarı ve aşağı hareket: :m hareket etme hareket için

:m +1 - 1 satır aşağı gider

:m -2 - 1 satır yukarı git

(Kaç satır yukarı veya aşağı taşımak istediğinize bağlı olarak + 1'i herhangi bir sayı ile değiştirebileceğinizi unutmayın, yani +2 2 satır aşağı, -3 2 satır yukarı taşıyacaktır)

Belirli bir satıra geçmek için

:set number - sayı satırlarını görüntüleme (nereye taşıdığınızı görmek daha kolay)

:m 3 - 3. satırdan sonra satırı taşıyın (3'ü istediğiniz herhangi bir satırla değiştirin)

Birden çok satırı taşıma:

V(yani Shift- V) ve VIM'de birden çok satır seçmek için kurser'i yukarı ve aşağı hareket ettir

seçildikten sonra :yukarıdaki komutlara basın ve çalıştırın, m +1vb.

Bir satırı yukarı taşıma: ddkP

Bir satırı aşağı taşı: ddp

Bu benim için çalıştı:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, ALT + some_key kullanmak istiyorsanız ve terminaliniz (urxvt bunu yapar) uymayı reddederse, .vimrc'nize böyle bir şey girmelisiniz:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

burada ^], ALT tuşunu temsil eden tek bir karakterdir . Bu karakteri C+v, Escgirmek için Vim'de ( C+q, EscWindows'ta) kullanın.

~ / .vimrc dosyasına aşağıdakini ekleyin (n, m için eşlemeniz olmadığından emin olun)

nmap n :m +1<CR>
nmap m :m -2<CR>

şimdi tuşuna basıldığında nbir satır aşağı ve mbir satır yukarı hareket eder.

Komut modunda, imleci aşağı taşımak istediğiniz satıra getirin ve ardından

ddp

Açıklama: dd geçerli satırı genel arabelleğe siler, imleç konumundan SONRA veya tüm satırlar durumunda bir satır aşağıya geri koyar.

Birçok dokümanda p ve P komutlarıyla ilgili bazı karışıklıklar vardır. Gerçekte p imleç SONRASI ve P AT imleci yapıştırır.

Bu kodu .vimrc (veya .gvimrc) 'ye eklemeniz yeterlidir.

nnoremap <A-j> :m+<CR>==
nnoremap <A-k> :m-2<CR>==
inoremap <A-j> <Esc>:m+<CR>==gi
inoremap <A-k> <Esc>:m-2<CR>==gi
vnoremap <A-j> :m'>+<CR>gv=gv
vnoremap <A-k> :m-2<CR>gv=gv

Bu harika eklentide tam olarak aradığınızı : https://github.com/vim-scripts/upAndDown

Bir basit bir çözüm sizin de koymaktır .vimrcbu satırlar:

nmap <C-UP> :m-2<CR>  
nmap <C-DOWN> :m+1<CR>

Aşağıdaki .vimrc dosyamın sonuna koydum:

noremap H ddkkp
noremap N ddp

Şimdi 'H' ve 'N' mevcut satırı sırasıyla yukarı ve aşağı hareket ettiriyor.

İşte Wikia makalesi örneklerini ( silahın yorumundan cf. bağlantısı) kullanarak MacVim için basitleştirilmiş bir sürüm .

" Move selection up/down (add =gv to reindent after move)
:vmap <D-S-Up> :m-2<CR>gv
:vmap <D-S-Down> :m'>+<CR>gv

Sadece blok seçimi varyantını kullanıyorum, çünkü tüm gereken mevcut satırı seçmek için Shift-V ve isteğe bağlı olarak yukarı / aşağı birkaç satır seçmek için imleç.

Yukarıdaki kısayollara göre, Cmd-ÜstKrkt-Yukarı / Aşağı tuşlarına basmak blok seçimini yukarı / aşağı kaydırır. "D", MacVim'deki Komut anahtarıdır, Windows için "C" (Kontrol) veya "A" (Alt) komutlarını deneyin (örn. <CAf>, Kontrol Alt f olacaktır).

Wikia makalesi, bunlara "= gv" ekliyor; bu, hareketten sonra çevreleyen metne göre blokun girintisini ayarlama etkisine sahip. Bu kafa karıştırıcı, bu yüzden onu kaldırdım ve bunun yerine seçimi hızla girintilemek için kısayollar ekledim.

" Indent selection left/right (Cmd Shift Left/Right is used for Tab switching)
:vmap <D-A-Left> <gv
:vmap <D-A-Right> >gv

Aynı şey << ve >> için de yapılabilir, ancak seçim kaybolacaktır, bu nedenle yukarıdaki bu kısayollar birden çok kez girintili olmasına ve seçimi korunduğu için bloğu hareket ettirmeye izin verir.

MacVim'im Cmd-Alt-Sol / Sağ kullandığım için Sekmeleri Cmd-Shift-Sol / Sağ ile değiştirecek şekilde yapılandırıldı.

İşte MacVim için Sekme anahtarlama (yukarıdaki geri kalanıyla .gvimrc yazın):

:macm Window.Select\ Previous\ Tab key=<D-S-Left>
:macm Window.Select\ Next\ Tab key=<D-S-Right>

vim eklentisi unimpaired.vim [e ve] e

Eğer komutu çarptığında :help moveiçinde vim, burada sonucudur:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

Örneğin: Geçerli satırı bir satır aşağı taşı => :m+1 .

Örn: 100 numaralı satırı 80 => numaralı satırın altına taşıyın :100 m 80 .

Örn: 100 numaralı satırı 200 => numaralı satırın altına taşıyın :100 m 200 .

Örn: [100, 120] içinde numaralı satırları 200 => satırının altına taşıyın :100,120 m 200 .

İşte makinemde çalışan bir çözüm : VIM 8.1 çalıştıran MacBook Pro

Bu komutlar ara belleğinizin üstündeki veya altındaki satırlarınızı silmez.

Alt-J ve Alt-K çıkışlarının gerçek sembollerini kullanmak, anahtar kodlarının ortamımda düzgün eşlenmemeleri için bir çözümdür.

Bunu eski .vimrc'ye atın ve sizin için işe yarayıp yaramadığına bakın.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Benim ddkkpiçin yaptı ( ddkPçok işe yarayacak bir büyük P harfi yerine ).

: m. + 1 veya: m.-2 tek bir satırı hareket ettirirseniz yapardı. Birden çok satırı hareket ettirmek için komut dosyam. Görsel modda, Alt-up / Alt-down görsel seçimi içeren satırları bir satır yukarı / aşağı hareket ettirir. Ekleme modunda veya normal modda, Sayma öneki verilmezse Alt-yukarı / Alt-aşağı geçerli satırı hareket ettirir. Bir sayım öneki varsa, Alt-up / Alt-down geçerli satırdan başlayarak birçok satırı bir satır yukarı / aşağı hareket ettirir.

function! MoveLines(offset) range
    let l:col = virtcol('.')
    let l:offset = str2nr(a:offset)
    exe 'silent! :' . a:firstline . ',' . a:lastline . 'm'
        \ . (l:offset > 0 ? a:lastline + l:offset : a:firstline + l:offset)
    exe 'normal ' . l:col . '|'
endf

imap <silent> <M-up> <C-O>:call MoveLines('-2')<CR>
imap <silent> <M-down> <C-O>:call MoveLines('+1')<CR>
nmap <silent> <M-up> :call MoveLines('-2')<CR>
nmap <silent> <M-down> :call MoveLines('+1')<CR>
vmap <silent> <M-up> :call MoveLines('-2')<CR>gv
vmap <silent> <M-down> :call MoveLines('+1')<CR>gv

Bunu belirli bir aramayla eşleşen birden çok satırda yapmak istiyorsanız:

• Yukarı: :g/Your query/ normal ddpveya:g/Your query/ m -1
• Aşağı :g/Your query/ normal ddpveya:g/Your query/ m +1