Mac OS X Finder'da sembolik bir bağlantı oluşturun

ln -sMac OS X Finder'da (OS 10.5) unix komutuyla aynı işlevselliği elde etmenin bir yolu var mı ? Finder pencerelerinde çalışırken Terminali açmadan sembolik bağlantılar oluşturabilmek istiyorum.

Not o Make AliasFinder'da komutunun bu takma adlar Terminalinde gidilemez çünkü ne istiyorum değil (ama ile oluşturulan bağlantılar ln -sTerminali ve Finder hem hareket edilebilen).

Peki , Finder'da AppleScript aracılığıyla sembolik bağlantılar oluşturmaya ne dersiniz ?

İşte bu linkteki en alakalı script:

on run
    open {choose file with prompt "Choose a file to create a symbolic link:" without invisibles}
end run

on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Sadece AppleScript Editor'a yapıştırın ve bir uygulama olarak kaydedin . Ardından bulucunuzun araç çubuğunun üzerine sürükleyebilir veya rıhtımda bağlayabilirsiniz .

SymbolicLinker tam olarak aradığınızı yapacak ve ücretsiz.

Kullanıcı nuc tarafından verilen bağlantıdaki bir el yazısı sorumu yanıtladı. İşte bağlantının kaybolması durumunda üretilen el yazısı.

Macworld makalesi olarak da kopyalanan yorumcu jonn8n tarafından verilen senaryoyu tercih ettim .

on run
    open {choose file with prompt ¬
        "Choose a file to create a symbolic link:" without invisibles}
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            do shell script "ln -s " & quoted form of posix_path ¬
                & " " & quoted form of (posix_path & ".sym")
        end try
    end repeat
end open

Bunu Script Editor kullanarak bir uygulama olarak kaydettim ve uygulamayı Finder kenar çubuğuna sürükledim, böylece artık dosya veya klasörleri uygulama simgesine sürükleyerek sembolik bağlantılar oluşturabiliyorum.

Yol Bulucu, Bulucunuza bunu ekler ve çok daha fazla özellik ekler.

Bir bash betiğini çalıştıran bir Servis oluşturmak için Automator.app kullanın . Bu, AppleScript'ten daha basittir ve üçüncü taraf yazılımı yüklemekten daha güvenilirdir.

for f in "$@"
do
    ln -s "$f" "$f.symlink"
done

Ardından Servisler menüsünden Sembolik Bağlantı Yap komutuna erişebilirsiniz :

Sonuç:

Bu komut dosyasındaki olası bir gelişme, şu anda seçilen dosyaları Finder'dan kullanmak için çalıştırma işleyicisini değiştiriyor olabilir:

on run
    tell application "Finder" to set sel to selection
    open sel
end run
on open the_files
    repeat with i from 1 to (count the_files)
        try
            set posix_path to POSIX path of (item i of the_files as alias)
            if posix_path ends with "/" then set posix_path to ¬
                text 1 thru -2 of posix_path
            try
                do shell script "ln -s " & quoted form of posix_path ¬
                    & " " & quoted form of (posix_path & ".sym")
            on error
                try
                    do shell script "ln -s " & quoted form of posix_path ¬
                        & " " & quoted form of (posix_path & ".sym") with administrator privileges

                end try
            end try
        end try
    end repeat
end open

Eklemek için [application] /Contents/Info.plist dosyasını düzenleyebilirsiniz.

<key>LSUIElement</key>
<true/>

Sonuncusundan hemen önce </dict>. Bu, uygulamanın arka planda çalışacağı ve tıkladığınızda öne gelmeyeceği anlamına gelir.

Ayrıca, SymbolicLinker'in çalışmadığı Snow Leopard'da, sembolik bir bağlantı oluşturmak için Terminal komutunu ya da AppleScript'i yapmak için Automator ile bir Servis oluşturabilirsiniz.

Bir AS daha:

tell application "Finder"
    repeat with f in (get selection)
        set p to POSIX path of (f as text)
        set p2 to POSIX path of (desktop as text) & name of f
        do shell script "ln -s " & quoted form of p & " " & quoted form of p2
    end repeat
end tell

Burada aramayı deneyin: http://www.techiecorner.com/528/how-to-create-shortcut-in-mac-os-x/

Bu, zaten bir şeye tıkladığınızda kontrol tuşuna basarsanız, zaten OSX'in içine yerleştirilmiştir.