Excel 2010 Formül giriş hücre argümanları için belirli hücreler

     Col A  Col B  Col C
Row 1  a      a      a  
Row 2  a      a      a  
Row 3  a      a      a  

COUNTIF işlevinde belirli bir aralık ayarlamaya çalışıyorum, = COUNTIF (aralık, ölçüt).

Örnek 1: Yukarıdaki örnek verileri kullanarak, Satır 1, Sütun A'da "a" harfinin kaç oluşumunun olduğunu görmek istiyorum. Bu sadece tek hücreye A2 bakarak yapılabilir.

=COUNTIF(A1,"a")

Örnek 2: Satır 2'nin tamamında kaç tane "a" gerçekleştiğini görmek istiyorum. Bu, A2: C2 aralığını kullanarak yapılabilir.

=COUNTIF(A2:C2,"a")

Örnek 3: Burası benim sıkışıp kaldığım yer. Satır 3, Sütun A & amp; Sadece C Bunun formüle nasıl girileceğini çözemiyorum.

=COUNTIF(????????,"a")

DÜZENLE : Hızlı tepkiler için hepinize teşekkür ederim. Bu soruyu sormamın nedeni, gerçekten şu sorun üzerinde çalışıyorum:

El ile A - H sütunlarına veri girdim. Sütun A & amp; B birleştirildiğinde dört derecelendirmeden birini oluşturur. C & amp; D ikinci puanı yaratın. E & amp; F üçüncü yaratır. G & amp; H, dördüncü derece yaratır. Bu dört derecelendirmeyi birleştirdim ve sütun I - L'de görülüyor. Bu dört derecelendirmenin (25 kombinasyondan, tekrarlanabilir) farklı sırada göründüğü gibi, en yüksek değeri (1 = yüksek, 4 = düşük ) sütun N içine. Sütun M, gerekli işlevleri tamamlamak için gereken ek bir sütun. Dört puanlamanın en yüksek derecesini 1-25 arasında bir sayı olarak verir (toplam olası seçenekler). Bu sayıdan sonra, derecelendirme sayfasından ilgili derecelendirmeyi endeksliyorum.

Aşağıdaki formüller gayet iyi çalışıyor. Yardım istememin sebebi iki nedenden dolayı. Tüm çalışmaları tek bir hücrede birleştirmek (eğer mümkünse) ve I - L eklenmiş sütunlarını kaldırmak istiyorum, burada bir işlevdeki derecelendirme başına iki manuel girişi kolayca CONCATENATE (). Yapılabileceğini düşündüm, ama beni esas tutan şey aşağıdaki kodun bölümleri:

COUNTIF(I1:L1,Ratings!$A$1:$A$25)

Beni geri tutuyor, çünkü COUNTIF () bir giriş bağımsız değişkeni olarak bir aralığı alabilir, ancak hücreleri ayıramaz. COUNT argümanının "range" bölümünün (A1 & B1), (C1 & D1), (E1 & F1), (G1 & H1) olmasını istiyorum. Mevcut olan her kombinasyon için derecelendirmeler "Derecelendirme" etiketli ikinci sayfadadır.

Sheet 1: Sheet1

Columns: A  B  C  D  E  F  G  H  I  J  K  L  M  N
  Row 1: D  2  A  5  E  3  E  3  D2 A5 E3 E3   

-Sollar A-H manuel olarak girilir.

Sütun I (A1 ve B1)

Sütun J, (C1 & D1)

Sütun K (El ve F1'dir)

Sütun L, (G1 & H1) dir.

- Sütun M

  {=IFERROR(MATCH(1,IF(COUNTIF(I1:L1,Ratings!$A$1:$A$25)>0,1,0),0),"")}

Sütun N

   =IFERROR(INDEX(Ratings!$B$1:$B$25,M1),"")

Derecelendirmeler etiketli ikinci sayfa aşağıdadır:

Sheet 2: Ratings
Columns: A   B
Row 1:   A5  1
Row 2:   A4  1
Row 3:   B5  1
Row 4:   A3  1
Row 5:   A2  1
Row 6:   B4  2
Row 7:   B3  2
Row 8:   C5  2
Row 9:   C4  2
Row 10:  D5  2
Row 11:  A1  3
Row 12:  B2  3
Row 13:  B1  3
Row 14:  C3  3
Row 15:  C2  3
Row 16:  D4  3
Row 17:  E5  3
Row 18:  C1  4
Row 19:  D3  4
Row 20:  D2  4
Row 21:  D1  4
Row 22:  E4  4
Row 23:  E3  4
Row 24:  E2  4
Row 25:  E1  4

Umarım eldeki tüm sorunla, neyi başarmaya çalıştığımı daha iyi anlayabilirsiniz.

=countif(A3,"a")+countif(C3,"a")

veya daha sade bir şekilde:

=(A3="a")+(C3="a")

Ayrık bir Adlı Aralık tanımlasanız bile, COUNTIF() kabul etmeyeceğim.

Ancak bir şey gibi:

=SUMPRODUCT(COUNTIF(INDIRECT({"A3","C3"}),"a"))

çalışacak, ama toplamından daha iyi değil COUNTIF() s.

İşte birkaç seçenek:

Bu, endeks numarasına dayanmaktadır:

=SUM(INDEX(((COLUMN(A3:C3) = 1)+(COLUMN(A3:C3) =3))*(A3:C3="a"),))

Bu, her birinin modeline dayanmaktadır:

=SUM(INDEX((MOD(COLUMN($A$3:$C$3),2)=1)*($A$3:$C$3="a"),))

Bu, Satır 1'deki değerlere dayanır:

=SUM(INDEX(($A$1:$C$1="Yes")*($A$3:$C$3="a"),))

Bir arkadaşımın yardımı ile daha iyi bir çözüm buldum. Verilen 4 değerin en yüksek derecesini bulmak için COUNTIF () yöntemini MIN (VLOOKUP (), VLOOKUP (), VLOOKUP (), VLOOKUP ()) ile değiştirmekten ibarettir. Ayrıca 2 sütunu birleştirebildim, böylece metodu kullanarak 4 ekstra kombinasyon sütunu ve 1 "orta adım" sütunu elimine ettim.

=MIN(VLOOKUP((A1&B1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((C1&D1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((E1&F1),Ratings!$A$1:$B$25,2,FALSE),VLOOKUP((G1&H1),Ratings!$A$1:$B$25,2,FALSE))