Bu şifre betiği ne işe yarıyor? [kapalı]

-1

Bu dosyayı işyerindeki bir birimde buldum ...

Set WshShell = CreateObject("WScript.Shell")
PINGFlag = Not CBool(WshShell.run("ping contoso.com -n 1 " & vSystemIdentifier,0,True))
      If PINGFlag = True Then
         'Successful ping
    'WScript.Echo "Connectivity to domain confirm."
    Call Password
      Else
         'Unsuccessful ping
    'WScript.Echo "No Connectivity to domain password check cancelled."
      End If



Function Password()

'========================================
    ' First, get the domain policy.
    '========================================
    Dim oDomain
    Dim oUser
    Dim maxPwdAge
    Dim numDays
    Dim warningDays

    warningDays = 15

    Set LoginInfo = CreateObject("ADSystemInfo")  
    Set objUser = GetObject("LDAP://" & LoginInfo.UserName & "")  
    strDomainDN = UCase(LoginInfo.DomainDNSName) 
    strUserDN = LoginInfo.UserName


    Set oDomain = GetObject("LDAP://" & strDomainDN)
    Set maxPwdAge = oDomain.Get("maxPwdAge")

    '========================================
    ' Calculate the number of days that are
    ' held in this value.
    '========================================
    numDays = CCur((maxPwdAge.HighPart * 2 ^ 32) + _
                    maxPwdAge.LowPart) / CCur(-864000000000)
    'WScript.Echo "Maximum Password Age: " & numDays

    '========================================
    ' Determine the last time that the user
    ' changed his or her password.
    '========================================
    Set oUser = GetObject("LDAP://" & strUserDN)

    '========================================
    ' Add the number of days to the last time
    ' the password was set.
    '========================================
    whenPasswordExpires = DateAdd("d", numDays, oUser.PasswordLastChanged)
    fromDate = Date
    daysLeft = DateDiff("d",fromDate,whenPasswordExpires)

    'WScript.Echo "Password Last Changed: " & oUser.PasswordLastChanged

    if (daysLeft < warningDays) and (daysLeft > -1) then
        Msgbox "Password Expires in " & daysLeft & " day(s)" & " at " & whenPasswordExpires & chr(13) & chr(13) & "Press CTRL-ALT-DEL and" & chr(13) & "select the 'Change a password' option" & chr(13) & "Please allow enough time for password change to take effect," & chr(13) & "minimum of 15 minutes before disconnecting", 0, "PASSWORD EXPIRATION WARNING!"
    End if

    '========================================
    ' Clean up.
    '========================================
    Set oUser = Nothing
    Set maxPwdAge = Nothing
    Set oDomain = Nothing
End Function

script passwords

— Alex
kaynak

Yerel BT personelinize senaryonun amacını sordunuz mu? Yoksa yerel BT misiniz ve bu komut dosyasının neden desteklediğiniz bilgisayarlarda olduğunu merak ediyor musunuz?

— music2myear

Parolalarının süresi dolmak üzere olduğunda, kullanıcıları hesaplarını kapatmadan önce potansiyel olarak değiştirebileceklerini bildiren bir komut dosyası gibi görünmektedir. Tahminimce senaryoyu giriş yaparken ya da arka planda sürekli olarak çalıştırmak planlanmış.

— Jesse P.,

Neden bilgisayarlarda olduğunu merak ediyorum. Her zaman çalıştıkları için bu birimlerde oturum açılmaz. Onları biraz fazla temizlemeye çalışmak o kadar da karışıklık yaratmadı ve buna rastladım. Bilgiyi takdir et.

— Alex

@Alex - Hesapların şifresi yoksa, şifresi yoktur ve bu, şifrenin herhangi bir hesapta olduğu gibi sona ereceği anlamına gelir. Senaryo hakkında en komik olan şey şudur: Windows, parolanın süresi dolmak

— üzereyken

@Alex Bu komut dosyasının gerekli olmasının nedeni, bu bilgisayarların her zaman oturum açmış olmalarıdır. Windows, bir kullanıcıya yalnızca oturum açtığında parolalarının süresinin dolduğunu bildirir.

— Twisty Impersonator

Bu komut dosyası, bir kullanıcının şifresinin süresinin dolması durumunda kullanıcıyı uyarması için bir açılır pencere oluşturur.

Başlangıçta MarkK / Mark-K tarafından hem Sunucu Arızası hem de Microsoft'un TechNet Forumlarında yayınlanan ve bu mesajların her ikisi de gönderdiğiniz sürümden itibaren güncellemeler almış olan cevaplara gönderilmiştir. Sorunuza eklediğiniz sürüm aynı zamanda Mark K sürümlerinde bulunmayan bazı değişiklikleri de içerir.

Başvuru için, burada ilgili Sunucu Hatası cevabına ve TechNet Forumları'ndaki Orijinal ve Güncelleme mesajlarına bir bağlantı verilmiştir .

Ayrıca, bu betiğin JitenSh tarafından Spiceworks forumlarına gönderdiği pop-up ekran görüntüsünü buldum :

— 3D1T0R
kaynak

Not: Tüm bu bilgileri kodun kısa bir kısmı için basit bir web aramasıyla buldum.

— 3D1T0R