CIL (MSIL için doğru isim) ve Java bayt kodu, farklı olduklarından daha fazla aynıdır. Yine de bazı önemli farklılıklar var:
1) CIL, başından beri birden çok dil için bir hedef olarak hizmet etmek üzere tasarlanmıştır. Bu nedenle, imzalı ve işaretsiz türler, değer türleri, işaretçiler, özellikler, temsilciler, olaylar, jenerikler, tek kökü olan bir nesne sistemi ve daha fazlasını içeren çok daha zengin bir tür sistemini destekler. CIL, global işlevler ve kuyruk arama optimizasyonları gibi ilk CLR dilleri (C # ve VB.NET) için gerekli olmayan özellikleri destekler . Karşılaştırıldığında, Java bayt kodu Java dili için bir hedef olarak tasarlanmıştır ve Java'nın kendisinde bulunan kısıtlamaların çoğunu yansıtır. Java bayt kodu kullanarak C veya Şema yazmak çok daha zor olurdu.
2) CIL, yerel kitaplıklara ve yönetilmeyen koda kolayca entegre olacak şekilde tasarlanmıştır
3) Java bayt kodu yorumlanacak veya derlenecek şekilde tasarlanırken, CIL yalnızca JIT derlemesi varsayılarak tasarlandı. Bununla birlikte, Mono'nun ilk uygulaması bir JIT yerine bir yorumlayıcı kullandı.
4) CIL, doğrudan bayt kodu formuyla eşleşen, insan tarafından okunabilir ve yazılabilir bir montaj dili formuna sahip olacak şekilde tasarlanmış ( ve belirtilmiştir ). Java bayt kodunun (adından da anlaşılacağı gibi) yalnızca makine tarafından okunabilir olması gerektiğine inanıyorum. Elbette, Java bayt kodu, orijinal Java'ya nispeten kolay bir şekilde geri derlenebilir ve aşağıda gösterildiği gibi, aynı zamanda "parçalarına ayrılabilir".
JVM'nin (çoğu) CLR'den (herhangi biri) daha yüksek düzeyde optimize edildiğine dikkat etmeliyim. Bu nedenle, ham performans Java bayt kodunu hedeflemeyi tercih etmek için bir neden olabilir. Bu bir uygulama detayıdır.
Bazı insanlar Java bayt kodunun çoklu platform olarak tasarlandığını, CIL ise yalnızca Windows için tasarlandığını söylüyor. Durum bu değil. .NET çerçevesinde bazı "Windows" ismleri vardır ancak CIL'de yoktur.
Yukarıdaki 4) numaralı noktaya örnek olarak, bir süre önce bir Java to CIL derleyicisine bir oyuncak yazdım. Bu derleyiciyi aşağıdaki Java programını beslerseniz:
class Factorial{
public static void main(String[] a){
System.out.println(new Fac().ComputeFac(10));
}
}
class Fac {
public int ComputeFac(int num){
int num_aux ;
if (num < 1)
num_aux = 1 ;
else
num_aux = num * (this.ComputeFac(num-1)) ;
return num_aux ;
}
}
derleyicim aşağıdaki CIL'yi çıkaracak:
.assembly extern mscorlib { }
.assembly 'Factorial' { .ver 0:0:0:0 }
.class private auto ansi beforefieldinit Factorial extends [mscorlib]System.Object
{
.method public static default void main (string[] a) cil managed
{
.entrypoint
.maxstack 16
newobj instance void class Fac::'.ctor'()
ldc.i4 3
callvirt instance int32 class Fac::ComputeFac (int32)
call void class [mscorlib]System.Console::WriteLine(int32)
ret
}
}
.class private Fac extends [mscorlib]System.Object
{
.method public instance default void '.ctor' () cil managed
{
ldarg.0
call instance void object::'.ctor'()
ret
}
.method public int32 ComputeFac(int32 num) cil managed
{
.locals init ( int32 num_aux )
ldarg num
ldc.i4 1
clt
brfalse L1
ldc.i4 1
stloc num_aux
br L2
L1:
ldarg num
ldarg.0
ldarg num
ldc.i4 1
sub
callvirt instance int32 class Fac::ComputeFac (int32)
mul
stloc num_aux
L2:
ldloc num_aux
ret
}
}
Bu, ilasm.exebir yürütülebilir dosya oluşturmak gibi bir CIL derleyicisine beslenebilen geçerli bir CIL programıdır . Gördüğünüz gibi, CIL tamamen okunabilir ve yazılabilir bir dildir. Herhangi bir metin düzenleyicide kolayca geçerli CIL programları oluşturabilirsiniz.
Ayrıca yukarıdaki Java programını javacderleyiciyle derleyebilir ve ardından ortaya çıkan sınıf dosyalarını javap"disassembler" aracılığıyla çalıştırarak aşağıdakileri elde edebilirsiniz:
class Factorial extends java.lang.Object{
Factorial();
Code:
0: aload_0
1: invokespecial #1;
4: return
public static void main(java.lang.String[]);
Code:
0: getstatic #2;
3: new #3;
6: dup
7: invokespecial #4;
10: bipush 10
12: invokevirtual #5;
15: invokevirtual #6;
18: return
}
class Fac extends java.lang.Object{
Fac();
Code:
0: aload_0
1: invokespecial #1;
4: return
public int ComputeFac(int);
Code:
0: iload_1
1: iconst_1
2: if_icmpge 10
5: iconst_1
6: istore_2
7: goto 20
10: iload_1
11: aload_0
12: iload_1
13: iconst_1
14: isub
15: invokevirtual #2;
18: imul
19: istore_2
20: iload_2
21: ireturn
}
javapÇıkışı (bildiğim kadarıyla) derlenebilir değil ama CIL çıkışına karşılaştırmak takdirde iki çok benzer olduğunu görebilirsiniz yukarıda.