Bir DOS komutuyla mevcut klasör adını al?

DOS komutunu kullanarak geçerli klasör adını (geçerli dizin yolu değil) elde etmek mümkün mü? Öyleyse nasıl?

En yakınım bu oldu ama yapmıyor:

for /f "delims=\" %%a in ("%CD%") do set CURR=%%a
echo.DIR: %CURR%

not: Yukarıdaki deneme, dizeyi tokenize etmeye ve CURR değişkeni olarak ayarlanan son belirteci almaya çalışmamdı.

Bulduğum en kısa yol:

for %I in (.) do echo %~nxI

veya bir .bat komut dosyasında:

for %%I in (.) do echo %%~nxI

veya değişkende değeri ile .bat içinde.

for %%I in (.) do set CurrDirName=%%~nxI
echo %CurrDirName%

Açıklama: http://www.robvanderwoude.com/ntfor.php

nx yalnızca dosya adı ve uzantısı anlamına gelir

Toplu iş dosyasının geçerli konumunu bilmek istiyorsanız (ve Windows'unuz çok eski bir sürüm değilse) for /?bir 'DOS kutusu' penceresine yazın. Aşağı kaydır. Okuyun.

Sen şimdi (dan okuyabileceği, dışarı bulacaksınız içinde bu değişkenler toplu dosya):

%0      - as the name how this batchfile was called
%~d0    - as the drive letter where this batchfile is located ('\\' in case of share)
%~p0    - as path (without the drive letter) where this batchfile is located
%~n0    - as filename (without suffix) of this batchfile
%~x0    - as filename's suffix (without filename) of this batchfile
%~a0    - as this batchfile's file attributes
%~t0    - as this batchfile's date+time
%~z0    - as this batchfile's filesize
%~dpnx0 - as this batchfile's fully qualified path+filename
[... and then some more ...]

Bu birçok durumda işe yarar. Toplu iş dosyasının çağrıldığını varsayalım mytest.bat. Bunu farklı şekillerde arayabilirsiniz:

1. ..\..\to\mytest.bat ............................... (göreceli yol)
2. d:\path\to\mytest.bat........................... (tam yol)
3. \\fileserver\sharename\mytest.bat... (uzak paylaşımdaki yol)

... ve değişkenlerinizde her zaman doğru değeri elde edersiniz.

Ben kişisel olarak Tom’ların cevabını beğendim, dir. Bu bana bir ipucu verdi:

for /f "delims=\" %%a in ("%cd%") do echo topmost dir: %%~nxa

Tom'un cevabı iyidir, ancak içinde belirli bir süre olan bir dizin isminiz varsa (yani wxwidgets-2.9.4) sadece tam adını alırsınız. Bu yüzden, bunun yerine wxwidgets-2.9 ​​çıkacaktır, çünkü .4 bir uzantı olarak kabul edildi (Evet, bir dizin adı olsa bile!).

Çıktı isminin tamamını almak için sonuna uzantı eklemelisiniz:

FOR %I IN (.) DO Echo %~nI%~xI

ve toplu iş dosyası modunda:

FOR %%I IN (.) DO Echo %%~nI%%~xI

Veya elbette, toplu iş dosyasında bir değişken ayarlayın:

FOR %%I IN (.) DO SET CurrentD=%%~nI%%~xI

Başka bir yol:

set "MyPath=%~dpnx0" & call set "MyPath=%%MyPath:\%~nx0=%%" 
echo MyPath=%MyPath%  

"." ile çalışır. pathname içindeki boşluklar

Bu ne işe yarıyor?

1. içine bütün dosya (sürücüharfi-yolu dosya yerine uzatma) koymak MyPathVar

2. MyPathvar adını dosya adını ve uzantısını kaldır

Aynı zamanda UNC Paths ile çalışır. Yolun sonundaki Backslash'a ihtiyacınız varsa. İkinci set komutunda \sonrasını kaldırın MyPath, örn.

set "MyPath=%%MyPath:%~nx0=%%"

Geçerli dizini bir değişkene alabilirsiniz. Tek astarı:

set a=%cd%

İle kontrol edin

echo %a%

sadece basit

for %%d in ("%CD%") do echo %%~nxd

veya

set "sPath=."
for %%d in ("%sPath%") do set "sDirName=%%~nxd"

Yolun sonunun ters eğik çizgisine dikkat edin, sonun ters eğik çizgisi olmamalıdır.

Bu konudaki cevabım 3 basit satırda yazıyor:

@echo off
SET "CDIR=%~dp0"
:: for loop requires removing trailing backslash from %~dp0 output
SET "CDIR=%CDIR:~0,-1%"
FOR %%i IN ("%CDIR%") DO SET "PARENTFOLDERNAME=%%~nxi"
ECHO Parent folder: %PARENTFOLDERNAME%
ECHO Full path: %~dp0
pause>nul

Bu benim için bir toplu iş dosyasından çalışır. Geçerli çalışma dizini adını döndürür.

pushd %1 & for %%i in (.) do @echo %%~ni