Windows toplu iş dosyaları% * yapısına sahip mi?

Bir toplu iş dosyasında aşağıdakileri yapmak zorunda mıyım (örn.)?

@echo off
call other.bat %1 %2 %3 %4 %5 %6 %7 %8 %9

Windows toplu iş dosyaları (Windows XP'den beri, ancak muhtemelen daha önce) %*,% 1'den sonraki tüm parametreleri değerlendiren yapıyı destekler .

Ne yazık ki, bu SHIFTkomut onurlandırılmaz , bu nedenle aşağıdakiler işe yaramaz:

@echo off
set EATEN=%1
shift

call other.bat %*

Yine de ilk parametreyi ikinci toplu iş dosyasına geçirir.

Tüm argümanları aşağıdaki gibi bir şey kullanarak bir araya getirebilirsiniz:

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Bu, kaç argüman olduğuna bakılmaksızın çalışır.

Örneğin, ilk 3 parametreyi atlamak ve geri kalanını geçirmek istiyorsanız:

@echo off
for /f "tokens=1-3*" %%a in ("%*") do (
   set par1=%%a
   set par2=%%b
   set par3=%%c
   set therest=%%d
   )

call other.bat %therest%

Parametrelerde tırnak işaretleri ile ilgili sorunlar olabilir.

şuraya: Patrick Cuff, /programming/382587/how-to-get-batch-file-parameters-from-nth-position-on

Evet onlar yapar.

Örneğinizi aşağıdaki gibi yazabilirsiniz:

@echo off
call other.bat %*

Ayrıca: vardiya pencerelerde desteklenmektedir ... Bkz bu .
Ancak, bu son bağlantı, vardiya işleminin% * ile birlikte çalışmadığını doğrular:

• ile% * Kullanımı vardiya
  Shift hiçbir% * toplu parametre üzerinde etkisi yoktur.

@echo off
cls
setlocal enabledelayedexpansion

:: Disable the display of information by changing [set "_ENABLE_INFO="] to [set "_ENABLE_INFO=::"].
set "_ENABLE_INFO="
set _DBQ="

set "_PARMS.ORIGINAL=%*" && if defined _PARMS.ORIGINAL (
   if not defined _PARMS.IDX (
      echo Parameter Index^(es^) to extract eg.:
      echo 1 2 5 9 11 39 400
      set /p "_PARMS.IDX=>"
   )
   set "_PARMS.IDX=¡!_PARMS.IDX: =¡ ¡!¡"
   set "_PARMS.IDX=!_PARMS.IDX:¡¡=!"
   set "_PARMS.IDX=!_PARMS.IDX: =!"
   call :_FN_PROC.STRING %*
%_ENABLE_INFO% goto :FINISH
   goto :eof
) else (
   echo No input parameters.
)
goto :eof


:_FN_PROC.STRING
set "_PARMS.PROCESS.STRING=%*"
:_FN_PROC.STRING.LOOP
set "_PARMS.PROCESS.STRING=!_PARMS.PROCESS.STRING:%_DBQ%=¡!"
set /a _PARMS.COUNT+=1
for /f "tokens=1* delims= " %%a in ("!_PARMS.PROCESS.STRING!") do (
   set _PARMS.TMP.CHECK=%%a
   set _PARMS.PROCESS.STRING=%%b
   if "!_PARMS.TMP.CHECK!" NEQ "!_PARMS.TMP.CHECK:¡=!" (
      for /f "tokens=1* delims=¡" %%c in ("%%a !_PARMS.PROCESS.STRING!") do (
         set _PARMS.TMP.CHECK="%%c"
         set _PARMS.PROCESS.STRING=%%d
      )
   )
)

if "!_PARMS.IDX:¡%_PARMS.COUNT%¡=!" EQU "!_PARMS.IDX!" (
   set _PARMS.REMAINING=!_PARMS.REMAINING! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX!{%_PARMS.COUNT%}
) else (
   set _PARMS.EXTRACTED=!_PARMS.EXTRACTED! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX:¡%_PARMS.COUNT%¡=!
   set _PARMS.IDX=!_PARMS.IDX![%_PARMS.COUNT%]
)

if "!_PARMS.PROCESS.STRING: =!"=="" (set _PARMS.PROCESS.STRING=)
if defined _PARMS.PROCESS.STRING (goto :_FN_PROC.STRING.LOOP)

set _DBQ=
set _PARMS.TMP.CHECK=
if defined _PARMS.REMAINING (set _PARMS.REMAINING=!_PARMS.REMAINING:~1!)
if defined _PARMS.EXTRACTED (set _PARMS.EXTRACTED=!_PARMS.EXTRACTED:~1!)
goto :eof


:FINISH
echo.
echo _PARMS.IDX ^:
echo    ¡^=¡ no Parameter Index was specified for extraction.
echo    ¡n¡ nth Parameter was not processed (Index larger than Parameters Count).
echo    [n] nth Parameter was Extracted.
echo    {n} nth Parameter was Ignored (Remaining).
echo.
set _
goto :eof