Hmm, iki olası algoritmayı düşünebilirim: A sekansı boyunca doğrusal bir tarama veya indekslerin sürekli zaman aramasıyla bir sözlük oluşturma.
Birçok potansiyel alt B'yi tek bir büyük A dizisine karşı test ediyorsanız , varyantı sözlükle kullanmanızı öneririm.
Doğrusal Tarama
Açıklama
A dizisi için bir imleç tutuyoruz . Daha sonra B alt sekansındaki tüm maddeleri tekrarlıyoruz . Her bir öğe için, eşleşen bir öğe bulana kadar imleci A'da ilerletiriz . Eşleşen bir öğe bulunamazsa, B bir alt sıra değildir.
Bu daima O (seq.size) biçiminde çalışır .
pseudocode
Emir Kipi:
def subsequence? seq, subseq:
i = 0
for item in subseq:
i++ while i < seq.size and item != seq[i]
return false if i == seq.size
return true
Fonksiyonel tarzı:
let rec subsequence? = function
| _ [] -> true
| [] _ -> false
| cursor::seq item::subseq ->
if cursor = item
then subsequence? seq subseq
else subsequence? seq item::subseq
Örnek uygulama (Perl):
use strict; use warnings; use signatures; use Test::More;
sub is_subsequence_i ($seq, $subseq) {
my $i = 0;
for my $item (@$subseq) {
$i++ while $i < @$seq and $item != $seq->[$i];
return 0 if $i == @$seq;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
return 1 if @$subseq == 0;
return 0 if @$seq == 0;
my ($cursor, @seq) = @$seq;
my ($item, @subseq) = @$subseq;
return is_subsequence_f(\@seq, $cursor == $item ? \@subseq : $subseq);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;
Sözlük araması
Açıklama
A dizisindeki öğeleri endeksleriyle eşleştiriyoruz . Ardından, B'deki her bir öğe için uygun endeksleri ararız, küçük olan indeksleri atlarız ve mümkün olan en küçük endeksi alt limit olarak seçeriz. Endeks bulunmadığında, B bir alt dizidir.
O , k ( kaç tane sayı) olduğunu açıklayan O (alt boyut) · k) gibi bir şeyde çalışır seq. Artı bir O (sıralı boyut) ek yükü
Bu çözümün avantajı, arama tablosunu oluşturmanın yükünü ödediğinizde negatif bir karara çok daha hızlı (sabit zamana kadar) ulaşılabilmesidir.
pseudocode:
Emir Kipi:
# preparing the lookup table
dict = {}
for i, x in seq:
if exists dict[x]:
dict[x].append(i)
else:
dict[x] = [i]
def subsequence? subseq:
min_index = -1
for x in subseq:
if indices = dict[x]:
suitable_indices = indices.filter(_ > min_index)
return false if suitable_indices.empty?
min_index = suitable_indices[0]
else:
return false
return true
Fonksiyonel tarzı:
let subsequence? subseq =
let rec subseq-loop = function
| [] _ -> true
| x::subseq min-index ->
match (map (filter (_ > min-index)) data[x])
| None -> false
| Some([]) -> false
| Some(new-min::_) -> subseq-loop subseq new-min
in
subseq-loop subseq -1
Örnek uygulama (Perl):
use strict; use warnings; use signatures; use Test::More;
sub build_dict ($seq) {
my %dict;
while (my ($i, $x) = each @$seq) {
push @{ $dict{$x} }, $i;
}
return \%dict;
}
sub is_subsequence_i ($seq, $subseq) {
my $min_index = -1;
my $dict = build_dict($seq);
for my $x (@$subseq) {
my $indices = $dict->{$x} or return 0;
($min_index) = grep { $_ > $min_index } @$indices or return 0;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
my $dict = build_dict($seq);
use feature 'current_sub';
return sub ($subseq, $min_index) {
return 1 if @$subseq == 0;
my ($x, @subseq) = @$subseq;
my ($new_min) = grep { $_ > $min_index } @{ $dict->{$x} // [] } or return 0;
__SUB__->(\@subseq, $new_min);
}->($subseq, -1);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;
Sözlük Arama Değişkeni: Sonlu Durum Makinesi Olarak Kodlama
Açıklama
Daha fazla bellekte işlem yaparsak algoritmik karmaşıklığı O (alt boyut) değerine kadar azaltabiliriz . Öğeleri dizinleriyle eşlemek yerine, her düğümün dizinindeki bir öğeyi temsil ettiği bir grafik oluştururuz. Kenarlar olası geçişleri gösterir, örneğin dizinin a, b, akenarları olabilir a@1 → b@2, a@1 → a@3, b@2 → a@3. Bu grafik sonlu durum makinesine eşdeğerdir.
Arama sırasında, başlangıçta ağacın ilk düğümü olan bir imleç tutuyoruz. Daha sonra B alt listesindeki her eleman için kenardan yürürüz . Böyle bir kenar yoksa, B alt liste değildir. Tüm öğelerden sonra imleç geçerli bir düğüm içeriyorsa, B bir alt listedir.
pseudocode
Emir Kipi:
# preparing the graph
graph = {}
for x in seq.reverse:
next_graph = graph.clone
next_graph[x] = graph
graph = next_graph
def subseq? subseq:
cursor = graph
for x in subseq:
cursor = graph[x]
return false if graph == null
return true
Fonksiyonel tarzı:
let subseq? subseq =
let rec subseq-loop = function
| [] _ -> true
| x::subseq graph -> match (graph[x])
| None -> false
| Some(next-graph) -> subseq-loop subseq next-graph
in
subseq-loop subseq graph
Örnek uygulama (Perl):
use strict; use warnings; use signatures; use Test::More;
sub build_graph ($seq) {
my $graph = {};
for (reverse @$seq) {
$graph = { %$graph, $_ => $graph };
}
return $graph;
}
sub is_subsequence_i ($seq, $subseq) {
my $cursor = build_graph($seq);
for my $x (@$subseq) {
$cursor = $cursor->{$x} or return 0;
}
return 1;
}
sub is_subsequence_f ($seq, $subseq) {
my $graph = build_graph($seq);
use feature 'current_sub';
return sub ($subseq, $graph) {
return 1 if @$subseq == 0;
my ($x, @subseq) = @$subseq;
my $next_graph = $graph->{$x} or return 0;
__SUB__->(\@subseq, $next_graph);
}->($subseq, $graph);
}
my $A = [1, 2, 3, 4];
my $B = [1, 3];
my $C = [1, 3, 4];
my $D = [3, 1];
my $E = [1, 2, 5];
for my $is_subsequence (\&is_subsequence_i, \&is_subsequence_f) {
ok $is_subsequence->($A, $B), 'B in A';
ok $is_subsequence->($A, $C), 'C in A';
ok ! $is_subsequence->($A, $D), 'D not in A';
ok ! $is_subsequence->($A, $E), 'E not in A';
ok $is_subsequence->([1, 2, 3, 4, 3, 5, 6], [2, 3, 6]), 'multiple nums';
}
done_testing;