Excel Kullanarak Tablo Oluştururken Hücrenin Yeniden Boyutlandırılmasından Kaçının

İnternette çok geniş kapsamlı olarak arama yaptım, ancak bulduğum soruların tüm çözümleri zaten var olan bir tablodaki veya pivot tabloda bulunan hücrelerin yeniden boyutlandırılmasında nasıl başarılı olunabileceğine ilişkin. Seçenekler altındaki ayarlarda da arama yaptım, ancak sorunumu giderecek herhangi bir ayar görmedim.

Asıl sorunum, yıla göre maaşlarım hakkında bilgi depolayan birden fazla tablo oluşturmak istediğim tek bir çalışma sayfamın olması. Verileri okunmasını kolaylaştırmak için sütunları zaten boyutlandırdığım ilk yıl için ilk tabloyu zaten yaptım. Ancak, yeni başlıklarımı seçtiğimde ve Tablo Olarak Biçimlendir , Excel, tüm metinlerimi yeni metne sığacak şekilde yeniden boyutlandırıyor.

Başlıklarımın bazıları sütunlara tam olarak uymuyor, ancak bu tablo kişisel kullanım içindir ve başlıklarımın daha sonra başvurmak için daha uzun süre açık olmak için açık adlara (daha uzun olsa da) sahip olmalarını tercih ediyorum. Bu yüzden birinin buna bir çözümü olduğunu umuyorum. Tüm sütunları tekrar el ile yeniden boyutlandırmak gerçekten can sıkıcı olurdu.

Bunu gerçekleştirmenin iki yolu vardır:

1. En basit yol boş bir tablo oluşturmaktır. ilk ve sonra istediğiniz şekilde ayarlayın.
2. Seçimin sütun genişliklerini kaydeden, Tablo olarak biçimlendiren ve ardından sütun genişliklerini geri yükleyen bir makro kullanın. Makro, bir kısayol tuşu veya bir komut düğmesiyle çalışmak üzere ayarlanabilir veya kurdeleye eklenebilir. Kesişmesini sağlamak bile mümkündür Format as Table şerit aracı.

Yöntem 2 için, standart bir modüle aşağıdaki kodu ekleyin:

'============================================================================================
' Module     : <any standard module>
' Version    : 0.1.0
' Part       : 1 of 1
' References : N/A
' Source     : https://superuser.com/a/1332155/763880
'============================================================================================
Option Explicit

Public Sub ToggleTable_NoResize()
       Dim ¡ As Long

  Const s_DefaultStyle As String = "TableStyleMedium9" ' Change this for a different default style

  Dim asngColumnWidths() As Single
  ReDim asngColumnWidths(1 To Selection.Columns.Count)
  For ¡ = LBound(asngColumnWidths) To UBound(asngColumnWidths)
    asngColumnWidths(¡) = Selection.Columns(¡).ColumnWidth
  Next ¡
  Application.ScreenUpdating = False
    Dim loNewTable As ListObject
    On Error Resume Next
      Set loNewTable = ActiveSheet.ListObjects.Add(xlSrcRange, Selection, , xlYes)
    On Error GoTo 0
    If loNewTable Is Nothing Then
      Dim loExistingTable As ListObject
      On Error Resume Next
        Set loExistingTable = Selection.ListObject
      On Error GoTo 0
      If Not loExistingTable Is Nothing Then
        loExistingTable.Unlist
      End If
    Else
      loNewTable.TableStyle = s_DefaultStyle
      For ¡ = LBound(asngColumnWidths) To UBound(asngColumnWidths)
        Selection.Columns(¡).ColumnWidth = asngColumnWidths(¡)
      Next ¡
    End If
  Application.ScreenUpdating = True

End Sub

Kısayol tuşu ile ayarlamak için:

• Geliştirici sekmesinin gösterildiğinden emin olun
• Basın Alt + L + P + M ; makroyu seçin; basın Options…; ve kısayol tuşunu ayarlayın.

Notlar:

Tablonun varsayılan stili belirtilen kodda değiştirilebilir.

Ek bir özellik olarak, makroyu tekrar çalıştırmak Tabloyu tekrar normal bir hücre aralığına dönüştürecektir.

RobinCTS tarafından yaratılan orijinal marco'ya tam kredi.

Ancak, makroda küçük sorunlar var. Kodlarda özel bir "¡" (ünlem işareti yazılı) işareti bulunur. Çalıştırdığınızda hata veriyor. Düzeltmek için küçük değişiklikler yaptım.

Varsayılan davranış da değişmiştir. Tablonun geçerli formatını / stilini korur ve herhangi bir formatlama / stil uygulamaz.

Makroyu tekrar çalıştırmak bir tabloyu tekrar veri aralığına dönüştürecektir.

Option Explicit

'A slight modification of the code from https://superuser.com/a/1332155/763880    
Public Sub ToggleTable_NoResize()
  Dim var As Long

  Const s_DefaultStyle As String = "" 'Change this if you want a different default style

  Dim asngColumnWidths() As Single
  ReDim asngColumnWidths(1 To Selection.Columns.Count)
  For var = LBound(asngColumnWidths) To UBound(asngColumnWidths)
    asngColumnWidths(var) = Selection.Columns(var).ColumnWidth
  Next var
  Application.ScreenUpdating = False
    Dim loNewTable As ListObject
    On Error Resume Next
      Set loNewTable = ActiveSheet.ListObjects.Add(xlSrcRange, Selection, , xlYes)
    On Error GoTo 0
    If loNewTable Is Nothing Then
      Dim loExistingTable As ListObject
      On Error Resume Next
        Set loExistingTable = Selection.ListObject
      On Error GoTo 0
      If Not loExistingTable Is Nothing Then
        loExistingTable.Unlist
      End If
    Else
      loNewTable.TableStyle = s_DefaultStyle
      For var = LBound(asngColumnWidths) To UBound(asngColumnWidths)
        Selection.Columns(var).ColumnWidth = asngColumnWidths(var)
      Next var
    End If
  Application.ScreenUpdating = True

End Sub